perm filename CLKSER[KA,SYS] blob
sn#228325 filedate 1976-08-02 generic text, type C, neo UTF8
COMMENT ⊗ VALID 00072 PAGES
C REC PAGE DESCRIPTION
C00001 00001
C00008 00002 APRINT - KLTINT
C00010 00003 AP2INT, BREAKX PROCESS CLOCK INTERRUPTS - BOTH PROCESSORS.
C00017 00004 APRI1A, APRADD, KL10 METER SERVICE, - P1 CLOCK ONLY
C00021 00005 APRDEL, APRDRL - P1 CLOCK ONLY.
C00025 00006 APRI2 - REQUEST CH7 INTERRUPT AND DISMISS. BOTH PROCESSORS. CLOCK INT ONLY.
C00029 00007 APRER APR INTERRUPTS OTHER THAN CLOCK ON P2 ONLY - APRFLT
C00042 00008 CLOCK 24 JULY 67
C00044 00009 HERE AT CLK INTERRUPT LEVEL - CLKINT
C00046 00010 P2 CLK INTS COME HERE
C00047 00011 CLKERR - NOW OFFICIALLY IN CHANNEL 7. CLKIN1
C00050 00012 P1 CLOCK LEVEL.- CIP2A
C00056 00013 CIPZZ1, CRKT4, CIP4, P2 CLOCK ROUTINES, CLOCK QUEUE
C00060 00014 CIP11, SPWCHK, SP2CHK
C00063 00015 CIP6A, CIP6B, NULJOB, S2U, U2S - CONTEXT SWITCHING
C00068 00016 RESTORE HARDWARE STATE OF NEW JOB - CIP8
C00073 00017 THE NULL JOB - NULJB NULP1, NULP2
C00075 00018 CHECK, CHKNOW
C00077 00019 BEGIN SYSFIX VERIFY SYSTEM CHECKSUM AND FIX IT IF WRONG.
C00083 00020 INTRUN - THE (MOORER) USER INTERRUPT HANDLER
C00088 00021 GETINT - GET FIRST SERVICABLE INTERRUPT BIT FROM WORD OF BITS.
C00090 00022 INTR9, INTR14 CLEAR THE INTERRUPT BIT IN JBTIRQ AND START THE I-PROCESS
C00097 00023 INTR4 - REGULAR I-PROCESS STARTUP (NOT AFTER UWAIT)
C00101 00024 INTADC, INTXIT
C00103 00025 ROUTINE TO SWAP A GUY IN SO HE MAY BE INTERRUPTED
C00105 00026 INTCH7 , INTERR, INTDSM, INTDEB
C00111 00027 INTKILL ROUTINE TO CLEAR A JOB'S INTERRUPT ENABLINGS AND RESET HIS MASKS
C00112 00028 INIJOB ROUTINE TO INITIALIZE A JOB SLOT
C00118 00029 COMCON THE COMMAND DECODER 8/4/67
C00122 00030 COMMAND
C00125 00031 COMFND: MOVE UUO,COMTAB(AC1) SAVE FULL COMMAND NAME
C00128 00032 CHKACT, CMDXMP, CMDMAP
C00130 00033 COMER, COMGO, COMDIS, COMRET, SKPBRK. DISPATCH TO AND RETURN FROM COMMAND SETUP
C00136 00034 TABLE OF CONSOLE COMMANDS
C00139 00035 DEFINE NAMES
C00148 00036 BEGIN COMTBL
C00149 00037 CEDDT, SLEVEL, TYPSL
C00151 00038 PTTY, NOTLOG
C00155 00039 PJOB COMMAND. DECLF, PJOBDV, PJOB
C00159 00040 PPPN
C00161 00041 SDSKPPN - ALIAS COMMAND
C00164 00042 KJOB - KILL ATTACHED JOB. LOGPLS, KJOB2, JOBKL
C00170 00043 KILCOM - KILL COMMAND.
C00175 00044 CORE COMMAND. JOB1
C00181 00045 COR4 - CORE COMMAND WITHOUT ARGUMENT - PRINT STUFF
C00184 00046 START, STARTC, REENTE, START, CSTART, REENTER COMMANDS
C00187 00047 DDTGO - DDT COMMAND
C00190 00048 STOP, "HALT" OR "<CONTROL>C", CONT, CONTC - CONTINUE AND CCONTINUE COMMAND
C00194 00049 SETUWP CLRUWP COMMANDS, SETWPS, CLRWPS
C00197 00050 DISABL, ENABLE PRIVILEGES
C00200 00051 PRJOB, HELLO, ALOGIN, SETTPV, CLRTPV
C00202 00052 CLOGIN LOGIN COMMAND
C00205 00053 COMMANDS THAT RUN PROGRAMS (RPG,COPY,DART,HELP,WHO,WHERE,FIND,TEST,LISP). HLPRUN
C00208 00054 R, RUN, SAVE, SSAVE, GET COMMANDS. ARCOM, CMDRUN, AXXCOM, AXCOM, ARPCOM
C00214 00055 "ASSIGN DEV:NAME" - ASSIGN DEVICE TO JOB AND GIVE IT LOGICAL NAME
C00226 00056 ALREADY ASSIGNED TO ANOTHER JOB
C00229 00057 "DEASSIGN DEV" - DEASSIGNS DEVICE FROM CONSOLE
C00232 00058 REASSI, REASS, REASSIGN UUO AND COMMAND.
C00239 00059 ATTACH COMMANDS
C00244 00060 ATTACH DEVICE DEVATT
C00248 00061 FLUSH THIS TTY'S BUFFERS IF NOT IN USE BY A JOB
C00250 00062 "FORK", "CFORK", "DETACH" AND "CDETACH" COMMANDS
C00258 00063 "DAYTIME" COMMAND. DAYTIM, DAYT2, DAYCNT, DCTOSD
C00265 00064 "TIME (JOB NO.)" - PRINT TOTAL AND INCREMENTAL RUNNING TIME FOR A JOB
C00272 00065 ROUTINE TO LET TTY TALK TO ANY OTHER RING OF TTYS
C00273 00066 ECOM, DCOM, EXAMINE/DEPOSIT COMMANDS
C00280 00067 CBLANK, NOCOM,
C00281 00068 FINIS - FINISH DEVICE - CLOSES,RELEASE AND DEASSIGNS DEVICE
C00288 00069 "RESOURCES" - PRINT OUT AVAILABLE DEVICES AND FREE BLOCKS ON THE DISK
C00292 00070 RUNCHK, DLYCOR, DLYCR1
C00295 00071 STOPCK SEARCH DEVICE CHAIN FOR DSK WITH COUNTS ON
C00297 00072 "FILES <filename or job number>" -- print status of open files.
C00309 ENDMK
C⊗;
SUBTTL APRINT - KLTINT
IFKL10,<
;KLTINT - VECTOR INTERRUPT FROM INTERVAL TIMER COMES HERE.
↑KLTINT:EXCH TAC,KLTINX ;SAVE TAC. GET INTERUPT PC
MOVEM TAC,APRCHL
EXCH TAC,KLTINX
CHKPIS (0,\APRCHN)
SKIPLE KLITCN
SETCMM KLITCN ;1 BECOMES -2
AOSGE KLITCN ;0→1→-1→0...
JRST KLTIN1
CONO TIM,60000!=1667 ;CLEAR INTERRUPT. METER ON. TWO LONG TICKS
JRST .+2
KLTIN1: CONO TIM,60000!=1666 ;AND ONE SHORT TICK
CONO PI,4000!<1⊗<7-APRCHN>> ;INITIATE INTERRUPT FOR III
;(RESTART III WHEN IT IS IDLE)
SETOM KLCLKF ;FLAG A CLOCK INTERRUPT
EXCH PID,APRID+P1PID ;KL10 CLOCK INTERRUPT.
CAIE PID,P1PID
HALT .+1
MOVEI PID,P1PID
JRST APR.I1
>;IFKL10
;AP2INT, BREAKX PROCESS CLOCK INTERRUPTS - BOTH PROCESSORS.
LOSYS
;P2 ENTERS AT AP2INT
;APR IS ALWAYS ENABLED FOR CLOCK,ILM,NXM,PDLOV,
;ALSO AROV, (PC CHNG, AND CONS ON PDP-6) AND FOV (KA10) IF THE USER REQUESTS
↑AP2INT:EXCH PID,APRID+P2PID
CAIE PID,P2PID
HALT .+1
MOVEI PID,P2PID
IFN FTPAGER,<
AOSN P2GFLG
JRST APRFLT ;SIMULATED ILM FROM BBN PAGER
>;FTPAGER
;ADDRESS BREAK SYSTEM.
;PUT THE EXCEPTED PCS (THE ONES YOU WANT TO IGNORE BREAKS FROM) IN BRKTAB,
;AND THE NUMBER OF EXCEPTED PCS IN BRKNUM.
;WHEN A BREAK OCCURS FROM SOME UNEXCEPTED PC, IT EXECUTES THE CODE AT
;BRKHIT, WHICH MAY BE PATCHED TO WHATEVER YOU WANT.
;NOTE THAT IF BRKNUM≤0 ALL BREAKS ARE EXCEPTED AND AN ERROR MESSAGE RESULTS
CONSO APR,ADRBRK ;ADDRESS BREAK?
JRST BREAKX ;NO.
MOVEM TAC,BRKTAC ;SAVE A COUPLE OF ACCUMULATORS
MOVEM AC1,BRKAC1
HRRZ TAC,AP2CHL ;PICK UP BREAK PC+1
SUBI TAC,1 ;MAKE IT HONEST
SKIPLE AC1,BRKNUM ;ARE WE READY FOR A BREAK?
CAILE AC1,BRKMAX ;YES. REASONABLE NUMBER OF EXCEPTED PCS?
JRST BRKERR ;NO. NOT READY
CAMN TAC,BRKTAB-1(AC1) ;IS THIS PC EXCEPTED?
JRST BRKXIT ;JUMP IF WE MATCHED SOME EXCEPTED PC.
SOJG AC1,.-2 ;NO. TRY NEXT ONE
BRKHIT: REPEAT 10,<JFCL> ;PATCH HERE FOR UN-EXCEPTED BREAKS.
BRKXIT: MOVE TAC,BRKTAC ;RESTORE ACCUMULATORS
MOVE AC1,BRKAC1
CONO APR,ADRBRK!APRCHN ;CLEAR BREAK BIT. SET PIA. DISMISS
JRST P2RET
BRKERR: EXCH P,APRPDL(PID)
PUSHACS
CAIG AC1,BRKMAX ;SKIP IF ILLEGAL VALUE OF BRKNUM
JUMPGE AC1,BRKER1 ;JUMPE IF LEGAL VALUE OF BRKNUM
PUSHJ P,DISMES
ASCIZ /BRKNUM VAL ILLEGAL = / ;VALUE ILLEGAL
HRRZ TAC,BRKNUM
PUSHJ P,DISLOC
PUSHJ P,DISCRLF
SETZM BRKNUM
BRKER1: PUSHJ P,DISMES
ASCIZ /ADDR BRK, PC=/
MOVE TAC,APRCHL
PUSHJ P,DISLOC
PUSHJ P,DISCRLF
POPACS
EXCH P,APRPDL(PID)
JRST BRKXIT
BREAKX: CONSO APR,1B26 ;IS IT A CLOCK TICK?
JRST APRER ;NO, GO CHECK ERROR FLAGS
;HERE FOR CLOCK TICK ON BOTH PROCESSORS
APR.I1: MOVEM TAC,APRTAC(PID) ;GET AN ACCUMULATOR
AOS TIME(PID) ;YES, INCREMENT TIME OF DAY
SETOM TIMEFF(PID) ;FLAG THAT APR CLOCK HAS TICKED
HLLOS CLKFLG(PID) ;SET FLAG FOR CLK FORCED INTERRUPT
CONSZ PI,7400 ;SKIP IF NO INT IN PROGRESS (CH4-7)
JRST BREAK3 ;YES
SKIPN TAC,JOB(PID) ;INCREMENT JOB'S RUNNING TIME.
JUMPN PID,APRI1 ;IF P2, DON'T BUMP NULL TIME
AOS TTIME(TAC) ;TIME ACCOUNTING
JUMPE TAC,APRI1 ;DON'T COUNT KCJ FOR NULL JOB.
MOVEM AC1,APRAC1(PID) ;GET AN AC
HLRZ AC1,JBTPAG(TAC) ;GET CURRENT JOB'S PAGE COUNT
ADDM AC1,JBTKCJ(TAC) ;PAGE-JIFFIES
MOVE AC1,APRAC1(PID) ;GET BACK OUR AC
AOSA JBTRNB(TAC) ;INCREMENT JOB LOADING. SKIP
BREAK3: AOS INTIME(PID) ;INCREMENT INTERRUPT LEVEL TIME
APRI1: AOS TAC,UPTIME(PID) ;INCREMENT SYSTEM UPTIME.
JUMPN PID,APRI2 ;P2 TAKES A GIANT STEP
JRST APRI1A ;(TO HISYS) TAC HAS UPTIME.
;APRI1A, APRADD, KL10 METER SERVICE, - P1 CLOCK ONLY
HISYS
;DATA DISK AND CART CLOCKS LIVE HERE.
;ENTER HERE FOR P1 CLOCK TICKS AFTER TIME ACCOUNTING
APRI1A:
IFN CARNUM,<
CAML TAC,CARALR ;TIME TO RUN HI-PRIORITY CART CLOCK?
JRST CARNXT ;YES. CLOBBERS TAC. RESTORES PID←P1PID.
↑CARDON:
>;IFN CARNUM
SOSGE DDCNT ;HAS DATA DISK TIMED OUT??
JRST DDCLK ;YES, GO FLUSH IT (RETURN TO APRADD)
SKIPE DDSTART ;DO WE NEED TO START IT UP?
JRST DDSTRT ;YES, DO SO. (RETURN TO APRADD)
↑APRADD: ;RETURN HERE FROM DPYSER
IFKL10,<
MOVE TAC,UPTIME
TRNE TAC,3 ;ONLY SAMPLE METER EVERY FOURTH TICK
JRST NOMTR
EXCH P,APRPDL
PUSH P,AC1
PUSH P,AC2
SKIPN TAC,MTRPTR ;GET CURRENT METER POINTER
JRST MTRTM1 ;IF NONE, START OVER
BLKI TIM,AC1 ;READ DOUBLE WORD METER
DMOVEM AC1,MTRVAL(TAC) ;STORE CURRENT VALUE
DADD AC1,MTRTOT(TAC) ;ADD TO MAKE CUMULATIVE TOTAL
DMOVEM AC1,MTRTOT(TAC) ;STUFF RESULT BACK
DMOVE AC1,MTRVAL(TAC) ;GET THE CURRENT VALUE AGAIN
DADD AC1,MTRTMP(TAC)
DMOVEM AC1,MTRTMP(TAC) ;INCREMENT TABLE OF 16 RECENT VALUES
AOS AC1,MTRCNT(TAC) ;COUNT A VALUE READ
TRNE AC1,17 ;16 ITEMS COMPLETE?
JRST MTRTM0 ;NOT YET
DMOVE AC1,MTRTMP(TAC)
DMOVEM AC1,MTRREC(TAC) ;SAVE TOTAL OF 16 RECENT VALUES
SETZM MTRTMP(TAC) ;AND CLEAR TEMP ACCUMULATOR FOR NEXT TIME
SETZM MTRTMP+1(TAC)
HLRZ AC2,MTRLNK(TAC) ;METER POINT NUMBER (STARTS COUNTING AT 1)
MOVE AC1,MTRCNS-1(AC2) ;SAVE COUNT OF RECENT VALUES
MOVEM AC1,MTRCNR-1(AC2)
SETZM MTRCNS-1(AC2)
MTRTM0: HRRZ TAC,MTRLNK(TAC) ;GET LINK TO NEXT METER BLOCK
SKIPN TAC ;SKIP UNLESS END OF LIST.
MTRTM1: MOVEI TAC,MTRLST ;START AT FRONT OF METER LIST
MOVEM TAC,MTRPTR ;SAVE POINTER FOR NEXT TIME
BLKO TIM,[40] ;STOP COUNTING, CLEAR METER
SETZM KLEPT+KLPFMT ;CLEAR EPT LOCATIONS FOR METER
SETZM KLEPT+KLPFMT+1
CLRUS1 ;CLEAR MICROCODE STATE 1
HLRZ AC2,MTRLNK(TAC)
MOVEM AC2,MTRCNM ;SAVE METER TYPE NUMBER (SEE MTRON MACRO)
CAME AC2,MTRCNW ;ARE WE ABOUT TO METER AN EVENT IN PROGRESS?
JRST MTRTM2
SETUS1 ;YES. SET MICROCODE STATE 1
AOS MTRCTV-1(AC2)
AOS MTRCNS-1(AC2)
MTRTM2: BLKO TIM,MTRDAT(TAC) ;SET METER CONDITION. START COUNTING
POP P,AC2
POP P,AC1
EXCH P,APRPDL
NOMTR:
>;IFKL10
;FALL OFF THE PAGE
;APRDEL, APRDRL - P1 CLOCK ONLY.
;FALLS THROUGH
;GENERATE ANY USER CLOCK-INTERRUPTS NEEDED.
;APRLST POINTS TO A LIST, 2-WORDS PER ENTRY
;LH OF FIRST WORD IS TIME BETWEEN INTERRUPTS
;RH OF FIRST WORD IS JOB NUMBER
;SECOND WORD IS NEGATIVE COUNT OF TIME BETWEEN INTERRUPTS
SKIPN TAC,APRLST ;ANY INTERRUPTS TO GIVE?
JRST APRI2 ;NO, EXIT NOW
MOVEM J,APRJ
MOVEM AC1,APRAC1 ;SAVE SOME AC'S AND PICK UP A PDL
MOVEM AC2,APRAC2
EXCH P,APRPDL
APRCI2: SKIPN J,(TAC) ;END OF LIST?
JRST APRCI9 ;YES, RESTORE ACS AND LEAVE
AOSGE 1(TAC) ;TIME EXPIRED YET?
JRST APRCI4 ;NO, LOOP AROUND
MOVSI AC2,INTCLK ;MAKE SURE HE IS STILL ENABLED
TDNN AC2,JBTIEN(J)
JRST APRCI5 ;NOT ENABLED, ALLOWABLE TIMING ERROR, JUST DELETE
HLRZ AC1,J ;RESET TIME
MOVNM AC1,1(TAC)
IORM AC2,JBTIRQ(J)
SETOM INTREQ
APRCI4: ADDI TAC,2 ;LOOP AROUND FOR NEXT ENTRY
JRST APRCI2
APRCI5: PUSHJ P,APRDEL ;DELETE THE ENTRY, SKIP IF THAT WAS THE LAST ONE
JRST APRCI2
JRST APRCI3 ;LIST EXHAUSTED
APRCI9: CAMN TAC,APRLST ;IS LIST EMPTY?
PUSHJ P,APRDRL
APRCI3: EXCH P,APRPDL ;RESTORE THE ACS WE SAVED
MOVE AC1,APRAC1
MOVE AC2,APRAC2
MOVE J,APRJ
JRST APRI2 ;(LOSYS)
;APRDEL, APRDRL ROUTINES
;APRDEL DELETE CLOCK INT ENTRY POINTED TO BY TAC
;DELETES FS BLOCK AND SKIP RETURNS IF LAST ENTRY IS DELETED
;CALL ONLY ON P1 AFTER DOING CONO PI,APROFF
↑APRDEL:JUMPN PID,CPOPJ
MOVEI AC1,(TAC) ;START AT CURRENT ENTRY
APRDL1: ADDI AC1,2 ;ADVANCE TOWARD END OF THE LIST.
SKIPE (AC1) ;AT THE END YET?
JRST APRDL1 ;NO. KEEP LOOKING.
MOVE AC2,-2(AC1) ;PICK UP LAST ENTRY.
MOVEM AC2,(TAC) ;AND STORE IT OVER THEN ENTRY BEING DELETED.
MOVE AC2,-1(AC1)
MOVEM AC2,1(TAC)
SETZM -2(AC1) ;CLEAR THE FORMER LAST ENTRY.
MOVEI AC1,-2(AC1) ;AC1←ADDRESS OF END OF THE LIST.
CAME AC1,APRLST ;SAME AS FIRST OF THE LIST?
POPJ P, ;NO. THE LIST IS NON-EMPTY
AOS (P) ;SET SKIP RETURN
APRDRL: MOVEI AC1,0 ;RETURN EMPTY APRLST TO FS.
EXCH AC1,APRLST
JRST FSGIVE
;APRI2 - REQUEST CH7 INTERRUPT AND DISMISS. BOTH PROCESSORS. CLOCK INT ONLY.
LOSYS
APRI2: CONO PI,4000+1⊗<7-CLKCHN> ;REQUEST INTERRUPT ON CLOCK CHANNEL.
JUMPN PID,APRI2X ;EXIT NOW IF P2.
SETOM DSFLAG ;TELL DPYSER THAT CLOCK HAS TICKED.
MOVE TAC,APRIN1(PID) ;GET USER'S ENABLINGS
TRNN TAC,1B26 ;IS USER ENABLED FOR OLD-STYLE CLOCK INT?
JRST APRI2X ;NO. EXIT NOW
MOVEI TAC,46 ;YES. FIND REAL USER PC. ASSUME CH3
CONSZ PI,0400 ;CH7 IN PROGRESS?
JRST APRI2K ;YES. LOOK @156
CONSZ PI,1000 ;CH6 IN PROGRESS?
JRST APRI2L ;YES. LOOK @154
CONSZ PI,2000 ;CH5 IN PROGRESS?
JRST APRI2M ;YES. LOOK @152
CONSZ PI,4000 ;CH4 IN PROGRESS?
JRST APRI2N ;YES. LOOK @150
JRST APRI2O ;NO. IT WAS CH3 - LOOK @146
APRI2K: ADDI TAC,2 ;CHANNEL 7
APRI2L: ADDI TAC,2 ;CHANNEL 6
APRI2M: ADDI TAC,2 ;CHANNEL 5
APRI2N: ADDI TAC,2 ;CHANNEL 4
APRI2O: CONSZ APR,MAOFF
IORI TAC,100
IFKL10,<
SKPNKL ;SKIP IF NOT THE KL10
IORI TAC,KLEPT ;KL10 PI LOCATIONS ARE IN THE EPT
>;IFKL10
MOVEM AC1,APRAC1 ;SAVE AC1 FOR A WHILE.
MOVE AC1,@(TAC) ;FETCH USER'S PC.
TLNN AC1,USRMOD ;IN USER MODE?
JRST APRI2W ;SORRY. CAN'T INTERRUPT UUO CODE FOR THIS.
EXCH P,APRPDL ;GET A STACK.
PUSHACS ;SAVE EVERYTHING
MOVE J,JOB ;SETUP MAP FOR THIS USER.
PUSHJ P,APRI2P ;HAVE TO PUSHJ FOR MAPSET TO WORK!
POPACS
EXCH P,APRPDL
APRI2W: MOVE AC1,APRAC1
APRI2X: MOVE TAC,APRTAC(PID) ;RESTORE TAC
IFKL10,<
JUMPE PID,P1RET ;KL10 CLOCK INTERRUPTS
>;IFKL10
CONO APR,1B26+APRCHN ;NO, CLEAR THE CLOCK FLAG
PBRET: JUMPE PID,P1RET
P2RET: EXCH PID,APRID+P2PID
JEN @AP2CHL
P1RET: EXCH PID,APRID+P1PID
JEN @APRCHL ;DISMISS INTERRUPT
APRI2P: PUSHJ P,MAPSET
MOVE AC1,@(TAC) ;GET PC AGAIN
XCTR XW,[MOVEM AC1,JOBTPC] ;STORE INTERRUPT PC IN JOB DATA AREA
MOVEI AC1,1B26
XCTR XRW,[IORM AC1,JOBCNI] ;STORE INTERRUPT CONDITION IN JOBCNI
ANDCAM AC1,APRIN1(PID) ;SHUT OFF FUTURE CLOCK TRAPS.
XCTR XRW,[ANDCAM AC1,JOBENB] ;IN USER'S ENABLES TOO.
XCTR XR,[HLLZ AC1,JOBTPC] ;SET USER PC TO HIS TRAP ADDRESS
XCTR XR,[HRR AC1,JOBAPR]
MOVEM AC1,@(TAC)
POPJ P, ;RETURN THRU MAPSET (RESTORE MAP) TO CALLER
;APRER APR INTERRUPTS OTHER THAN CLOCK ON P2 ONLY - APRFLT
;WE ALREADY LOOKED AT CLOCK FLAG. DO NOT TEST IT OR CLEAR IT!
APRER: EXCH TAC,@APRCH+P2PID ;SAVE TAC, GET PC WORD
XORI TAC,P2GINT+1
TDNN TAC,[USRMOD,,-1]
JRST APRSCR ;GOT SCREWED BY PDLOV/MEM PROT?
APRNSC: XORI TAC,P2GINT+1
APRNS1: CONSZ APR,ILM
JRST APRMPV ;CLEAN UP AFTER CPU ON MPV
TLNN TAC,USRMOD ;IS IT IN USER MODE?
JRST APRER2 ;EXEC MODE.
APRER1: CONSZ PI,7400 ;USER MODE.
JRST APRER2 ;USER IN PROGRESS IN PI 4,5,6,7?
SKIPN SPWUUF+P2PID ;SPACEWAR?
JRST APRER2 ;NO.
EXCH TAC,@APRCH+P2PID ;ERROR FROM SPACEWAR.
EXCH PID,APRID+P2PID
JRST SP2INT
;APR INT FROM EXEC MODE OR, USER NOT ENABLED FOR INT.
APRER2: CONSZ APR,630000 ;DOES EXEC CARE? CONS,PDLOV,NXM,MPV
JRST APRERB ;YES!
CONSZ APR,110 ;AROV OR FOV
CONO APR,440!APRCHN ;YES, DISABLE THEM
APRER3: TLZ TAC,440000 ;CLEAR FOV AND AROV PC FLAGS SO INT MAY
EXCH TAC,@APRCH+P2PID ; BE DISMISSED. RESTORE TAC & @APRCH
CONO APR,530110+APRCHN ;CLEAR PDLOV,CONS,MPV,NXM,FOV,AROV
JRST P2RET
;NON-TRIVIAL ERROR DETECTED. MAY BE FROM EXEC.
APRERB: MOVEM TAC,APRPC+P2PID ;STORE ERROR PC FOR CLK CHANNEL
CONI APR,APRERR+P2PID ;STORE ERROR FLAGS - SEE CH7 CODE
HLLOS CLKFLG+P2PID ;SET FLAG FOR CLK INTERRUPT
SETOM SCHEDF+P2PID ;FLAG THAT RESCHEDULING IS NEEDED
;(EVEN THOUGH PC MAY BE IN EXEC MODE)
CONO PI,4000+1⊗<7-CLKCHN> ;REQUEST INTERRUPT ON CLOCK CHANNEL.
CONSO APR,ILM ;ILL MEM REF?
JRST APRERC ;NO.
MOVEM TAC,USAVPC+P2PID ;SAVE ERROR PC FOR CLKINT
HRRI TAC,0 ;YES. SET ADDRESS SO PDP-10 DOESN'T HANG
APRER4: CONSO APR,NXM ;NON-EXISTANT MEMORY?
JRST APRER3 ;NO. RESTORE ACS AND DISMISS
MOVEI TAC,(TAC) ;YES. IS IT PC?
CAML TAC,RMEMSIZ
MOVEI TAC,[CONO PI,4000!1⊗<7-CLKCHN>] ;YES. DISMISS TO CLKINT
HLL TAC,APRPC+P2PID
JRST APRER3 ;RESTORE ACS AND DISMISS
APRERC: TLNN TAC,USRMOD ;ERROR FROM USER?
CONSO PI,177B27≠<1B27⊗<7-APRCHN>> ;NO. PI IN PROGRESS?
JRST APRER4 ;USER MODE OR UUO LEVEL.
EXCH P,APRPDL+P2PID ;SYSTEM ERROR!
PUSHACS
PUSH P,TAC
PUSHJ P,DISDATE
PUSHJ P,DISMES
ASCIZ /P2CH3 ERROR IN EXEC. PC = /
POP P,TAC
PUSHJ P,DISOCT
PUSHJ P,DISMES
ASCIZ /
APR CONI = /
MOVE TAC,APRERR+P2PID
PUSHJ P,DISOCT
PUSHJ P,DISCRLF
PUSHJ P,SYSFIX
JFCL ;NOT IN MONITOR
JFCL ;ERROR, BUT COULDN'T FIX
PUSHJ P,DISFLU ;SEND MESSAGES TO CTY.
PUSHJ P,WDDTCALL ;MAY REQUIRE INTERVENTION.
POPACS
EXCH P,APRPDL+P2PID
JRST APRER4
;GET HERE IF ADDRESS IN CH3 IS EXEC PAGINT+1
APRSCR: CONSZ APR,200000 ;SKIP IF PDLOV
CONSZ PI,7400 ;SKIP IF NOT IN PROGRESS ON 4-7
JRST APRNSC ;NOT PDLOV OR PDLOV FROM PI CH 4-7
EXCH TAC,P2GINT ;GET PC OF PUSH/PUSHJ THAT SCREWED UP
TLNE TAC,USRMOD
JRST APRNS1 ;MAKE IT LOOK LIKE USER MODE PDLOV
EXCH TAC,P2GINT ;WAS FROM EXEC MODE - UUO LEVEL
JRST APRNSC
IFN FTPAGER,<
APRFL2: MOVE TAC,P2GINT
HRRI TAC,-1(TAC) ;IT WAS A WRITE, SO SOS THE PC
JRST APRMPV
APRFLT: MOVEM TAC,APRCHL ;SAVE TAC AWAY
MOVE TAC,PSB+TSW ;GET TRAP STATUS WORD
TLNE TAC,4 ;SKIP IF WASN'T A WRITE REQUEST
JRST APRFL2 ;IT WAS A WRITE REQUEST
MOVE TAC,P2GINT ;SET UP TAC TO PC OF LOSSAGE
>;FTPAGER
APRMPV: CONO APR,400000!APRCHN ;DON'T MENTION PDLOV YET IF BOMBED ON MPV
TLNE TAC,USRMOD ;MAY HAVE TO WORRY IF EXEC LOST
JRST APRER1 ;NO. USER MODE.
CONSZ PI,67400 ;PI IN PROGRESS? (EXCEPT APRCHN)
JRST APRER2 ;YES. MPV FROM EXEC PI IN PROGRESS.
HRRI TAC,UADERR ;SEND HIM TO ADDRESS CHECK
JRST APRER3
HISYS
SUBTTL CLOCK 24 JULY 67
;THIS ROUTINE RUNS ON THE LOWEST PRIORITY PI CHANNEL AND AT UUO LEVEL
;TO CAUSE AN INTERRUPT ON CLK CHANNEL:
; SETOM CLKFLG ;FLAG THAT INTERRUPT HAS BEEN REQUESTED
; CONO PI,CLKREQ ;REQUEST PI INTERUPT ON LOWEST PI CHANNEL
;THE FOLLOWING OTHER FLAGS MUST ALSO BE SET
;APRERR-APR DETECTED ERROR IN CURRENT JOB
;SCHEDF-RESCHEDULING MUST TAKE PLACE(EVEN THOUGH PC IN EXEC MODE)
;TIMEF-APR CLOCK HAS TICKED ON HIGH PRIORITY CHANNEL
;SEE APRSER AND RUNCSS TO SEE HOW THIS ROUTINE IS CALLED
;CLK SERVICE PERFORMS THE FOLLOWING ON A REGULAR BASIS:
;PROCESSES CLOCK QUEUE REQUESTS
;CALLS CONSOLE MONITOR COMMAND DECODER
;CALLS CORE SHUFFLER
;THEN CALLS SCHEDULER
;IF THE CURRENT JOB IS IN EXEC MODE THE ABOVE 4 TASKS ARE
;DELAYED UNTIL THE CURRENT JOB ENTERS A STOPPABLE STATE: I.E., UNTIL
; 1. JOB STARTS TO WAIT FOR A BUSY SHARABLE DEVICE
; 2. JOB STARTS TO WAIT FOR IO TO COMPLETE
; 3. CONTROL ABOUT TO RETURN TO USER MODE
;THEN CLK SERVICE IS ENTERED AT THE UUO LEVEL
;HERE AT CLK INTERRUPT LEVEL - CLKINT
IFKL10,<
↑KCLKIN:EXCH 17,KLTPC
MOVEM 17,CLKCHL
EXCH 17,KLTPC
JRST CLKINT
>;IFKL10
↑CLKIN0:EXCH 17,UUO0+P1PID ;GET HERE WHEN CLKFLG IS NEGATIVE
MOVEM 17,CLKCHL ;SIMULATE INT FROM USER
EXCH 17,UUO0+P1PID
↑CLKINT:SETZM CLKFLG+P1PID
MOVEM 17,CLKS17+P1PID ;SAVE AC 17
SKIPP1
HALT .
IFKL10,<
JSP 17,.+1
TLO 17,PCU ;SET PCU SO XCTRS WILL WORK
HRRI 17,.+2
JRST 2,@17
>;IFKL10
SKIPE SPWUUF+P1PID ;SPACEWAR IN PROGRESS?
JRST SPCLK1 ;YES, RUN SPACEWAR CLOCK P1
IFN FTHG,<
MOVEI 17,7
MOVEM 17,HGCODE
>;FTHG
MOVEI 17,P1PID
SKIPLE INTDISP(17) ;IS SOMEONE SNEAKING INTO CH7 FOR USER-INT SERVICE?
JRST @INTDISP(17) ;SERVICE HIM (INTCH7, INTDSM, OR INTDEB)
IFN FTHG,< SETZM HGCODE >
SKIPN 17,USAVPC
MOVE 17,CLKCHL ;IS CURRENT JOB IN USER MODE?
TLNN 17,USRMOD
SKIPE SCHEDF+P1PID ;EXEC MODE - IS THIS A FORCED RESCHEDULING?
JRST CLKIN1 ;USER MODE OR FORCED RESCHEDULING.
MOVE 17,[CONO PI,PIOFF]
MOVEM 17,UUOXIT+P1PID ;DIVERT TO CLKIN0 ON WAY BACK TO USER
MOVE 17,CLKS17+P1PID ;LEAVE TIMEF SET AND DISMISS INT.
JEN @CLKCHL
;P2 CLK INTS COME HERE
LOSYS
↑CL2IN0:EXCH 17,UUO0+P2PID
MOVEM 17,CL2CHL
EXCH 17,UUO0+P2PID
↑CL2INT:SETZM CLKFLG+P2PID
SKIPP2
HALT .
MOVEM 17,CLKS17+P2PID
SKIPE SPWUUF+P2PID
JRST SPCLK2 ;SPACEWAR CLOCK TICK
MOVEI 17,P2PID
SKIPLE INTDISP(17)
JRST @INTDISP(17)
SKIPN 17,USAVPC+P2PID
MOVE 17,CL2CHL
TLNN 17,USRMOD
SKIPE SCHEDF+P2PID
JRST CL2IN1
MOVE 17,[CONO PI,PIOFF]
MOVEM 17,UUOXIT+P2PID
MOVE 17,CLKS17+P2PID
JEN @CL2CHL
CL2IN1: MOVEM 17,USRPC+P2PID
MOVEI 17,P2PID
JRST CLKERR
;CLKERR - NOW OFFICIALLY IN CHANNEL 7. CLKIN1
CLKIN1: NOKL10,<DATAO PI,[0] > ;P1 - NOW OFFICIALLY IN CHANNEL 7
MOVEM 17,USRPC+P1PID
MOVEI 17,P1PID
CLKERR: JSR @CLKSV(17) ;SAVE ACS
SETZM USAVPC(PID) ;(BOTH PROCESSORS HERE)
HRLI P,-CLKPLN
HRRI P,CLKPDL-1(PID)
MOVE TAC,UUOXI(PID)
MOVEM TAC,UUOXIT(PID) ;RESTORE EXIT, NOW THAT WE MADE IT
SKIPE TAC,APRERR(PID) ;IS THIS AN ERROR INTERRUPT?
PUSHJ P,APRILM ;YES, GO PROCESS ERROR
JUMPN PID,CLKER1 ;AVOID INTERRUPT PROCESSING ON P2.
SKIPE INTREQ(PID) ;ANY INTERRUPTS PENDING?
PUSHJ P,INTRUN
CLKER1: SKIPN TIMEFF(PID) ;CLOCK FLAG?
JRST CIP5 ;NO, JUST RESCHEDULE
SETZM TIMEFF(PID) ;CLEAR CLOCK FLAG
SETOM TIMEF(PID) ;SET TIME FLAG. CLOCK HAS TICKED.
MOVE TAC,OTHERID(PID)
SOS PALIVE(TAC)
MOVEI TAC,30
MOVEM TAC,PALIVE(PID)
MOVE TAC,MIDNIT ;TAC←NUMBER OF TICKS/DAY
CAMLE TAC,TIME(PID) ;IS TIME OF DAY PAST MIDNIGHT?
JRST CIP2 ;NO.
MOVN TAC,TAC
ADDB TAC,TIME(PID) ;DECREMENT TIME BY NUMBER OF TICKS/DAY
CAILE TAC,-1 ;RESULT SHOULD BE A SMALL NUMBER OF TICKS
HALT .+1 ;LOSE! TIME IS OUT OF JOINT.
CIP3: MOVEI IOS,0 ;IOS←0 (FOR DIVI BELOW)
AOS TAC,THSDAT(PID) ;INCREMENT DAY
IDIVI TAC,=31 ;TAC1←DAY OF MONTH -1
DIVI IOS,=12 ;IOS←YEAR-1964, TAC←MONTH-1 (0=JAN)
LDB TAC,PMONTB ;TAC←NUMBER OF DAYS IN MONTH-1
CAIL TAC,(TAC1) ;SKIP IF PAST THE END OF THE MONTH.
JRST CIP2 ;(STILL INSIDE OF THIS MONTH)
CAIN TAC,=27 ;SKIP IF THIS IS NOT FEB.
TRNE IOS,3 ;FEB. SKIP IF LEAP YEAR
JRST CIP3 ;ADVANCE THSDAT TO FIRST OF NEXT MONTH
CAIE TAC1,=28 ;ALLOW FEB 29 TO EXIST
JRST CIP3 ;ADVANCE TO MARCH 1.
CIP2: SOSGE CHKYET(PID) ;COUNTDOWN TO NEXT CHECKSUM TIME.
PUSHJ P,CHKNOW ;GO CHECK THE CHECKSUM
JUMPN PID,CIPZZ1 ;P2 TAKES TWO GIANT STEPS
JRST CIP2A ;(HISYS)
;P1 CLOCK LEVEL.- CIP2A
HISYS
CIP2A: SOSLE T15CNT ;TIME TO CHECK FOR AUDIO SWITCH?
JRST CIP2B ;NO.
MOVEI TAC1,JIFSEC/4 ;REPEAT THIS 4 TIMES PER SECOND.
MOVEM TAC1,T15CNT
PUSHJ P,ASSCN ;SEE IF ANY AUDIO SWITCH WORK TO BE DONE(TTYSER)
CIP2B: SOSLE HNGTIM ;TIME TO RUN THE 1 SECOND CLOCK?
JRST CIP2D ;NO
MOVEI TAC,JIFSEC ;RESET COUNT TO CHECK EVERY SECOND.
MOVEM TAC,HNGTIM
PUSHJ P,DEVCHK ;GO CHECK FOR HUNG IO DEVICES
MOVE TAC,TIME ;GET CURRENT TIME
IDIVI TAC,=60 ;AND CONVERT IT TO SECONDS
HRL TAC,THSDAT ;PUT DATE IN LEFT HALF
MOVEM TAC,TIMDAT ;SAVE <DATE>,,<TIME IN SECS>
NOKL10,<
CONSZ PTP,200 ;SKIP IF KEY NXM STOP IS OFF.
JRST CIP2C ;IS OK.
PUSHJ P,DISMES
ASCIZ /TURN NXM STOP ON!
/
PUSHJ P,DISFLUSH ;MAKE SURE HE SEES THE MESSAGE BEFORE WE STOP.
CONSO PTP,200
JRST .-1 ;WAIT UNTIL SOMEONE NOTICES.
>;NOKL10
CIP2C:
CONI DKB,TAC ;STATIC ELECTRICITY CAUSES SCANNER TO LOSE PIA.
ANDI TAC,7
CAIE DKB,SCNCHN
CONO DKB,10!SCNCHN
IFN FTDDSTAT,<
SOSLE NDSTAT ;TIME FOR DD STATISTICS?
JRST CIP2D ;NO. CHECK THE SCANNER NEXT
MOVEI TAC,5 ;HERE EVERY 5 SECONDS
MOVEM TAC,NDSTAT
MOVE TAC,NDDXCT ;GET NEW COUNT
EXCH TAC,NDDXOL ;STORE AS OLD COUNT
SUB TAC,NDDXOL ;OLD COUNT - NEW COUNT. RESULT NEGATIVE
MOVN TAC,TAC
CAMLE TAC,NDDXMX ;BIGGER THAN OLD MAX?
MOVEM TAC,NDDXMX ;YES. STORE NEW MAX.
MOVE TAC,NDDLCT ;GET NEW COUNT
EXCH TAC,NDDLOL ;STORE AS OLD COUNT
SUB TAC,NDDLOL ;OLD-NEW. RESULT IS POSITIVE.
CAMLE TAC,NDDLMX ;BIGGER THAN OLD MAXIMUM?
MOVEM TAC,NDDLMX ;YES. STORE NEW MAX.
> ;END FTDDSTAT
CIP2D: HGMAC (21)
SOSLE FSCKCT
SKIPE FSNCLK
PUSHJ P,FSCLK ;THINK ABOUT FREE STORAGE.
SKIPLE SPFSNT
PUSHJ P,SFSCLK ;REPLENISH SPARE LISTS IF NECESSARY
PUSHJ P,DPYCLK ;MAINTAIN DISPLAYS. DPYSER CLOCK QUEUE
IFN IMPSW,< HGMAC (23)
PUSHJ P,IMPCLK>
HGMAC (14)
MOVEI PID,P1PID ;MAKE SURE PID STAYS HONEST.
HGMAC (16)
MOVE TAC,OTHERID(PID)
SKIPE P2NUM
SKIPGE PALIVE(TAC)
PUSHJ P,JLCAL ;RECOMPUTE PRIORITIES IF P2 IS DEAD.
SKIPE ORDYET
PUSHJ P,ORDER ;SORT RUNQ BY PRIORITY ORDER.
HGMAC (0)
IFN FTBAT,<
SOSG BATYET ;TIME TO SEE ABOUT PHANTOMS?
PUSHJ P,BATCLK ;YES.
>;FTBAT
CONI TV,SPWBUT ;READ THE SPACEWAR BUTTONS
SKIPE SPWGO ;ONLY RUN SPACEWAR IF SOMEONE WANTS IT
PUSHJ P,SPWP1 ;SEE IF SOMEONE WANTS P1 SPACEWAR.
MOVE TAC,OTHERID(PID);PICK UP ADDRESS OF P2'S DATA AREA
SKIPGE PALIVE(TAC) ;IS SIX RUNNING?
PUSHJ P,WHOSER ;APPARANTLY NOT. REFRESH WHO LINE.
SKIPN P2NUM ;DOES P2 EXIST?
JRST CRKT2 ;NO, FORGET IT
SKIPE PARFLG ;PARITY ERROR ON P2?
PUSHJ P,PARCLK ;YES. CALL PARITY ERROR SERVICE
SKIPN DAT,CRKDAT ;DOES P2 HAVE A NEW, GOOD DATE AND TIME?
JRST CRKT1 ;NO (DATES AREN'T ZERO)
MOVE ITEM,CRKTIM ;PICK UP TIME OF DAY
MOVEM ITEM,TIME(PID) ;UPDATE TIME OF DAY
MOVEM DAT,THSDAT(PID) ;UPDATE DATE
SETZM CRKDAT ;CLEAR DATE FLAG
CRKT1: SKIPE PTRADV ;RUN CLOCKS FOR PTR,PTP,AD AND XGP
PUSHJ P,PTRP1 ;SERVE PTR
IFE PLTNUM,<
SKIPE PTPSID
PUSHJ P,PTPP1 ;SERVE PTP
>
IFG PLTNUM,<
PRINTX FLUSH ABOVE HERE!
PUSHJ P,PTPP1 ;PTP/PLT P1 CLOCK.
>
SKIPE XGPP1F
PUSHJ P,XGPP1 ;SERVE XGP
SKIPE ADCP1L
PUSHJ P,ADCP1 ;SERVE ADC
SKIPE DACP1L
PUSHJ P,DACP1 ;SERVE DAC
IFG ADNUM,< SKIPLE ADADV
PUSHJ P,ADP1 >;IFG ADNUM
CRKT2: HGMAC (0)
MOVE TAC,DISPTR ;FLUSH DISASTER BUFFER IF NEEDED.
CAME TAC,DISOPT ;ANYTHING IN THE DISASTER BUFFER?
PUSHJ P,DISOUT ;YES, GO EMPTY IT
HGMAC (11)
JRST CRKT4 ;JUMP (TO LOSYS)
;CIPZZ1, CRKT4, CIP4, P2 CLOCK ROUTINES, CLOCK QUEUE
LOSYS ;BOTH PROCESSORS HERE
CIPZZ1: SKIPP2
HALT .
PUSHJ P,JLCAL ;P2 ONLY HERE. CALCULATE JOB LOADING
PUSHJ P,SPWP2 ;DO SPACEWAR
PUSHJ P,WHOSER ;CALCULATE WHO LINES
PUSHJ P,PTRP2 ;KEEP PAPERTAPE READER ALIVE
PUSHJ P,PTPP2 ;KEEP TAPE PUNCH/PLOTTER GOING
IFG ADNUM,< PUSHJ P,ADP2 ;AND THE AD >
SOSG XGPP2F ;COUNT DOWN TO RUN XGP CLOCK LEVEL.
PUSHJ P,XGPP2 ;AND THE XGP
PUSHJ P,ADCP2 ;RUN ADC CLOCK
PUSHJ P,DACP2 ;AND DAC CLOCK
SOSL CRKYET ;TIME TO READ THE CROK AGAIN?
JRST CRKT4 ;NO, SKIP IT
MOVEI TAC,=3600*5 ;SET FOR 5 MINS
MOVEM TAC,CRKYET
MOVEI TAC1,5 ;WE WILL TRY FIVE TIMES
PUSHJ P,DAT2 ;READ PETIT CROCK
JRST CRKT4 ;NO, CRK SICK
MOVEM ITEM,CRKTIM ;UPDATE TIME OF DAY
MOVEM DAT,CRKDAT ;UPDATE DATE
;PROCESS CLOCK QUEUE - BOTH PROCESSORS.
CRKT4: HGMAC (17)
HRRZ DAT,CLOCK(PID) ;GET END OF LIST
CIP4: CAIG DAT,CIPWT-1(PID);END YET?
JRST CIP5 ;YES
SOS TAC1,(DAT) ;DECREMENT TIMING REQUEST
TRNE TAC1,7777 ;TIME EXPIRED YET?
SOJA DAT,CIP4 ;NO, CONTINUE SCAN
CONO PI,PIOFF ;YES, MOVE LAST ITEM IN LIST TO THIS
MOVE TAC,@CLOCK(PID)
SOS CLOCK(PID)
MOVEM TAC,(DAT)
CONO PI,PION
LDB TAC,[POINT 6,TAC1,23] ;GET 6 BIT DATA ITEM.
HLRZ TAC1,TAC1 ;SETUP DISPATCH ADDRESS
CAIL TAC1,CHKBEG ;DISPATCH MUST BE WITHIN CHECKSUMMED REGION
CAILE TAC1,CHKEND
CAIA ;OUT OF RANGE
JRST CIP5AA ;IN RANGE, GO DO IT.
IFN FTHSYS,<
CAIL TAC1,400000
CAIL TAC1,HIEND
CAIA
JUMPE PID,CIP5AA
>
PUSH P,DAT
PUSH P,TAC1
PUSHJ P,DISMES ;ILLEGAL ADDRESS FOR CLOCK REQUEST
ASCIZ /ILL ADR FOR CLK REQ = /
POP P,TAC
PUSHJ P,DISLOC
PUSHJ P,DISCRLF
POP P,DAT
JRST CIP5A
CIP5AA: PUSH P, DAT ;SAVE ONLY VALUABLE AC
IFN FTHG,< PUSH P,HGCODE
HGMAC (22) >
PUSHJ P,(TAC1) ;AND DISPATCH TO TIMING REQUEST ROUTINE
IFN FTHG,< POP P,HGCODE >
POP P,DAT
CIP5A: SOJA DAT,CIP4 ;GO BACK FOR MORE REQUESTS
CIP5: JUMPN PID,CIP6A ;P2 AVOIDS COMMAND, NXTJOB
MOVE TAC,TIME
TRNE TAC,3 ;SKIP IF THIS IS THE FOURTH TICK
JRST CIP11
MOVEI J,JOBN-1 ;DECREMENT PROTECT TIME
CNTCPT: SOSG JBTICP(J)
JRST CNTCP1
MOVM TAC,JOBQUE(J)
CAIE TAC,TQ
CAIN TAC,RUNQ
JRST CNTCP1
CAIE TAC,DIOWQ
SOS JBTICP(J) ;COUNT 2 TICKS PER TICK FOR NOT RUNNING
CNTCP1: SOJG J,CNTCPT
JRST CIP11 ;TO HISYS
;CIP11, SPWCHK, SP2CHK
HISYS
SPWCHK: SKIPA TAC1,[,SPWGO(J)]
SP2CHK: MOVE TAC1,[,SP2GO(J)]
SETZ J,
MOVSI TAC,SPWERB ;LOOK FOR ANY SPACEWAR MODE ERRORS
LDB J,[POINT 6,@TAC1,5]
TDNN TAC,JBTST2(J)
JUMPN J,.-2
JUMPE J,CPOPJ
JRST SPWMES
CIP11: SKIPE SPWGO
PUSHJ P,SPWCHK
SKIPE SP2GO
PUSHJ P,SP2CHK
HGMAC (1)
SKIPG COMCNT ;ANY COMMANDS TO PROCESS?
JRST CIP11A
PUSHJ P,PSHMAP ;SAVE STATE OF MAP
PUSHJ P,COMMAND ;YES, CALL COMMAND DECODER.
PUSHJ P,POPMAP ;RESTORE THE MAP
CIP11A: HGMAC (6)
PUSHJ P,NXTJOB ;CALL SCHEDULER
HGMAC (15)
IFN FTSTAT,< MOVEI TAC,JOBSTA ;TRANSMIT NEXT JOB NUMBER TO RUN
CAME J,JOB(PID) ;DON'T RETRANSMIT SAME JOB NUMBER AGAIN
PUSHJ P,STAPUT >;IFN FTSTAT
JUMPN J,CLKSRJ ;IF NULL JOB RUNS NEXT, DO FOLLOWING TEST.
MOVE AC1,[-RUNQ,,-RUNQ]
MOVE AC2,[-TQ,,-TQ]
CAMN AC1,JBTQ-RUNQ
CAME AC2,JBTQ-TQ
AOSA NJRNULLS ;COUNT WASTED TIME. OTHER JOBS WANT TO RUN
JRST CLKSRJ ;NOT WASTED
MTRON (MTRWST) ;COUNT WASTED TIME
JRST CLKSRX
CLKSRJ: MTROFF (MTRWST) ;THIS ISN'T A WASTED TICK
CLKSRX: MOVEI TAC1,1 ;THIS BIT WILL REPRESENT THE NEW JOB
SETZ TAC, ;SOMEWHERE IN TAC OR TAC1
LSHC TAC,(J) ;MOVE BIT TO APPROPRIATE POSITION
IORM TAC,JBSRUN ;AND NOTE THIS JOB HAS BEEN RUN LATELY
IORM TAC1,JBSRUN+1
JRST CIP6B ;(LOSYS)
;CIP6A, CIP6B, NULJOB, S2U, U2S - CONTEXT SWITCHING
LOSYS
;S2U AND U2S -- MOVE DATA BETWEEN PROTECTED USER CORE AND USRPRT.
;(S2U ALSO CALLED FROM ANYACT)
↑S2U: MOVSI TAC,USRPRT(PID) ;FROM SYSTEM COPY OF JOBDAT
HRRI TAC,JOBPRT ;TO USER'S JOBDAT WHILE NOT RUNNING.
SKIPGE USRHCU(PID) ;SAVGET IO HAPPENING?
JRST S2U1 ;
XCTR XBLTW,[BLT TAC,JOBJDA+17] ;MOVE SYSTEM TO USER.
POPJ P,
S2U1: XCTR XBLTW,[BLT TAC,JOBPC] ;STORE ONLY JOBCHU AND JOBPC.
POPJ P,
U2S: MOVSI TAC,JOBPRT ;FROM USER'S JOBDAT
HRRI TAC,USRPRT(PID) ;TO SYSTEM'S PROTECTED COPY
XCTR XBLTR,[BLT TAC,USRJDA+17] ;MOVE USER TO SYSTEM
POPJ P,
;PREPARE TO RETURN TO USER JOB. (POSSIBLY SWITCHING JOBS)
CIP6A: MOVEI J,0 ;HERE ON P2. RUN THE NULL JOB.
CIP6B: SETZM SCHEDF(PID) ;CLEAR FORCED SCHEDULING FLAG
SETZM TIMEF(PID) ;CLEAR "CLOCK FIRED" FLAG
JUMPN PID,CIP8 ;NO JOB SWITCHING ON P2
CAMN J,JOB(PID) ;IS NEXT JOB SAME AS LAST ONE?
JRST CIP8 ;YES, JUST RESTORE ACS AND DISMISS
SKIPE J ;ARE WE SWITCHING TO THE NULL JOB?
AOS NJSWITCHES ;NO, MARK ANOTHER SWITCHING
MOVE TAC1,JOB(PID) ;SAVE SOFTWARE STATE. GET OLD JOB
MOVE TAC,TIMDAT ;GET <DATE>,,<TIME IN SECS>
MOVEM TAC,FTIME(TAC1) ;AND SAVE FOR JOB THAT JUST RAN
SKIPLE TAC,JOB(PID) ;SKIP IF THERE WAS NO OLD JOB
SKIPN JBTPAG(TAC) ;OLD JOB EXISTED. SKIP IF IT STILL HAS CORE
JRST NULJOB ;IF NO OLD JOB OR NO CORE, THEN DON'T
PUSHJ P,S2U ; PUT CHANNEL ASSIGNMENTS BACK IN USER CORE
↑NULJOB: ;HERE FROM SYSINI WITH J←0
MOVEM J,JOB(PID) ;STORE NEW CURRENT JOB NUMBER
SKPKL
CONO APR,550+APRCHN ;CLEAR APR ENABLED FLAGS
HLLZS APRIN1(PID) ;DISABLE USER APR INTERRUPTS
SETZM APRIN3(PID)
JUMPE J,CIP8X ;JUMP IF SWITCHING TO NULJOB (P2 JUMPS)
PUSHJ P,APRMAP ;P1. NOT THE NULL JOB. SETUP THE MAP
HLRZ TAC,JBTPAG(J)
LSH TAC,9
SUBI TAC,1
XCTR XW,[HRRZM TAC,JOBREL] ;LET USER SEE HIS PROTECTION IN JOBREL
PUSHJ P,U2S ;MOVE USER TABLE INTO SYSTEM
IFKL10,<PUSHJ P,CSHSET ;TURN ON CACHE FOR THIS JOB >
JRST CIP8A7 ;MAP ALREADY SETUP.
CIP7XX: PUSHACS ;A BUG TRAP.
PUSHJ P,DISMES
ASCIZ /RUNNING JOB WITH NO CORE. /
MOVSI TAC,RUN
ANDCAM TAC,JBTSTS(J)
PUSHJ P,DISJOB
PUSHJ P,DISCRLF
PUSHJ P,DISFLUSH
POPACS
PUSHJ P,WDDTCAL
SETZB J,JOB(PID) ;FALL INTO NULL JOB.
SETOM NULBAD(PID)
JRST CIP8
;RESTORE HARDWARE STATE OF NEW JOB - CIP8
CIP8X: SETOM NULBAD(PID) ;SWITCH TO (RESTART) NULL JOB.
CIP8: JUMPE PID,CIP8A
JUMPE J,CIP8A6
SETZB J,JOB(PID) ;P2 IS ALLOWED ONLY THE NULL JOB.
SETOM NULBAD(PID)
CIP8A6:
IFE FTP2PAG,<
DATAO APR,[0] ;HERE TO RUN THE NULL JOB ON THE PDP-6
>;NOT FTP2PAG
IFN FTP2PAG,<
PUSHJ P,APRMAP ;SETUP MAP
>;FTP2PAG
JRST CIP8A8
;CIP8A - ON P1 TO CONTINUE A JOB, OR TO INITIATE THE NULL JOB
CIP8A: PUSHJ P,APRMAP ;SETUP MAP
JUMPE J,CIP8A8 ;FOR NULL JOB, AVOID SETTING UP INTERRUPTS
CIP8A7: MOVE TAC,JBTIEN(J) ;PICK UP USER INTERRUPT ENABLINGS
ANDI TAC,CPUMSK ;CONS,PDLOV,NXM,MPV,FOV,OV. NOT CLOCK!
MOVEM TAC,APRIN2(PID) ;SET SO CH3 CAN TEST FOR THEM
XCTR XR,[IOR TAC,JOBENB] ;NOW INCLUDE OLD-STYLE INTS
ANDI TAC,CPUMSK!1000 ;SYSTEM ENABLED FOR PDL OV, ILM, NXM, CLK
PUSHJ P,APREN2 ;(IN APRENB UUO. SETUP APR, TRAP LOCS)
CIP8A8: SETOM STIME(J) ;MARK CORE IMAGE HAS BEEN RUN (AND MODIFIED)
IFN FTSCNBUG <
JUMPN PID,.+2 ;DON'T LET P2 USE BUG TRAP
JSR CH7CHK ;BUG TRAP FOR STATE OF SCANNER CHANNEL
>;FTSCNBUG
LDB TAC,PSEGN ;AND MARK HIGH SEGMENT TOO
MOVE TAC1,JBTSTS(TAC) ;IF IT IS NOT WRITE-PROTECTED
TLNN TAC1,JWP
SETOM STIME(TAC) ;IF WRITE-ENABLED, MARK AS MODIFIED.
SKIPE JBTPAG(J) ;SKIP IF THERE IS NO JOB DATA AREA
JUMPE PID,CIP8B ;NOT THE NULL JOB. RUN JOB IF THIS IS P1.
SKIPE NULBAD(PID) ;NO. IT'S THE NULL JOB. IS IT SICK?
JRST NULJB ;YES, GO START IT UP AGAIN
MOVEI TAC,NULDAT(PID) ;HERE TO CONTINUE RUNNING THE NULL JOB
MOVE TAC,JOBD17(TAC)
MOVEM TAC,CLKS17(PID)
JUMPE PID,CIP8C
MOVSI 17,JOBDAC+NULDAT(PID) ;RESTORE DUMP ACS
BLT 17,16 ;THIS WAY OUT FOR P2
MOVEI 17,P2PID
SKIPE APRERR(17)
JRST CLKERR
DATAO PI,[400000,,0]
MOVE 17,CLKS17(17)
JRST 12,@USRPC+P2PID
HISYS
CIP8C: ;HERE TO CONTINUE NULL JOB ON P1.
NOKL10,<DATAO PI,[400000,,0] >;NOKL10
IFKL10,<DATAO KLPAG,[401000,,0] ;AC BLOCK 1. PREV IRRELEVANT >;IFKL10
MOVSI 17,JOBDAC+NULDAT+P1PID ;RESTORE DUMP ACS
BLT 17,16
MOVEI 17,P1PID
SKIPE APRERR(17) ;ERROR IN THE EXEC?
JRST CLKERR ;YES. GO PROCESS.
MOVE 17,CLKS17(17)
JEN @USRPC+P1PID ;RETURN TO USER.
CIP8B: XCTR XR,[MOVE TAC,JOBD17] ;RUN A JOB (NOT JOB 0) ON P1.
MOVEM TAC,CLKS17(PID)
IFKL10,<
MOVE TAC,USRPC+P1PID ;GET PC WE'RE ABOUT TO RETURN TO
TLNN TAC,USRMOD
DATAO KLPAG,[400100,,0] ;BACK TO EXEC MODE
TLNE TAC,USRMOD
DATAO KLPAG,[401000,,0] ;BACK TO USER MODE, PREV IRRELEVANT
>;IFKL10
NOKL10,<
MOVN J,J ;READY TO RUN THAT JOB.
MOVSI TAC,400000 ;UNARY BUT AMBIGUOUS DISPLAY OF JOB NUMBERS
ROT TAC,(J)
DATAO PI,TAC ;DISPLAY JOB NUMBER.
>;NOKL10
MOVSI 17,JOBDAC ;RESTORE DUMP ACS
XCTR XBLTR,[BLT 17,16] ;MOVE DUMP ACS TO PHYSICAL ACS.
MOVEI 17,P1PID
SKIPE APRERR(17) ;ERROR IN THE EXEC?
JRST CLKERR ;YES. GO PROCESS.
MOVE 17,CLKS17(17) ;RESTORE LAST AC.
JRST 12,@USRPC+P1PID ;RETURN TO USER.
;THE NULL JOB - NULJB NULP1, NULP2
;RUNS IN ACS IN USER MODE.
LOSYS
NULJB: SETZM NULBAD(PID)
JUMPN PID,NULP2
DATAO KLPAG,[401000,,0] ;SET CURRENT AC BLK = 1, PREV IRRELEVANT
MOVSI 17,NULJP1 ;SET UP BLT TO ACCUMULATORS
BLT 17,NULP1X ;BLT IN ZINGHEIM'S NULL JOB
JRST 12,@[USRMOD,,1] ;DISMISS IF INTERRUPT IN PROGRESS
NULP2: DATAO PI,[400000,,0] ;DISPLAY US IN LITES
MOVSI 17,NULJP2
BLT 17,NULP2X
JRST 12,@[USRMOD,,1]
NULJP1: 0
ROT 0,-1 ;RING AROUND THE ACCUMULATOR
TLNN 0,200000
TLC 0,400000
MOVEI 10,70000
SOJGE 10,5
JRST 1
NULP1X←←.-NULJP1
NULJP2: 0
ROT 0,1 ;RING AROUND THE ACCUMULATOR
TRNN 0,2
TRC 0,1
IFL PRCONF-2,< MOVEI 10,34000 >;SHORT COUNT FOR PDP-6
IFE PRCONF-2,< MOVEI 10,70000 >;LONG COUNT FOR KA10
SOJGE 10,5
XCT SIXRUN ;TRAP IF CORE GETS CLEARED
JRST 1
NULP2X←←.-NULJP2
;CHECK, CHKNOW
;18-BIT FOLDED CHECKSUM ROUTINE.
;CALL WITH AOBJN POINTER IN TAC. RETURNS CHECKSUM IN TAC1.
↑CHECK: MOVEI TAC1,0 ;INITIALIZE SUM
JCRY0 .+1 ;CLEAR CARRY 0 FLAG
ADD TAC1,(TAC) ;FORM THE SUM.
JCRY0 [AOJA TAC1,.+1] ;IN CASE OF CARRY 0, INCREMENT SUM
AOBJN TAC,.-2
HLRZ TAC,TAC1 ;TAC←LH OF SUM
HRRZ TAC1,TAC1 ;TAC1←RH OF SUM
ADD TAC1,TAC ;TAC1←FOLDED SUM
TLZE TAC1,1 ;INCASE OF HIGH ORDER CARRY,
ADDI TAC1,1 ;INCREMENT.
POPJ P,
CHKNOW: MOVEI TAC1,=300*JIFSEC ;CHECKSUM EVERY 5 MINUTES
MOVEM TAC1,CHKYET(PID)
PUSHJ P,SYSFIX ;CHECK FOR ERROR AND FIX
POPJ P, ;NO ERRORS
JFCL ;ERROR, BUT CAN'T FIX, FIX CHECKSUM.
MOVE TAC,MONPTR ;RECOMPUTE CHECKSUM
PUSHJ P,CHECK
MOVEM TAC1,MONSUM
IFN FTHSYS,<
JUMPN PID,CPOPJ
MOVE TAC,HMNPTR
PUSHJ P,CHECK
MOVEM TAC1,HMNSUM
>;IFN FTHSYS
POPJ P,
BEGIN SYSFIX ;VERIFY SYSTEM CHECKSUM AND FIX IT IF WRONG.
; ROUTINE TO RE-READ THE PROTECTED PART OF THE MONITOR FROM LIBRASCOPE
; CALLED BY:
; PUSHJ P,SYSFIX
; <NO ERRORS>
; <ERROR, BUT COULDN'T FIX>
; <ERRORS FIXED>
↑↑SYSFIX:
PUSH P,TAC
PUSH P,TAC1
MOVE TAC,MONPTR
PUSHJ P,CHECK ;CHECKSUM MONITOR
CAME TAC1,MONSUM ;IS IT OK?
JRST NOTOK
IFN FTHSYS,<
JUMPN PID,SYSFX1
MOVE TAC,HMNPTR
PUSHJ P,CHECK
CAME TAC1,HMNSUM
JRST NOTOK
>
SYSFX1: POP P,TAC1
POP P,TAC
POPJ P, ;ALL IS WELL
NOTOK: POP P,TAC1
POP P,TAC
↑↑SYSCHK:
PUSHACS
IFN FTDDT,< SKIPE DDTFLG ;IS P1 IN DDT NOW?
JUMPN PID,SIXFIX ;YES. IF THIS IS P2, SAY NOTHING! >
PUSHJ P,DISMES
ASCIZ /⊗π⊗π⊗π⊗MONITOR CHECKSUM FAILURE.
/
JUMPN PID,SIXFIX ;THE PDP-6 CANT FIX ANYTHING
; CONSO DSK,1B27 ;IS THERE ANY DISK TODAY?
; SKIPN SYSTHERE ;IS THIS SYSTEM OUT THERE?
JRST NOFIX
JRST GOFIX ;ATTEMPT TO FIX ERRORS
SIXFIX: SETZM CHKYET+P1PID ;TELL THE PDP-10 TO LOOK SOON
NOFIX: POPACS ;IF DISK IS OFF-LINE, NOTHING WE CAN DO.
JRST CPOPJ1 ;TELL THEM NOTHING FIXED!
GOFIX: SETOM ERRYET
REPEAT 0,< ;12/1/73
CONI APR,TAC ;THE REMEMBER STATE OF SYS REF KLUGE
PUSH P,TAC ;THE ONLY WAY OUT GOES THRU FIXXIT
DATAO PTR,[0] ;SHUT OFF THE SYS REF KLUGE.
>
CONSO IOP,777770 ;IF NO BITS ON, IS IDLE.
JRST IOPOK
MOVSI UUO,1
CONSO IOP,IOPJDN!IOPANY;IF JOB DONE, OR ANY ERROR IS UP, IS OK
SOJG UUO,.-1 ;IF OTHER BITS ON BUT NOT JOB DONE, OR ERROR WAIT FOR IT
IOPOK: CONI IOP,IOPSAV# ;SAVE THE STATUS OF THE IOP
SKIPN UUO,MONPTR ;IOWD FOR THE PROTECTED PART OF THE MONITOR
JRST FIXXIT ;IF NOT SET UP YET, FORGET IT! (WHEREDAFUCKAREWE)
HRRZ AC1,UUO
LSH AC1,-5 ;THIS SHOULD BE THE STARTING SECTOR COUNT
MOVEI AC2,37
AND AC2,UUO ;GET OFFSET FOR FIRST 40 WORDS
SUBI AC2,FIXLEN ;AND THAT LEAVES....
;READ FIXLEN WORDS AT A TIME AND COMPARE WITH MEMORY
DONXT: MOVEI AC3,40 ;WE WILL TRY THIS MENY TIMES
DOAGIN: CONO IOP,0
CONO DSK,14000
DATAO IOP,[XWD -FIXLEN,FIXBUF]
PUSH P,AC1 ;SAVE SECTOR #
CAIL AC1,2300 ;WRAP TO NEXT TRACK?
ADDI AC1,1B24-2300 ;YES, ADJUST
ADD AC1,SYSBAND
DATAO DSK,AC1
POP P,AC1 ;RESTORE SECTOR #
CONSO IOP,IOPANY!IOPJDN;WAIT FOR IOP TO FINISH
JRST .-1
CONSO IOP,IOPANY ;ANY ERRORS?
CONSZ DSK,3370
SOJG AC3,DOAGIN
JUMPLE AC3,FIXXIT
CHKWRD: AOJG AC2,NXTCHK
MOVE AC3,FIXBUF+FIXLEN-1(AC2)
CAME AC3,(UUO)
JRST PRNDIF ;TELL THE WORLD!
STRDON: AOBJN UUO,CHKWRD
AOSLE TAC,ERRYET ;DONE WITH CHECK.
JRST FIXXTB ;THERE WERE ERRORS.
PUSHJ P,DISMES
ASCIZ /NO ERRORS FOUND.
/
JRST FIXXIT
FIXXTB: PUSHJ P,DISDCP
PUSHJ P,DISMES
ASCIZ / ERRORS.
/
FIXXIT: MOVE UUO,IOPSAV ;SUCCESS. NOW TRY TO PUT THE WORLD BACK.
TRNE UUO,IOPJDN ;IF JOB DONE IS ON, PUT UP DATA MISSED ALSO
TRO UUO,IOPMIS ;TO DO PREVIOUS TRANSFER OVER FOR GOOD MEASURE
CONO IOP,(UUO) ;SINCE WE FORGET THAT THERE WAS AN ERROR
REPEAT 0,<
POP P,TAC ;RESTORE STATE OF SYS WR REF KLUGE
TRNE TAC,SWRENB ;WAS KLUGE ENABLED?
DATAO PTR,[1] ;YES. IT WAS. TURN IT BACK ON.
>
POPACS
JRST CPOPJ2
PRNDIF: PUSHACS
AOSLE TAC,ERRYET
JRST PRNDF1
PUSHJ P,DISMES
ASCIZ /LOC CORE DISK
/
MOVEI TAC,0
PRNDF1: CAIL TAC,10 ;ONLY PRINT THE FIRST 8 ERRORS
JRST PRNDF2
MOVEI TAC,(UUO)
PUSHJ P,DISLOC
PUSHJ P,DISMES
ASCIZ / /
MOVE TAC,(UUO)
PUSHJ P,DISOCT
PUSHJ P,DISMES
ASCIZ / /
MOVE TAC,AC3
PUSHJ P,DISOCT
PUSHJ P,DISCRLF
PRNDF2: POPACS
MOVEM AC3,(UUO) ;FIX THE SYSTEM!
JRST STRDON ;AND CONTINUE LOOKING.
NXTCHK: ADDI AC1,FIXNUM
MOVNI AC2,FIXLEN ;THIS MANY WORDS FROM NOW ON!
JRST DONXT
BEND SYSFIX
;INTRUN - THE (MOORER) USER INTERRUPT HANDLER
HISYS
↑INTRUN:SETZB AC1,INTREQ(PID)
EXCH AC1,APRIN3(PID) ;GET CORRECT PC, IF APR TRAP (SEE APRERV)
SKIPE AC1 ;SKIP IF NOT AN APR TRAP
MOVEM AC1,USRPC(PID) ;STORE INTERRUPT PC (NOT JOBTM5)
PUSHJ P,PSHMAP ;SAVE STATE OF MAP
PUSH P,USRSAV(PID) ;MAY HAVE INTERRUPTED UUOCON BEFORE IT'S REENTRANT
PUSH P,UUO0(PID) ;THE UUO LOCATION
PUSH P,@UUOLOC(PID) ;THE UUO ITSELF
MOVE AC1,JOB(PID) ;JOB NUMBER THAT WAS INTERRUPTED TO RUN THIS INT.
MOVEM AC1,SJOB(PID) ;SAVEIT FOR LATER.
PUSH P,@CLKCH(PID) ;SAVE CLKINT DATA BECAUSE IT IS NOT REENTRANT
PUSH P,CLKS17(PID) ;
PUSH P,SCHEDF(PID)
PUSH P,APRPC(PID) ;SAVE ANY APR ERRORS - I-PROCESS MAY MAKE NEW ONES
PUSH P,APRERR(PID)
PUSH P,APRIN1(PID)
MOVSI AC1,USRPRT(PID) ;SAVE USER CHANNEL TABLE. (SOURCE)
HRRI AC1,1(P) ;(DESTINATION)
MOVEI AC2,USRJDA+20-USRPRT(P) ;(ENDING ADDRESS OF BLT)
BLT AC1,(AC2)
ADD P,[USRJDA+20-USRPRT,,USRJDA+20-USRPRT]
SETOM INTACT(PID) ;WE ARE NOW AT INTERRUPT LEVEL
INTSC1: MOVEI J,JOBN-1 ;SCAN JOBS LOOKING FOR ONE WITH AN INTERRUPT.
INTR2: SKIPN AC1,JBTIRQ(J) ;INTERRUPT WAITING HERE?
INTR1: SOJG J,.-1 ;NO
JUMPE J,INTXIT ;IF NONE AT ALL, GO AWAY
JUMPL J,INTSCR ;(BUG TRAP)
PUSHJ P,GETINT ;GET THE BIT CORRESPONDING TO THE INTERRUPT
JRST INTR1 ;ALL MASKED OUT, LOOP BACK FOR NEXT GUY
MOVE AC2,JBTSTS(J)
TLNN AC1,INTSWW!INTSHW ;IF THIS IS A SHUFFLE OR A SWAP INTERRUPT,
TLNN AC2,SWP!SHF ; THE JOB IS REALLY THERE!
SKIPN JBTPAG(J) ;IS THIS JOB INCORE?
JRST INTSWAPIN ;GET HIM SWAPPED IN IF NEEDED.
LDB AC3,PSEGN ;DOES HE HAVE AN UPPER?
JUMPE AC3,INTR11
MOVE AC2,JBTSTS(AC3) ;SEE IF UPPER IS IN CORE
TLNN AC1,INTSWW!INTSHW
TLNN AC2,SWP!SHF
SKIPN JBTPAG(AC3) ;SKIP IF SEGMENT IS INCORE
JRST INTSWS ;GET SEGMENT IN
INTR11: SKIPN JBTIIP(J) ;IS THIS JOB ALREADY AT I-LEVEL?
JRST INTR9 ;NO. - RUN THIS INTERUPT.
SETOM INTREQ(PID) ;WE'LL HAVE TO RUN THIS INT LATER.
JRST INTR1 ;CONTINUE SCAN.
INTSCR: ADD P,[5,,5] ;SO WE CAN LOOK AT PREV RETURN ADDRESSES
PUSHACS
PUSHJ P,DISMES
ASCIZ /J NEGATIVE AT INTR2
/
PUSHJ P,DISFLU
PUSHJ P,WDDTCAL
POPACS
SUB P,[5,,5]
JRST INTSC1 ;OVER FROM THE TOP.
;GETINT - GET FIRST SERVICABLE INTERRUPT BIT FROM WORD OF BITS.
; ENTER WITH COPY OF JBTIRQ IN AC1
; WILL RETURN SINGLE SERVICABLE BIT IN AC1
GETINT: MOVSI AC2,INTWAIT
TDNE AC2,JBTIEN(J)
JRST GTINT1 ;HERE IF TRYING TO FINISH UUO (VIA UWAIT)
MOVEI AC3,0
INTR8: JFFO AC1,.+1 ;GET FIRST BIT. SERVE INTERRUPTS ONLY ONE AT A TIME.
MOVN AC2,AC2
MOVSI AC1,(1B0)
LSH AC1,(AC2) ;AC1←LEFTMOST BIT IN JBTIRQ(J)
TDNE AC1,JBTMSK(J) ;IS THIS PROCESSOR ENABLED FOR THIS INTERRUPT?
JRST CPOPJ1 ;YES.
IORB AC1,AC3 ;AC3 ACCUMLATES INTS MASKED OFF ON THIS PROC
ANDCA AC1,JBTIRQ(J) ;AC1←ANY INTS PENDING (THAT AREN'T ALREADY MASKED)
JUMPN AC1,INTR8 ;JUMP IF SOME INTS ARE STILL PENDING.
POPJ P, ;NONE PENDING (EXCEPT THOSE MASKED OFF)
GTINT1: TDNN AC2,AC1 ;SKIP IF INTWAIT ENABLED AND REQUESTED
POPJ P, ;ENABLED BUT NOT REQUESTED YET
MOVE AC1,AC2
JRST CPOPJ1 ;DO INTWAIT INT FIRST
;INTR9, INTR14 ;CLEAR THE INTERRUPT BIT IN JBTIRQ AND START THE I-PROCESS
INTR9: MOVE AC1,JBTIRQ(J) ;GET INTERRUPT BITS AGAIN
PUSHJ P,GETINT ;GET BIT CORRESPONDING TO INTERRUPT
JRST INTR1 ;ALL MASKED OUT. SCAN OTHERS.
TDNN AC1,JBTIRQ(J) ;MAKE SURE INT IS THERE.
JRST INTR9 ;HUH? IT DISAPPEARED.
ANDCAM AC1,JBTIRQ(J) ;NOW WE HAVE SERVICED THIS INTERRUPT.
TDNN AC1,JBTIEN(J) ;IS THIS GUY ENABLED FOR THIS INTERRUPT?
JRST INTR2 ;NO, FORGET IT.
;THE FOLLOWING UP TO THE LABEL INTR14 IS PROBABLY UNNECESSARY.
SKIPN JBTIIP(J)
JRST INTR14
IORM AC1,JBTIRQ(J)
SETOM INTREQ(PID)
JRST INTR2 ;TRY TO GET BACK NEXT TICK
;INITIALIZE SYSTEM VARIABLES IN TO RUN THE USER I-PROCESS
INTR14: IORM AC1,JBTIIP(J) ;HE NOW HAS THIS INTERRUPT IN PROGRESS
PUSHJ P,APRMAP ;SETUP APR MAP
HLRZ TAC,JBTPAG(J)
LSH TAC,=9 ;NUMBER OF WORDS IN LOWER.
XCTR XR,[SKIPN AC3,JOBINT] ;DOES HE WANT INTS SOMEWHERE ELSE?
JRST INT14A ;NO
ADDI AC3,2 ;THIS MUST BE LEGAL, TOO
CAIL AC3,JOBPFI+2
CAIL AC3,(TAC)
JRST INTADC ;ILLEGAL ADDRESS. (MUST BE IN LOWER)
SKIPA AC2,AC3 ;ADDRESS FOR THE BITS -2
INT14A: MOVEI AC2,JOBCNI+2 ;OR HERE
XCTR XW,[MOVEM AC1,-2(AC2)] ;STORE INTERRUPT BITS IN USER CORE.
SKIPN AC2,AC3
MOVEI AC2,JOBAPR
XCTR XR,[HRRZ AC2,(AC2)] ;AC2←TRAP ROUTINE ADDRESS
CAIL AC2,JOBPFI
CAIL AC2,(TAC)
CAIA
JRST INTR10 ;TRAP ADDRESS IS LEGAL
LDB AC1,PSEGN ;SEE IF ADDRESS IS IN UPPER
JUMPE AC1,INTADC ;NO UPPER, ERROR
HLRZ AC1,JBTPAG(AC1)
LSH AC1,=9 ;UPPER'S WORD COUNT.
CAIGE TAC,400000 ;IF LOWER'S IS SMALLER THAN 400000
MOVEI TAC,400000 ; THEN UPPER STARTS AT 400000
ADD AC1,TAC ;AC1←FIRST NXM WORD ABOVE UPPER
CAIL AC2,400000 ;SKIP IF BELOW TOP OF UPPER.
CAIL AC2,(AC1)
JRST INTADC ;NOT WITHIN UPPER, ADDRESS CHECK
INTR10: PUSH P,UUOPC(J) ;SAVE HIS UUO LEVEL PC TOO
MOVEM J,JOB(PID) ;THIS IS OUR TEMPORARY JOB NUMBER
CAME J,SJOB(PID) ;MIGHT ALREADY BE THERE
PUSHJ P,U2S ;MOVE JOBJDA INTO THE SYSTEM
SETZM APRERR(PID) ;PREVIOUS JOB MAY HAVE HAD AN ERROR
SETZM APRPC(PID)
SETZM APRIN1(PID)
SETZM SCHEDF(PID)
SETOM STIME(J) ;MARK CORE IMAGE AS ALTERED NOW.
LDB AC1,PSEGN ;SEE IF WE MUST MARK UPPER
JUMPE AC1,INTR5 ;NONE THERE.
MOVE AC2,JBTSTS(AC1) ;SEE IF WRITE PROTECTED
TLNN AC2,JWP
SETOM STIME(AC1)
INTR5: MOVNI AC1,10 ;
MOVEM AC1,INTQUANT(PID) ;8 TICKS BEFORE TIMEOUT
MOVEI AC1,INTCH7
MOVEM AC1,INTDISP(PID) ;CLOCK INTS DISPATCH TO TIMER COUNTDOWN
MOVM AC1,JOBQUE(J) ;SEE IF HE IS WAITING FOR AN INTERRUPT
CAIE AC1,INTWQ
JRST INTWRJ
MOVE AC1,JBTIIP(J) ;DO WE WAKE HIM UP?
TDNN AC1,JBTWKM(J)
JRST INTWRJ ;NO
MOVNI AC1,TQ ;YES, WAKE HIM UP WITH HIGH PRIORITY
MOVEM AC1,JOBQUE(J)
PUSHJ P,REQUE
INTWRJ: MOVEM P,INTSP(PID) ;SAVE THE STACK POINTERS.
;CLKINT DOESN'T DEPEND ON ACCUMULATORS.
MOVE AC2,JBTIIP(J)
TLNN AC2,INTWAIT ;UWAIT? - GIVE THE UUO LEVEL ACS.
JRST INTR4 ;NOT UWAIT.
ANDCAM AC2,JBTIEN(J) ;NO LONGER ENABLED FOR INTERRUPT-WAIT
SKIPN AC2,AC3 ;(AC3=ADDRESS TO STORE CRUD)
MOVEI AC2,JOBTPC+1
MOVE AC1,USRPC(PID) ;GIVE HIM HIS MOST ACCURATE PC
XCTR XW,[MOVEM AC1,-1(AC2)]
MOVE AC1,JBTUPC(J) ;RESTART HIM JUST AFTER THE UWAIT UUO
TLO AC1,USRMOD ;MAKE SURE HE GETS INTO USER MODE
MOVEM AC1,UUO0(PID)
JUMPE PID,INTR15
MOVSI 17,JOBDAC ;GIVE HIM UUO-LEVEL ACS TO SAVE AWAY
BLT 17,17
JRST 12,@UUO0+P2PID
INTR15:
IFKL10,<
DATAO KLPAG,[401000,,0] ;USER GETS AC BLOCK 1
>
MOVSI 17,JOBDAC
XCTR XBLTR,[BLT 17,17] ;MOVE DUMP ACS TO PHYSICAL ACS
JRST 12,@UUO0+P1PID
;INTR4 - REGULAR I-PROCESS STARTUP (NOT AFTER UWAIT)
INTR4: MOVSI AC1,JOBAC ;SAVE UUO-LEVEL ACS
HRRI AC1,INTACS(PID) ;SINCE HE WILL DO UUO'S
XCTR XBLTR,[BLT AC1,INTACS+17(PID)]
MOVE AC1,USRPC(PID) ;SHOULD BE HERE BY NOW
TLNE AC1,USRMOD
JRST INTR4A ;PC IS IN USER MODE.
MOVE AC1,UUOPC(J) ;USE LAST UUO-LEVEL PC.
CAIN AC1,USRXT5 ;WAS UUOCON INTERRUPTED EARLY?
MOVE AC1,UUO0(PID) ;YES. HERE'S HIS USER LEVEL PC
TLZN AC1,USRMOD ;FLAG IT AS COMING FROM EXEC
TDZA AC1,AC1 ;MAKE ZERO IF WE DON'T KNOW IT
SUBI AC1,1 ;ADJUST IT TO POINT AT HIS UUO
INTR4A: SKIPE AC2,AC3 ;AC3 IS NON-ZERO FOR DUAL INT. SYSTEM
JRST .+3
MOVEI AC2,JOBTPC+1 ;PLACE TO STORE INTERRUPT PC, +1
MOVEI AC3,JOBAPR ;PLACE TO FETCH TRAP PC.
XCTR XR,[MOVE AC3,(AC3)] ;AC3←TRAP ADDRESS
XCTR XW,[MOVEM AC1,-1(AC2)] ;STORE INTERRUPT PC.
MOVE AC2,JBTPRV(J)
TLNN AC2,LUPPRV
TLZ AC3,4000 ;DON'T SET IOT USER UNLESS LOCAL
TLO AC3,USRMOD ;AND MAKE SURE WE DO GET TO USERMODE
TLZ AC3,37 ;AVOID @ LOOPS
MOVE 16,J ;SET UP HIS ACS
MOVE 2,JBTPAG(16)
LSH 2,=9
SUB 2,[1,,0]
MOVE 1,SPWBUT
SETZM 3
MOVE 15,JBTIIP(16)
TLNE 15,INTSHW!INTSWW
SETOM 3 ;SWAP/SHUFFLE WARNING
MOVEI 4,1
SKIPE PID
MOVEI 4,2 ;PROCESSOR NUMBER IN 4
SETZM 5 ;5 TELLS IF THE OTHER PROCESSOR IS ALIVE
MOVE 6,JBTSTS(16) ;HE WANTS HIS STATUS WORD IN 6 TOO
LDB 7,[POINT 6,JBTSTS(16),35] ;7←SEGMENT NUMBER
HLRZ 7,JBTPAG(7)
LSH 7,=9
SUBI 7,1 ;7←PROTECTION OF SEGMENT
MOVE 10,INTDTM(16)
MOVM 14,JOBQUE(16) ;TELL HIM HIS CURRENT Q
SKIPN P2NUM ;IS THERE A P2?
JRST SIXDED ;NO. OTHER PROC IS DEAD.
CAIE 4,1 ;IS THIS P2?
JRST SIXTST ;YES. SEE IF P1 IS ALIVE.
SKIPGE PALIVE+P2PID
SIXDED: SETOM 5
IFKL10,< SKPKL
JRST INTNKL
XCTR XW,[MOVEM 17,17] ;STORE EXEC 17 IN USER'S 17
MOVEI 17,0
XCTR XBLTW,[BLT 17,16] ;STORE EXEC 0-16 IN USER'S 0-16
DATAO KLPAG,[401000,,0] ;USER RUNS WITH AC BLOCK 1
INTNKL: >;IFKL10
JRST 12,@AC3 ;DISMISS TO TRAP ADDRESS.
SIXTST: SKIPGE PALIVE+P1PID
SETOM 5
JRST 12,@AC3 ;SINCE JRST 2,() DOESN'T WORK ON 6
;INTADC, INTXIT
;TYPE ERROR MESSAGE FOR ILL. STARTING ADDRESS
INTADC: SETZM JBTIIP(J) ;ADDRESS CHECK. GET OUT OF I-LEVEL
PUSHJ P,TTYERP ;NOW GIVE HIM A NASTY MESSAGE
PUSHJ P,INLMES
ASCIZ /Interrupt address out of bounds
/
PUSHJ P,HOLD ;PRINT ↑C CRLF . CRLF. CALL TTYSTC AND ESTOP
JRST INTR1 ;RESCAN FOR OTHER INTERRUPTS.
INTXIT: JRST 2,@[4000,,.+1] ;KEEP PCU SET
SETZM INTACT(PID) ;DONE. RESTORE ALL THE STUFF WE SAVED UP FRONT.
SETZM INTDISP(PID)
HRLI AC1,-USRJDA-20+USRPRT+1(P)
HRRI AC1,USRPRT(PID)
BLT AC1,USRJDA+17(PID)
SUB P,[USRJDA+20-USRPRT,,USRJDA+20-USRPRT]
POP P,APRIN1(PID)
POP P,APRERR(PID)
POP P,APRPC(PID)
POP P,SCHEDF(PID)
POP P,CLKS17(PID)
POP P,@CLKCH(PID)
POP P,@UUOLOC(PID)
POP P,UUO0(PID)
POP P,USRSAV(PID)
PUSHJ P,POPMAP
MOVE J,SJOB(PID)
MOVEM J,JOB(PID)
POPJ P,
; ROUTINE TO SWAP A GUY IN SO HE MAY BE INTERRUPTED
INTSWAPIN:
MOVE AC3,J ; AC3 IS JOB TO TEST FOR BEING IN
PUSHJ P,INTSWT ; SWAPIN TEST SUBR
JRST INTR1 ; NO CAN DO
LDB AC3,PSEGN ; GET SEGMENT #
JUMPE AC3,INTR1
MOVE TAC,JBTSTS(AC3)
TLNE TAC,SWP ; IF SWAPPED OUT,
JRST INTR1 ; NORMAL THING WILL HAPPEN
MOVSI TAC,JHLDIN ; ELSE HOLD IT IN
IORM TAC,JBTSTS(AC3) ; FOR LOWER
JRST INTR1
INTSWS: PUSHJ P,INTSWT ; AC3 JOB TO BRING IN, J LOWER
JRST INTR1
MOVE TAC,JBTSTS(J)
TLNE TAC,SWP ; IF LOWER IS SWAPPED OUT,
JRST INTR1 ; LET NORMAL THING HAPPEN
MOVSI TAC,JHLDIN
IORM TAC,JBTSTS(J) ; ELSE HOLD HIM IN FOR UPPER
JRST INTR1
INTSWT: ; SEE IF HE IS MASKED OUT
TDNN AC1,JBTMSK(J) ; ARE ANY OF THOSE BITS ON?
POPJ P, ; APPARANTLY NOT, DON'T BOTHER TO CALL HIM IN
SETOM INTREQ(PID) ; COME BACK NEXT TIME AROUND TOO
MOVE AC2,JBTSTS(AC3)
TLNN AC2,SWP ; NEED TO GET HIM IN CORE?
POPJ P, ; NO, MUST BE SHUFFLE, JUST WAIT
EXCH AC3,J ; GET US IN J
MOVSI TAC,INTSNB
PUSHJ P,SETSIN ; PUT INTO SWAP IN LIST
EXCH AC3,J
JRST CPOPJ1
;INTCH7 , INTERR, INTDSM, INTDEB
;THIS IS THE PLACE WE COME UPON CH7 BREAKS WHILE AN I-LEVEL PROCESS
;IS RUNNING. CHECK FOR ERRORS, FOR TIMEOUT, DISMISS CH7 IF ALL IS OK.
INTCH7: SKIPN APRERR(17) ;CH3 ERROR?
SKIPE SCHEDF(17) ;OR ATTEMPT TO RESCHEDULE?
JRST INTERU ;YES - I LEVEL ERROR
AOSL INTQUANT(17) ;HAS HIS QUANTUM EXPIRED?
JRST INTERU ;YES - ERROR
JUMPE 17,INTOK
MOVE 17,CLKS17+P2PID
JEN @CL2CHL
INTOK: MOVE 17,CLKS17+P1PID
JEN @CLKCHL
;HERE WE HAVE A PROBLEM.
INTERU: JSR @CLKESV(17) ;SAVE THE ACS. SETUP J, PID,
JSP TAC,ERRPTU ;"? ERROR IN JOB N USER I-LEVEL ...."
ASCIZ /User Interrupt-Level /
SKIPE APRERR(PID)
JRST INTAPR
SKIPE SCHEDF(PID)
JRST INTERP ;MAY HAVE COME FROM ESTOP - CHECK JERR.
PUSHJ P,INLMES ;MUST HAVE BEEN A TIMEOUT.
ASCIZ /timeout/
MOVE TAC1,@CLKCH(PID) ;GET A PC TO TYPE.
JRST INTERR
INTERP: SKIPE ESTINT ;ARE WE HERE FROM ESTOP?
JRST INTDSM ;YES - ACT LIKE DISMISS (PHANTOM WITH ERROR)
PUSHJ P,INLMES
ASCIZ /attempt to schedule, UUO/
MOVE TAC1,UUOPC(J)
SOJA TAC1,INTERR
INTAPR: MOVEI TAC,[ASCIZ /CH3 error/]
MOVE AC1,APRERR(PID)
TRNE AC1,ILM
MOVEI TAC,[ASCIZ /ill mem ref/]
TRNE AC1,NXM
MOVEI TAC,[ASCIZ /NXM/]
TRNE AC1,POV
MOVEI TAC,[ASCIZ /pdl ov/]
PUSHJ P,CONMES
MOVE TAC1,APRPC(PID)
INTERR: PUSHJ P,PCP
PUSHJ P,HOLD
INTDSM: SETZM ESTINT ;ENTER HERE FOR THE DISMISS UUO
MOVE P,INTSP(PID) ;HERE WE ARE AT THE DISMIS UUO
MOVE J,JOB(PID) ;PICK UP ALL THE ACCUMULATORS
MOVSI AC1,INTACS(PID) ;PUT BACK EVERYTHING. (SOURCE)
HRRI AC1,JOBAC
XCTR XBLTW,[BLT AC1,JOBAC+17];STORE INT ACS INTO USER RELATIVE 0-17
INTDB1: CAME J,SJOB(PID) ;DON'T BOTHER IF ALREADY OK
PUSHJ P,S2U ;MOVE JOBJDA BACK
POP P,UUOPC(J)
SETZM JBTIIP(J) ;GET HIM OUT OF INTERRUPT LEVEL
JRST INTR2
INTDEB: MOVE P,INTSP(PID) ;HERE FOR DEBREAK UUO.
MOVE J,JOB(PID)
MOVE AC1,UUOPC(J) ;WHERE WE WANT TO BE WHEN AT MAIN LEVEL
MOVEM AC1,USRPC(PID)
CAMN J,SJOB(PID)
MOVEM AC1,-USRJDA-20+USRPC(P) ;THIS IS WHAT WILL BE PUT INTO USRPC!!
MOVE AC1,[JOBAC,,JOBDAC]
XCTR XBLTRW,[BLT AC1,JOBDAC+17];REAL ACS WILL BE UUO ACS AT TIME OF DEBREAK
MOVM AC1,JOBQUE(J)
CAIE AC1,IOWQ
JRST INTDB1
MOVNI AC2,RUNQ ;IN CASE UUO WAS IN IOWQ
MOVEM AC2,JOBQUE(J)
PUSHJ P,REQUE
JRST INTDB1
;INTKILL ROUTINE TO CLEAR A JOB'S INTERRUPT ENABLINGS AND RESET HIS MASKS
↑INTKILL:
PUSH P,AC1
PUSH P,AC2
SETZM JBTIEN(J) ;CLEAR THE ENABLE BITS FIRST
SETZM JBTIRQ(J) ;NOW CLEAR ANY PENDING INTERRUPTS
SETZM JBTIIP(J)
SETOM JBTWKM(J) ;INITIALIZE THE WAKE UP MASK
SETOM JBTMSK(J) ;NOW CLEAR THE PROCESSOR MASK
PUSHJ P,APRDKL ;FLUSH CLOCK REQUESTS
POP P,AC2
POP P,AC1
SETZM UUOPTR(J) ;ALSO DISABLE UUO INTERPRETER
POPJ P,
;INIJOB ROUTINE TO INITIALIZE A JOB SLOT
;CALL AT CLOCK LEVEL OR UUO LEVEL
; PUSHJ P,INIJOB
; <JOB CAPACITY EXCEEDED>
; <CANNOT GET FREE STORAGE - TRY AGAIN LATER>
; <SUCCESS. J IS SET UP>
; IF YOU WANT TO MAKE THIS A REAL JOB, YOU MUST CLAIM JOB
; SLOT BY MARKING JNA OR CMWB IN JBTSTS.
;CLOBBERS TAC
;SETS UP: JBTADR,JBTPRV,JBTBTM,JBTSTS,TTIME,RTIME,JBTUFD,DSKPPN,JBTRNB,JBTPR2,
; JBTKCJ,J,JBTMAP
INIJB0: MOVSI TAC,JNA!CMWB
INIJB1: MOVEI J,1 ;SEEK JOB SLOT
INIJB2: TDNN TAC,JBTSTS(J)
JRST CPOPJ1 ;THIS ONE IS FREE.
CAMGE J,JOBNM1 ;HAVE WE REACHED MAXIMUM SLOT NUMBER?
AOJA J,INIJB2 ;NOT YET.
MOVEI J,0 ;RETURN A ZERO
POPJ P, ;AND LOSE.
↑INIJOB:JUMPN PID,CPOPJ ;GOD FORBID THE PDP-6 SHOULD TRY THIS
PUSHJ P,INIJB0 ;SEEK A JOB SLOT
POPJ P, ;NONE AVAILABLE
SKIPE JBTPAG(J) ;BUG TRAP
PUSHJ P,INIJXX ;COMPLAIN
PUSH P,AC3
PUSH P,AC1
PUSHJ P,MAKPDL ;MAKE A JOB PDL - RETURNS PDL IN AC1
JRST INIJXA ;LOSE. - GIVE THE NO FS. RETURN.
MOVSI TAC,JNA!CMWB ;JOB SLOT STILL AVAILABLE?
TDNN TAC,JBTSTS(J)
JRST INIJBA ;YES. WE'RE WINNING.
PUSHJ P,INIJB1 ;GET A NEW JOB SLOT
JRST INIJXC ;THERE ARE NO JOB SLOTS.
INIJBA: EXCH AC1,JBTPDL(J) ;STORE PDL POINTER
JUMPE AC1,INIJBC
MOVEI AC1,1(AC1) ;MAKE A BLOCK ADDRESS
PUSHJ P,FSGIVE ;RETURN OLD PDL
INIJBC: POP P,AC1
POP P,AC3
SETZM JBTPAG(J) ;JOB HAS NO CORE ASSIGNED
SETZM TTIME(J)
SETZB RTIME(J)
SETZM DSKOPS(J) ;NO DISK USAGE YET
SETZM JBTWAT(J) ;HAVEN'T WAITED FOR SYSTEM YET
SETZM JB2WAT(J) ;DITTO
SETZM XTIME(J) ;MAKE SURE NO-UPDATE BIT IS CLEAR IN XTIME
SETZM JBTMSC(J) ;NO RANDOM BITS
MOVSI TAC,JERR
MOVEM TAC,JBTSTS(J) ;AN NICE WAY TO START: JERR.
SETZM JBTPRV(J) ;NO ACTIVE PRIVILEGES
SETZM JB2PRV(J) ;OR PASSIVE ONES
SETZM JBTTPV(J) ;OR TEMPORARY ONES
SETZM JBTRNB(J)
SETZM JBTPR2(J) ;NO PEEK-POKE
SETZM JBTUFD(J) ;NO UFD ADDRESS
SETZM DSKPPN(J) ;NO DSKPPN
SETZM JBTKCJ(J) ;NO KILO-CORE JIFFIES
MOVE TAC,TIMDAT ;GET <DATE>,,<TIME IN SECS>
MOVEM TAC,JBTBTM(J) ;SAVE JOB BEGINING TIME.
MOVEM TAC,FTIME(J) ;SET TIME LAST RUN.
IFKL10,< PSYNC CSHCSC
SETZM JBTCSH(J) ;NO REASON WE CAN'T CACHE THIS. NOT CACHED
XSYNC CSHCSC >;IFKL10
JRST CPOPJ2 ;GIVES THE (DOUBLE) SKIP RETURN.
INIJXC: SOS (P) ;NO JOBS. RETURN +0 (CPOPJ1 BELOW)
MOVEI AC1,1(AC1)
PUSHJ P,FSGIVE
INIJXA: POP P,AC1 ;NO FREE STORAGE FOR JBTPDL
POP P,AC3
JRST CPOPJ1 ;NO F.S. RETURN +1
;HERE TO RELEASE AN ILL-GOTTEN JOB.
RELJOB: JUMPN PID,CPOPJ ;GOD FORBID THE PDP-6 SHOULD EVER TRY
MOVEI AC1,0
EXCH AC1,JBTPDL(J)
JUMPE AC1,RELJB1
MOVEI AC1,1(AC1)
PUSHJ P,FSGIVE
RELJB1:
IFN FTPAGER,< SKIPE AC1,JBTMAP(J)
PUSHJ P,GIVMAP
SETZM JBTMAP(J) >;FTPAGER
MOVSI TAC,JNA
ANDCAM TAC,JBTSTS(J)
POPJ P,
MAKPDL: MOVEI AC3,JBTPLN ;GET A PDL FOR THIS JOB.
PUSHJ P,FSGET ;FROM FREE STORAGE.
POPJ P, ;NO FREE STORAGE.
HRLI AC1,1-<JBTPLN+JOBPRT-JOBPFI> ;SET LEFT SIDE TO COUNT.
SETZM (AC1) ;ZERO FIRST LOCATION OF PDL
MOVSI AC3,(AC1) ;SOURCE OF BLT
HRRI AC3,1(AC1) ;DESTINATION
BLT AC3,JBTPLN-1(AC1) ;ZERO THE ENTIRE PDL.
SOJA AC1,CPOPJ1 ;AC1 SET AS PDL POINTER. SKIP RETURN.
INIJXX: PUSHACS ;CALLED FROM INIJOB OR ESTSG2
PUSHJ P,DISMES
ASCIZ /JBTPAG NOT 0 AT INIJXX /
PUSHJ P,DISJOB
PUSHJ P,DISTAB
MOVE TAC,JBTPAG(J)
PUSHJ P,DISOCT
PUSHJ P,DISCRLF
PUSHJ P,DISFLU
POPACS
PUSHJ P,WDDTCAL
POPJ P,
SUBTTL COMCON THE COMMAND DECODER 8/4/67
COMMENT $
COMMAND is called from the clock routine when COMCNT, set by TTYSER,
is greater than 0. All ACs are available to the command decoder.
COMMAND calls TTYCOM to scan for a TTY which has typed a command.
Then the command is looked-up and the dispatch address and control
bits are found. After checking that initial conditions, as specified
by the control bits are satisfied, we dispacth via PUSHJ to the
command setup routine. The initial ACs and stack are set up as
follows:
DDB TTY DDB address
TAC Byte pointer to the command string (the space or CR after the command name)
DAT Byte pointer to the last output character
J Job number of TTY typing this command or 0.
TAC1 COMMAND BITS,,DISPATCH ADDRESS
UUO The full name of this command in SIXBIT
IOS 0 (is used for subsequent dispatches)
The TTY DDB and control bits are pushed on the stack prior to
dispatching. Thus, by referencing down the stack the command setup
routine can get at it's TTY DDB (in case it uses multiple DDBs) and
also it can affect the typeout generated by the command decoder after
returning from command setup (by changing the control bits).
PUSH P,DDB
PUSH P,TAC1
PUSHJ P,(TAC1)
On return from the command setup routine, usually a CRLF is appended
to the message (generated by the command setup routine) and the TTY
(specifed by the DDB on the stack) is started. Several flags are
checked on return from the command setup routine (unless an error has
occurred) for standard command response. If an error occurs, the job
number (J) should be set to 0 on return to prevent the job from being
initialized if this is the first command. ERRMES routine will set J
to 0.
Since the command decoder is called from the clock routine each
command setup routine must run to completion quickly, without waiting
for core assignments or I/O of any kind. If a command function
cannot complete without waiting, it must either
1. delay itself (DLYCOR, DLYCM1) until conditions obtain such
that it can complete. In this case the command will be called
repeatedly until it completes.
2. schedule a monitor job to run at UUO level and complete the
function.
3. perform whatever work it can, remember it's state, and
on subsequent calls, perform more work when possible.
$
;COMMAND
↑COMMAND:
PUSHJ P,TTYCOM ;FIND A TTY THAT TYPED A COMMAND.
;SETUP DDB, DAT, TAC, AND J
POPJ P, ;THERE WERE NO TTY'S WITH COMMANDS
SETOM LINSV1 ;MARK THAT WE SAW A COMMAND
COM0: PUSH P,DDB ;SAVE TTY DEVICE DATA BLOCK ADDRESS
PUSHJ P,CTEXT ;SCAN COMMAND NAME, RETURN IT IN TAC1
CAMN TAC1,['HAL '] ;LET ↑C THROUGH
JRST NOSCRU
JUMPE J,NOSCRU
MOVE AC1,JBTSTS(J)
TLNN AC1,JNA
JRST NOSCRU
TLNN AC1,JACCT ;THIS CAN'T HAPPEN EXCEPT FROM PARITY ERR ETC.
TLNN AC1,JLOG
SCREWU: MOVSI TAC1,'K ' ;NOT LOGGED IN - ANY COMMAND, OR AFTER ↑C FINISHES
NOSCRU: MOVE AC1,TAC1 ;COPY COMMAND.
MOVNI AC2,1 ;SET MASK ALL ONES
LSH AC2,-6 ;CLEAR OUT ONE MORE CHAR.
LSH AC1,6 ;SHIFT 1 COMMAND CHAR OFF
JUMPN AC1,.-2 ;IF NOT END OF COMMAND, GO AROUND
MOVEI DSER,0 ;CLEAR FLAG REGISTER
MOVSI AC1,-DISPL ;SEARCH COMMAND TABLE FOR MATCH
COMLP: CAMN TAC1,COMTAB(AC1);EXACT MATCH?
JRST COMFND ;YES, THIS IS IT. (AC1 SET WITH INDEX)
MOVE UUO,COMTAB(AC1) ;GET FULL ENTRY NAME FROM COMMAND TABLE
TDZ UUO,AC2 ;MASK OFF UNSPECIFIED CHARACTERS
CAME TAC1,UUO ;MATCH UNDER MASK?
JRST COMNEQ ;NO. NOT EVEN GOOD MATCH
JUMPE DSER,.+2
TLOA DSER,400000 ;SET SIGN BIT TO DENOTE AMBIGUOUS MATCH
MOVEI DSER,1(AC1) ;COPY INDEX TO DSER - FIRST MATCH UNDER MASK
COMNEQ: AOBJN AC1,COMLP ;NO, KEEP LOOKING
JUMPLE DSER,.+2 ;DID ONE AND ONLY ONE COMMAND MATCH?
MOVEI AC1,-1(DSER) ;YES. GET COMMAND INDEX THAT WE SAVED.
;FALL INTO COMFND.
;IF NOTHING MATCHES, WE HAVE ILLEGAL COMMAND
COMFND: MOVE UUO,COMTAB(AC1) ;SAVE FULL COMMAND NAME
MOVE TAC1,DISP(AC1) ;GET DISPATCH TABLE ENTRY.
PUSH P,TAC1 ;SAVE RH(DISPATCH ADR.+BITS)
MOVE AC1,JBTSTS(J) ;JOB STATUS WORD FOR THIS JOB
TLNN AC1,JLOG ;IS JOB LOGGED IN?
TLNE TAC1,NOLOGIN ;NO, CAN COMMAND PROCEED WITH NO LOGIN?
JRST CHKNO ;YES
TLNE TAC1,DOLOG ;THE REG KLUGE?
JRST CHKNOX ;YES. ALLOW THIS USER TO LOGIN NOW.
JSP TAC,COMER ;NO, TYPE "LOGIN PLEASE"
ASCIZ /Login please
/
CHKNOX: MOVE TAC1,DISP-1 ;INDEX FOR THE REG KLUDGE
MOVEM TAC1,(P) ;STORE THE BITS ON THE STACK AGAIN
CHKNO: JUMPN J,CHKRUN ;JUMP IF JOB NUMBER ALREADY ASSIGNED.
TLNE TAC1,NOJOBN ;NO, DOES THIS COMMAND NEED A JOB NUMBER?
JRST COMGO ;NO
PUSHJ P,INIJOB ;INITIALIZE A JOB
JRST JBCPEX ;NO JOBS AVAILABLE.
JRST [MOVEI TAC1,DLYCM1 ;WE NEED TO WAIT FOR FREE STORAGE.
JRST COMDIS] ;SO WE DELAY THIS COMMAND FOR A TICK.
MOVE TAC1,(P) ;RESTORE TAC1 - CLOBBERED BY INIJOB
SETZM DEVLOG(DDB) ;CLEAR LOGICAL NAME OF TTY
JRST CHKCO1
CHKRUN: TLNE AC1,RUN ;SKIP IF THE CURRENT JOB IS NOT RUNNABLE.
TLNN TAC1,NORUN ;IS RUNNABLE. SKIP IF COMMAND WANTS JOB STOPPED
JRST CHKACT ;PROCEDE WITH COMMAND.
MOVM AC3,JOBQUE(J) ;IS THE JOB TRYING TO BE IN STOPQ?
CAIE AC3,STOPQ
JRST CNCMES ;NO - TELL HIM TO STOP FIRST.
MOVSI AC3,RUN ;JOB IS IN STOPQ BUT RUN BIT IS SET. CLEAR IT.
ANDCAM AC3,JBTSTS(J) ;THIS IS A BUG FIX. - RPH
JRST CHKACT
CNCMES: JSP TAC,COMER
ASCIZ /Please type ↑C first
/
JBCPEX: JSP TAC,COMER
ASCIZ /Job capacity exceeded
/
;CHKACT, CMDXMP, CMDMAP
CHKACT: TLNE AC1,SWP ;IS JOB ON DISK OR ON ITS WAY?
TLNN TAC1,INCORE ;MUST JOB BE IN CORE?
JRST CHKCO2 ;NO
TLNN TAC1,SHRINK ;SHALL WE SHRINK HIM BEFORE BRINGING HIM IN?
JRST CHKCO3 ;NO.
PUSHJ P,INTKILL ;KILL INTERRUPTS BEFORE SHRINK.
SKIPE JBTPAG(J) ;IS THERE CORE ASSIGNED TO THIS JOB?
JRST CHKCO3 ;YES. DON'T SHRINK IT WHILE THERE'S CORE ASSIGNED.
MOVEI TAC,1 ;SHRINK BEFORE SWAPIN.
PUSHJ P,CORE0K ;SET IMGIN TO 1 PAGE BEFORE BRINGING HIM IN.
JFCL ;CORE0K ALWAYS SKIPS.
CHKCO3: MOVEI TAC1,DLYCOR ;YES, DELAY COMMAND.
JRST COMDIS
CHKCO2: TLNE TAC1,NOACT ;CAN COMMAND BE PERFORMED WITH ACTIVE DEVICES?
PUSHJ P,RUNCHK ;NO, RETURN IF JOB STOPPED AND NO ACTIVE DEVICES
CHKCO1: SKIPN JBTPAG(J) ;SKIP IF JOB IS IN CORE.
TLNE TAC1,NOCORE ;DOES THIS COMMAND NEED CORE?
JRST COMGO ;JOB INCORE OR INCORE ISN'T NECESSARY.
JSP TAC,COMER ;NO, PRINT "NO CORE ASSIGNED"
ASCIZ /No core assigned
/
;COMER, COMGO, COMDIS, COMRET, SKPBRK. DISPATCH TO AND RETURN FROM COMMAND SETUP
COMER: MOVSI TAC1,NOINCK ;SET ERROR CONDITIONS
MOVEM TAC1,(P)
MOVEI TAC1,ERRMES ;CALL ERROR MESSAGE ROUTINE
COMGO: MOVSI IOS,NOSKPB ;CLEAR BIT THAT'S SHARED WITH PRE-DISPATCH
ANDCAM IOS,(P)
TLZ AC1,CMWB ;FLUSH CMWB FROM JBTSTS
MOVEM AC1,JBTSTS(J)
COMDIS: TLNE TAC1,NOPRIV ;NEED TO CLEAR TEMPORARY PRIVILEGES?
PUSHJ P,CLRTPV ;YES, DO IT
MOVEI IOS,0 ;CLEAR IOS FOR SETTING DISPATCH ADDRESSES
TLNE TAC1,SETMAP ;NEED TO REFERENCE USER CORE?
PUSHJ P,APRMAP ;YES.
AOS NCOMS
;ABSOLUTELY EVERY COMMAND KNOWS THE STACK ENVIRONMENT IS PRECISELY:
;-3(P) THE RETURN TO CLOCK LEVEL PROCESSING,
;-2(P) THE TTY DDB,
;-1(P) THE COMMAND DISPATCH AND BITS
; 0(P) THE RETURN TO COMRET
PUSHJ P,(TAC1) ;DISPATCH TO COMMAND SETUP ROUTINE.
COMRET: POP P,AC2 ;RESTORE COMMAND FLAGS
POP P,DDB ;RESTORE TTY DDB ADDRESS.
TLNN AC2,NOSKPB ;REQUESTED TO SKIP TO BREAK CHARACTER?
PUSHJ P,COMR2A ;YES.
PUSHJ P,COMR2B ;DECREMENT COMCNT
TLNN AC2,NOACT ;DID WE STOP SPACEWAR?
JRST COMRE1 ;NO.
MOVSI AC1,SPWSUS!SPWST1!SPWST2 ;PREPARE TO RESTART IT
PSYNC SPWCSC ;GET CONTROL OF SPW TABLES
ANDCAM AC1,JBTST2(J) ;ZERO OUT THE SUSPENSION BIT
XSYNC SPWCSC ;RELEASE CONTROL
COMRE1: JUMPN J,COMRT1 ;DID AN ERROR OCCUR?
TLNN AC2,NOJOBN ;I.E., J=0 AND NOJOBN=0?
MOVSI AC2,NOINCK!ERRFLG ;YES, PRINT ERROR MESSAGE ONLY.
COMRT1: MOVE AC1,JBTSTS(J) ;JOB STATUS WORD
TLNN AC2,NOINCK ;SUPPRESS JOB INIT. CHECK?
TLOE AC1,JNA ;NO, IS JOB INIT BIT ALREADY SET?
JRST PCRLF ;YES.
MOVSI AC1,JNA ;NO, SET IT THIS COMMAND
IORM AC1,JBTSTS(J)
PUSHJ P,TTYATI ;ATTACH TTY TO JOB
JFCL ;IGNORE IF CAN NOT(SHOULD NEVER HAPPEN)
PUSHJ P,PRJOB ;TYPE JOB # & CONFIG LINE
PCRLF: TLNE AC2,ERRFLG ;DID AN ERROR OCCUR?
PUSHJ P,PRQM ;YES. APPEND ?
TLNN AC2,NOCRLF ;SUPRESS CRLF?
PUSHJ P,CRLF ;NO
TLNN AC2,NOPER ;SUPRESS PRINTING PERIOD?
PUSHJ P,PRPER ;NO
JUMPE J,PCRLF1 ;JOB DOES NOT RUN IF ERROR
;OR NO JOB NUMBER ASSIGNED.
TLNE AC2,TTYRNU ;JOB TO RUN WHEN TTY FINISHED TYPING?
;COMMAND RESPONSE (TTY TO USER MODE)?
PUSHJ P,TTYUSR ;YES, CALL SCANNER ROUTINE
TLNE AC2,TTYRNC ;NO, JOB TO RUN AND REMAIN IN MONITOR MODE?
PUSHJ P,SETRUN ;YES, CALL SCANNER ROUTINE ;MCF(JS)
PCRLF1: TLNN AC2,NOMESS ;IS THERE A MESSAGE?
JRST TTYSTR ;YES, START TTY TYPING IT OUT
POPJ P,
COMR2A: LDB TEM,TITAKR(DDB) ;GET BREAK CHARACTER
ANDI TEM,177
MOVEI DAT,TTIBUF(DDB) ;IN CASE SOMEONE CLOBBERED IT.
SKPBRK: PUSH P,TAC
SKPBR2: PUSHJ P,SPCHEK
JRST SKPBR1
TLNE TAC,BREAKB ;IS THIS CHAR THE BREAK?
JRST TPOPJ ;YES, RESTORE TAC AND RETURN
SKPBR1: PUSHJ P,GETLCCHR ;GET A CHARACTER FROM COMMAND LINE
JUMPN TEM,SKPBR2 ;LOOK FURTHER FOR BREAK CHAR
JRST TPOPJ ;UNLESS NO MORE CHARS
;CALLED FROM COMMAND RETURN AND FROM DETACH (CDET,FORK,CFORK) COMMAND
COMRT2: PUSHJ P,COMR2A ;SKIP TO BREAK CHAR
COMR2B: MOVSI AC1,COMBIT
LDB TAC,PUNIT
; CONO PI,SCNOFF
OFFSCN ;TURN OFF SCANNER CHANNEL
SKIPGE TTYTAB(TAC)
SOS COMCNT
ANDCAM AC1,TTYTAB(TAC)
IFN FTTTYBUG,<
PUSHJ P,COMBCK
PUSHJ P,CNTCOM
>
; CONO PI,SCNON
ONSCN ;TURN ON SCANNER CHANNEL
POPJ P,
;TABLE OF CONSOLE COMMANDS
;"*" MARKS THOSE BITS THAT ARE CHECKED BEFORE DISPATCHING TO COMMAND SETUP ROUTINE
;"+" MARKS THOSE BITS THAT ARE CHECKED AFTER RETURNING FROM COMMAND SETUP
;NOTE THAT SOME BITS HAVE TWO MEANINGS, BEWARE!
NOCORE←←400000 ;*NO CORE NEEDED FOR COMMAND
NOJOBN←←200000 ;*NO JOB NUMBER NEEDED FOR COMMAND
NOLOGIN←←100000 ;*JOB DOES NOT NEED TO BE ALREADY LOGGED IN.
NOACT←←40000 ;*COMMAND MUST BE DELAYED IF JOB HAS ACTIVE DEVICES.
INCORE←←20000 ;*COMMAND MUST BE DELAYED IF JOB IS CURRENTLY SWAPPED OUT.
NORUN←←10000 ;*↑C MUST BE TYPED BEFORE COMMAND CAN BE EXECUTED.
SHRINK←←4000 ;*IF JOB IS SWAPPED OUT, SHRINK BEFORE BRINGING HIM IN!
NOSKPB←←4000 ;+DON'T CALL SKPBRK
NOPRIV←←2000 ;*CLEAR TEMPORARY PRIVILEGE BITS
SETMAP←←1000 ;*SET APR MAP TO REFERENCE JOB TO WHICH THIS COMMAND
;PERTAINS, RESTORE MAP TO CURRENT JOB WHEN DONE
NOINCK←←400 ;+NO CHECK FOR JOB INITIALIZATION (JNA=0)
NOCRLF←←200 ;+NO PRINTING OF CRLF
NOPER←←100 ;+NO PRINTING OF PERIOD
TTYRNU←←40 ;+SET TTY TO USER MODE AND START JOB AFTER COMMAND
;RESPONSE STOPS TYPING
TTYRNC←←20 ;+KEEP TTY IN COMMAND MODE AND START JOB AFTER COMMAND
;RESPONSE STOPS TYPING
NOMESS←←10 ;+NO COMMAND RESPONSE EVER, DO NOT CALL TTYSTR
DOLOG←←4 ;*ALLOW LOGIN FIRST
ERRFLG←←1 ;COMMAND ERROR
RPGBIT←←NOCORE!NOPER!NOCRLF!INCORE!NORUN!NOACT!TTYRNU!SHRINK!DOLOG!NOPRIV
;BITS FOR THE RPG COMMANDS
DEFINE NAMES
<
C KJOB,KJOB,NOCORE!NOJOBN!NOINCK!NOLOGIN!NOACT!NORUN!NOCRLF!NOPER!NOMESS!INCORE!SHRINK
C LOGOUT,KJOB,NOCORE!NOJOBN!NOINCK!NOLOGIN!NOACT!NORUN!NOCRLF!NOPER!NOMESS!INCORE!SHRINK
C K,KJOB,NOCORE!NOJOBN!NOINCK!NOLOGIN!NOACT!NORUN!NOCRLF!NOPER!NOMESS!INCORE!SHRINK
C KATTACH,KJOB,NOCORE!NOJOBN!NOINCK!NOLOGIN!NOACT!NORUN!NOCRLF!NOPER!NOMESS!INCORE!SHRINK
C KLOG,KJOB,NOCORE!NOJOBN!NOINCK!NOLOGIN!NOACT!NORUN!NOCRLF!NOPER!NOMESS!INCORE!SHRINK
C START,START,NOPER!TTYRNU!INCORE!NOACT!NORUN!SETMAP
C S,START,NOPER!TTYRNU!INCORE!NOACT!NORUN!SETMAP
C HALT,STOP,NOCORE!NOJOBN!NOLOGIN!NOINCK
C KILL,KILCOM,NOCORE
C FLUSH,FLUSH,NOINCK!NOLOGIN!NOJOBN!NOCORE
C <>,CBLANK,NOCORE!NOJOBN!NOLOGIN!NOINCK!NOCRLF
C R,RCOM,NOCORE!NOPER!TTYRNU!NOCRLF!INCORE!NOACT!NORUN!SHRINK!DOLOG!NOPRIV
C RUN,RUNCOM,NOCORE!NOPER!TTYRNU!NOCRLF!INCORE!NOACT!NORUN!SHRINK!DOLOG!NOPRIV
C CORE,CORE,NOCORE!NOACT!NOLOGIN!NORUN!NOINCK!NOJOBN
C C,CORE,NOCORE!NOACT!NOLOGIN!NORUN!NOJOBN!NOINCK
C SETUWP,SETWPS,NOACT!INCORE!NOPRIV!SETMAP
C CLRUWP,CLRWPS,NOACT!INCORE!NOPRIV!SETMAP
C ENABLE,ENABLE,NOCORE
C DISABLE,DISABLE,NOCORE
C GET,GET,NOCRLF!NOPER!TTYRNU!INCORE!NOCORE!NOACT!NORUN!SHRINK!DOLOG!NOPRIV
C G,GET,NOCRLF!NOPER!TTYRNU!INCORE!NOCORE!NOACT!NORUN!SHRINK!DOLOG!NOPRIV
C SAVE,SAVE,NOCRLF!NOPER!TTYRNU!INCORE!NOACT!NORUN!NOPRIV!SETMAP
C SSAVE,SSAVE,NOCRLF!NOPER!TTYRNU!INCORE!NOACT!NORUN!NOPRIV!SETMAP
C CONTINUE,CONT,NOPER!TTYRNU!INCORE!NORUN
C DE,DCOM,INCORE!NOPRIV!SETMAP
C E,ECOM,NOCRLF!INCORE!SETMAP
C PJOB,PJOBDV,NOCORE!NOLOGIN!NOJOBN!NOINCK
C PTTY,PTTY,NOCORE!NOJOBN!NOINCK!NOLOGIN
C ALIAS,SDSKPPN,NOCORE!NOPRIV
C SLEVEL,SLEVEL,NOCORE
C ASSIGN,ASSIGN,NOCORE!DOLOG!NOPRIV
C A,ASSIGN,NOCORE!DOLOG!NOPRIV
C DEASSI,DEASSIGN,NOCORE
C D,DEASSIGN,NOCORE
C DDT,DDTGO,NOPER!TTYRNU!INCORE!NORUN!NOPRIV!SETMAP
C TTY,TTYSUB,NOLOGIN!NOCORE!NOJOBN!NOINCK
C FINISH,FINIS,NOPER!NOACT!INCORE!NORUN!NOPRIV!SETMAP
C F,FINIS,NOPER!NOACT!INCORE!NORUN!NOPRIV!SETMAP
C REENTER,REENTER,TTYRNU!NOPER!INCORE!NORUN!SETMAP
C CSTART,STARTC,TTYRNC!INCORE!NORUN!SETMAP
C CCONTINUE,CONTC,TTYRNC!INCORE!NORUN
C DETACH,DETACH,NOCORE!NOINCK!NOPER!NOCRLF!NOMESS
C CDETACH,CDETACH,NOCORE!NOINCK
C ATTACH,ATTACH,NOCORE!NOJOBN!NOLOGIN!NOINCK
C DAYTIME,DAYTIM,NOCORE!NOJOBN!NOLOGIN!NOINCK
C EDDT,CEDDT,NOCORE!NOJOBN!NOLOGIN!NOINCK
C TIME,RUNTIM,NOCORE!NOLOGIN!NOINCK!NOJOBN
C RESOURCES,FREDEV,NOCORE!NOJOBN!NOLOGIN!NOINCK
C FILES,FILCOM,NOCORE!NOJOBN!NOLOGIN!NOINCK
C FI,FILCOM,NOCORE!NOJOBN!NOLOGIN!NOINCK
C REASSI,REASS,NOCORE!NOACT!INCORE!NORUN
C TALK,TALK,NOCORE!NOJOBN!NOLOGIN!NOMESS!NOINCK!NOCRLF!NOPER
C HELLO,HELLO,NOCORE!NOLOGIN!NOJOBN!NOINCK
C LOGIN,CLOGIN,NOCORE!NOLOGIN!NOPER!TTYRNU!INCORE!NOACT!NORUN
C L,CLOGIN,NOCORE!NOLOGIN!NOPER!TTYRNU!INCORE!NOACT!NORUN
C PPPN,PPPN,NOLOGIN!NOCORE!NOJOBN!NOINCK
C FORK,FORK,NOINCK!NOMESS!NOPER!NOCRLF!NOCORE!NOPRIV
C CFORK,CFORK,NOINCK!NOMESS!NOPER!NOCRLF!NOCORE!NOPRIV
C HELP,HLPRUN,RPGBIT!NOLOGIN
C WHERE,HLPRUN,RPGBIT!NOLOGIN
C SYSTAT,WHOCOM,RPGBIT!NOLOGIN
C WHO,WHOCOM,RPGBIT!NOLOGIN
C W,WHOCOM,RPGBIT!NOLOGIN
C FINGER,HLPRUN,RPGBIT!NOLOGIN
C FIND,HLPRUN,RPGBIT!NOLOGIN
C FIXIML,HLPRUN,RPGBIT!NOLOGIN
C PARRY,HLPRUN,RPGBIT!NOLOGIN
C COMPILE,RPGCOM,RPGBIT ;RPG COMMANDS
C DEBUG,RPGCOM,RPGBIT
C PREPARE,RPGCOM,RPGBIT
C LOAD,RPGCOM,RPGBIT
C EXECUTE,RPGCOM,RPGBIT
C CREF,RPGCOM,RPGBIT
C TRY,RPGCOM,RPGBIT
C PUB,RPGCOM,RPGBIT
C POX,RPGCOM,RPGBIT
C RER,RPGCOM,RPGBIT
C RERUN,RPGCOM,RPGBIT
C PROCES,RPGCOM,RPGBIT
C EDIT,ERPGCM,RPGBIT ;EDIT STYLE RPG COMMANDS
C ED,ERPGCM,RPGBIT
C CREATE,ERPGCM,RPGBIT
C TECO,ERPGCM,RPGBIT
C MAKE,ERPGCM,RPGBIT
; C TV,ERPGCM,RPGBIT ;FLUSHED 1-15-76 REG
; C CTV,ERPGCM,RPGBIT
C READ,ETCOM,RPGBIT ;COMMANDS TO E
C ETV,ETCOM,RPGBIT
C CETV,ETCOM,RPGBIT
C LIST,CPYCOM,RPGBIT ;COPY COMMANDS
C DIRECTORY,CPYCOM,RPGBIT!NOLOGIN
C DI,CPYCOM,RPGBIT!NOLOGIN
C DELETE,CPYCOM,RPGBIT
C RENAME,CPYCOM,RPGBIT
C TYPE,CPYCOM,RPGBIT!NOLOGIN
C COPY,CPYCOM,RPGBIT
C PRINT,CPYCOM,RPGBIT
C TRANSFER,CPYCOM,RPGBIT
C XGPLIST,CPYCOM,RPGBIT
C SEND,MAICOM,RPGBIT!NOLOGIN ;MAIL AND REMINDERS
C MAIL,MAICOM,RPGBIT!NOLOGIN
C GRIPE,MAICOM,RPGBIT!NOLOGIN
C REMIND,MAICOM,RPGBIT
C CANCEL,CMDRUN,RPGBIT ;DELETE REMINDERS
C LATER,MAICOM,RPGBIT
C RCV,HLPRUN,RPGBIT!NOLOGIN
C PLAN,MAICOM,RPGBIT
C EVENT,MAICOM,RPGBIT
C BATCH,MAICOM,RPGBIT
C RETRY,MAICOM,RPGBIT
C SPOOL,SPLCOM,RPGBIT ;SPOOLER
C QSPOOL,SPLCOM,RPGBIT!NOLOGIN
C UNSPOOL,SPLCOM,RPGBIT
C XSPOOL,SPLCOM,RPGBIT
C REWIND,DSCCOM,RPGBIT ;DART
C DUMP,DSCCOM,RPGBIT
C RESTOR,DSCCOM,RPGBIT
C ADVANC,DSCCOM,RPGBIT
C BACKSP,DSCCOM,RPGBIT
C TLIST,DSCCOM,RPGBIT
C EOT,DSCCOM,RPGBIT
C LOCATE,DSCCOM,RPGBIT
;ASSORTED PROGRAMS
C TN,TNCOM,RPGBIT
C TELNET,TNCOM,RPGBIT
C FTP,CMDRUN,RPGBIT
C DRD,DRDCOM,RPGBIT
C ZERO,CMDRUN,RPGBIT
C XEROX,CMDRUN,RPGBIT
C DO,CMDRUN,RPGBIT
C TEST,CMDRUN,RPGBIT
C DIAL,CMDRUN,RPGBIT
C LISP,CMDRUN,RPGBIT
C RSL,CMDRUN,RPGBIT
C DECIDE,ORACOM,RPGBIT!NOLOGIN
;MORE PROGRAMS - THAT NEED PRIVILEGES
C NS,NSCOM,RPGBIT ;NEWS SERVICE
C HOT,HOTCOM,RPGBIT ;NEWS HOT LINE
C UDPUFD,UDPCOM,RPGBIT ;UDP UFD MAKER
>
BEGIN COMTBL
DEFINE C(A,B,C),<
<SIXBIT /A/> ;ONLY FIRST SIX CHARACTERS.
>
LOSYS
↑↑COMTAB:
XLIST
NAMES
LIST
↑↑DISPL←.-COMTAB ;LENGTH OF TABLE
HISYS
;GENERATE THE DISPATCH TABLE AND SPECIAL BITS
DEFINE C(A,B,D)
< XWD D,B>
;SPECIAL HACK TO FORCE LOGIN FROM "ANY" COMMAND.
XWD NOCORE!NOLOGIN!NOPER!TTYRNU!INCORE!NOACT!NORUN,CXLOGI
↑DISP:
XLIST
NAMES
LIST
XWD NOCORE+NOJOBN+NOLOGIN+NOINCK,NOCOM ;CATCH ANYTHING THAT'S NOT A COMMAND
BEND COMTBL
PURGE NAMES ;RECLAIM SPACE FOR THE ASSMBLER
;CEDDT, SLEVEL, TYPSL
;CEDDT - ENTER EXEC DDT (EDDT)
CEDDT: PUSHJ P,STLNAC ;SET UP LINE(TAC1)
TLNN TAC1,CTYLIN ;IS HE ON THE CTY?
JRST COMERR ;NO, FLUSH HIM
JRST DDTCAL ;YES, GET EXEC DDT
;SLEVEL - SERVICE LEVEL COMMAND PRINT CURRENT SERVICE LEVEL
MAXLEV ←← =80 ;NOBODY CAN HAVE MORE THAN 80% OF THE MACHINE
SLEVEL:
TYPSL: PUSHJ P,SPRSSL ;MAKE SURE CURRENT SERVICE LEVEL IS SPREAD
;SPRSSL IS IN UUOCON
HRRZ TAC,JBTGSL(J)
IMULI TAC,=100
ADDI TAC,400000 ; TRY TO CORRECT FOR ROUNDOFF ERROR
HLRZS TAC
PUSHJ P,RADX10
JSP TAC,CONMES
ASCIZ /% SL
/
;PTTY, NOTLOG
;TYPE THE LOGICAL NAME OF THE TTY THE USER IS ON.
;"PTTY N", AS ABOVE FOR JOB N.
↑NOTLOG:JSP TAC,ERRMES
ASCIZ /No such job
/
PTTY: PUSHJ P,DECIN ;LOOK FOR JOB NUMBER ARGUMENT.
JRST PTTY1 ;NONE. USE THIS TTY.
JRST COMERA
JUMPE TAC1,NOTLOG
CAIL TAC1,JOBN ;LEGAL?
JRST NOTLOG ;NONE SUCH JOB
MOVE TAC,JBTSTS(TAC1)
TLNN TAC,JNA ;DOES HE HAVE A JOB NUMBER?
JRST NOTLOG ;NO, LOSE
MOVE AC1,JBTLIN(TAC1);LINE NUMBER
CAMN AC1,[-1] ;DETACHED?
JRST PTTYDT ;YES
TLNN AC1,CTYLIN ;CTY?
JRST NOTCTY
JSP TAC,CONMES
ASCIZ /CTY
/
NOTCTY: PUSH P,AC1
PUSHJ P,INLMES
ASCIZ /TTY/
POP P,TAC
HRRZ TAC,TAC
PUSHJ P,OCTPNT
JRST PTTY2
PTTY1: MOVE TAC1,DEVNAM(DDB)
PUSHJ P,PRNAME
LDB AC1,PUNIT
HLL AC1,LINTAB(AC1)
PTTY2: TLNN AC1,DDDLIN
JRST CRLF
PUSHJ P,INLMES
ASCIZ /, DD/
MOVE AC1,LETAB(AC1) ;NONZERO IT SAYS HERE
HLRZ TAC,PRGNUM(AC1)
PUSHJ P,OCTPNT
JRST CRLF
PTTYDT: JSP TAC,CONMES
ASCIZ /Detached
/
;PJOB COMMAND. DECLF, PJOBDV, PJOB
;"PJOB" PRINT JOB NUMBER OF JOB TTY IS ATTACHED TO
;"PJOB DEV" PRINT JOB NUMBER OF JOB USING DEVICE "DEV"
LOSYS
PJOBDV: PUSHJ P,CTEXT1 ;GET DEVICE NAME ARGUMENT
JUMPN TAC1,PJOBX ;JUMP IF ARGUMENT WAS GIVEN
JUMPE J,LOGPLS ;NO ARGUMENT. JUMP IF NO JOB HERE
↑PJOB: MOVE TAC,J ;JOB NO.
↑DECLF: PUSHJ P,RADX10 ;PRINT TAC AS DEC. THEN CRLF
JRST CRLF
HISYS
PJOBX: MOVE TAC,TAC1 ;TAC←SIXBIT DEVICE NAME.
PUSH P,TAC ;SAVE DEVICE NAME.
PUSHJ P,DEVPHY
SKIPA DDB,-3(P) ;NOT A REAL DEVICE. GET BACK TTY DDB. SKIP
JRST FNDDEV ;DEVICE NAME FOUND.
PUSHJ P,DADD00 ;NOT DEVICE, PERHAPS DD CHAN
JRST PJDVLZ ;NO, NO SUCH DEVICE.
LDB TAC1,[DDUSR+<(TAC1)>] ;YES, GET USE CODE
JUMPE TAC1,DEVFRE ;0, NOT IN USE
CAIGE TAC1,100 ;IF LESS THAN 100,
JRST FNDDV1 ;IT'S ASSIGNED TO THAT JOB
CAIL TAC1,200 ;ABOVE 200,
JRST DEVFR2 ;DETACHED FROM SYS (OR AVLCHN)
SUBI TAC1,100-DDL0 ;ELSE MAKE IT A TTY LINE NUMBER
PUSH P,TAC1
MOVEI AC1,(TAC1)
PUSHJ P,NOTCTY ;THIS WILL TYPE THE TTY NUMBER
POP P,TAC1
FNDDV0: SKIPN DDB,TTYTAB(TAC1) ;DOES IT HAVE A DDB?
JRST DEVFRE ;NO ONE HAS IT
FNDDEV: MOVE AC1,DEVMOD(DDB)
TLNE AC1,DVUDP
JRST PJBUDP ;SPECIAL FOR UDP.
LDB TAC1,PJOBN
JUMPE TAC1,DEVFR1 ;IF NOT IN USE, SAY SO.
FNDDV1: PUSH P,TAC ;(MAKE STACK DEPTH RIGHT!)
PUSHJ P,PJPRNM ;PRINT DEVICE NAME. TAC1→-1(P)
POP P,TAC
PUSHJ P,INLMES
ASCIZ / assigned to job /
POP P,TAC ;BY NOW, THIS IS THE JOB #
JRST DECLF
PJBUDP: LDB TAC,PUNIT ;UDP: GET INDEX TO TABLES
SKIPLE TAC1,UDPOWN-1(TAC)
JRST FNDDV1 ;PRIVATELY OWNED, TAC1←JOB NUMBER
JUMPE TAC1,DEVFR2 ;DETACHED
SKIPN UDPCNT-1(TAC)
JRST DEVFRE ;NO DDBS, NOT IN USE
PUSH P,TAC ;(MAKE STACK DEPTH RIGHT FOR PJPRNM)
PUSHJ P,PJPRNM
POP P,TAC
SKIPLE TAC,SATADR(TAC) ;IS THE SATID KNOWN?
PUSHJ P,SATTAC ;YES, PRINT SATID IF ANY
SUB P,[1,,1]
JSP TAC,CONMES
ASCIZ / public
/
PJDVLZ: POP P,(P)
MOVE DDB,-2(P)
MOVEI DAT,TTOBUF(DDB)
JRST NOTDEV
DEVFR1: TRNN AC1,ASSCON ;SKIP IF DEVICE IS DETACHED
JRST DEVFRE ;NO. DEVICE IS FREE.
DEVFR2: JSP TAC,PJBMSG
ASCIZ /Detached from system
/
DEVFRE: TLNE AC1,DVTTY
PUSHJ P,TTYKIL ;THIS COMMAND MADE A TTY DDB
JSP TAC,PJBMSG
ASCIZ /Not in use
/
PJBMSG: POP P,(P)
MOVE DDB,-2(P)
MOVEI DAT,TTOBUF(DDB)
JRST CONMES
PJPRNM: MOVE DDB,-5(P) ;THE TTY DDB
MOVEI DAT,TTOBUF(DDB) ;OUTPUT BYTE POINTER
EXCH TAC1,-2(P) ;BLARGH!
JRST PRNAME ;PRINT SIXBIT AND POPJ.
;PPPN
PPPN: PUSHJ P,DECIN ;GET ARGUMENT, IF ANY
JRST PPPN6 ;NO ARGUMENT. PPN FOR CURRENT JOB.
JRST COMERA ;ILL. ARGUEMENT
MOVSI TAC,NOINCK ;DON'T INITIALIZE A JOB JUST FOR ME!
IORM TAC,-1(P)
CAIGE TAC1,JOBN ;OUT OF BOUNDS?
CAIG TAC1,0
JRST ECOMA ;PRINT "OUT OF BOUNDS"
MOVE AC1,TAC1 ;USE THAT JOB NUMBER
PPPN5: MOVE TAC,JBTSTS(AC1)
SKIPE PRJPRG(AC1)
TLNN TAC,JNA
JRST NOTLOG
MOVE TAC,[POINT 6,PRJPRG(AC1)]
PUSHJ P,PPPN65 ;WRITE PPN
SKIPN DSKPPN(AC1) ;ANY ALIAS PPN?
JRST CRLF ;NO. TYPE CRLF AND RETURN
PUSHJ P,INLMES
ASCIZ / Alias /
MOVE TAC,[POINT 6,DSKPPN(AC1)]
PUSHJ P,PPPN65
JRST CRLF ;TYPE CRLF AND POPJ
PPPN6: MOVEI AC1,(J) ; NO ARGUMENT USE PPN OF CURRENT JOB
MOVE AC2,JBTSTS(J)
TLNN AC2,JLOG
JRST LOGPLS
JRST PPPN5
PPPN65: PUSHJ P,PPPN7 ;WRITE 3 SIXBIT CHARACTERS
MOVEI TEM,","
XCT TYO
PPPN7: MOVEI TAC1,3 ;3 CHARACTERS
PPPN8: ILDB TEM,TAC ;LOAD THE NEXT BYTE
JUMPE TEM,PPPN9 ;FLUSH NULL BYTES
ADDI TEM," " ;MAKE SIXBIT INTO ASCII
XCT TYO ;TYPE ONE CHARACTER
PPPN9: SOJG TAC1,PPPN8 ;LOOP
POPJ P,
;SDSKPPN - ALIAS COMMAND
;ALIAS COMMAND "ALIAS PRJ,PRG", "ALIAS PRJ", "ALIAS PRJ," OR "ALIAS"
;THE FIRST THRE SET DSKPPN(J) AND THE LAST RESETS IT
SDSKPPN:CAIE TEM,";"
CAIN TEM,12 ;TERMINATOR SEEN ALREADY?
JRST CDSKPPN ;YES. SET ALIAS TO LOGGED-IN NAME.
PUSHJ P,GETWRB ;LOOK FOR PRJ
JUMPN TAC1,SDKPP1
CAIE TEM,12 ;NO ARG AT ALL?
CAIN TEM,";"
JRST CDSKPPN ;NO ARG IS OK
JRST COMERR ;BAD ARGUMENT, BAD DELIMITER
SDKPP1: HLLZ AC2,TAC1 ;SAVE PRJ
TRNE TAC1,-1 ;CHECK SYNTAX.
JRST COMERR
CAIN TEM,"," ;COMMA SEEN?
JRST SDKPP2 ;YES.
CAIE TEM,12 ;NO COMMA MEANS ONLY PRJ TYPED. MAKE PRG FROM PRJPRG
CAIN TEM,";" ;BUT ONLY IF THE DELIMTER IS EITHER LF OR SEMICOLON
JRST ALDFL2 ;NO. ONLY PRJ TYPED. MAKE PRG FROM PRJPRG
JRST COMERR ;BAD DELIMITER
SDKPP2: PUSHJ P,GETWRB ;SCAN PRG
JUMPE TAC1,ALDFL1 ;IF NONE, PRG SET FROM OLD DSKPPN.
HLR AC2,TAC1 ;DON'T CARE ABOUT TERMINATOR HERE
TRNE TAC1,-1
JRST COMERR
CNGPRJ: CAMN AC2,MFDENT ;SAME AS 1,1?
JRST COMERR ;SOME THINGS NOT ALLOWED.
CAMN AC2,PRJPRG(J) ;SKIP UNLESS EXPLICITLY RESETTING ALIAS
CDSKPPN:MOVEI AC2,0 ;CLEAR ALIAS
MOVEM AC2,DSKPPN(J)
SETZM JBTUFD(J) ;CLEAR JBTUFD.
POPJ P,
ALDFL1: SKIPN TAC1,DSKPPN(J)
ALDFL2: MOVE TAC1,PRJPRG(J)
HRR AC2,TAC1
JRST CNGPRJ
GETWRB: PUSHJ P,CTEXT
JUMPE TAC1,NOJUST
TLNN TAC1,7777
LSH TAC1,-14
TLNN TAC1,77
LSH TAC1,-6
NOJUST: PUSHJ P,SKIPSB ;SKIP TO BREAK. THIS GUY MAY CALL TPOPJ!
POPJ P, ;BEWARE OF UPLEVEL RETURN FROM SKIPSB
;KJOB - KILL ATTACHED JOB. LOGPLS, KJOB2, JOBKL
;JOB IS GUARANTEED BY THE COMMAND DISPATCHER TO BE INCORE. (POSSIBLY SHRUNK)
KJOB: JUMPG J,KJOB1 ;JUMP IF THERE IS A JOB HERE.
SETZM -1(P) ;CLEAR NOJOBN SO COMRET WILL PRINT MESSAGE
LOGPLS: JSP TAC,ERRMES
ASCIZ /Login please
/
;ENTER AT KJOB1. AT KJOB1A IF JOB HAS NO CORE AND WE NEED TO RUN LOGOUT.
KJOB1A: MOVEI TAC,ASSPRG ;JOB HAS NO CORE. CLEAR ASSPRG IN TTY DDB
ANDCAM TAC,DEVMOD(DDB)
MOVEI TAC,JOBDA ;REQUEST JUST ENOUGH CORE FOR A JOB DATA AREA
PUSHJ P,CORE0 ;GET NEW CORE
JFCL
SKIPN JBTPAG(J)
JRST DLYCOR ;DELAY IF NEW CORE IS ON THE DISK (IT WILL BE)
MOVE AC1,JBTSTS(J)
KJOB1: PUSHJ P,STLNAC ;GET TTY BITS
TLNN TAC1,IMPBIT ;IMP'S GET TO RUN LOGOUT, DESPITE BEING ON PTYS.
TLNN TAC1,PTYLIN ;FLUSH PTY JOBS INSTANTLY!
TLZN AC1,JLOG!JACCT ;SHALL WE RUN LOGOUT?
JRST KJOB2 ;NO.
SKIPN JBTPAG(J) ;YES. WE'LL RUN LOGOUT. SKIP IF JOB HAS CORE.
JRST KJOB1A ;WE NEED TO GET SOME CORE FIRST
TLO AC1,JACCT ;SET "ACCOUNTING PGM RUNNING"
HLLM AC1,JBTSTS(J)
PUSHJ P,ALOGN1
MOVSI TAC,TTYRNU+NOMESS
XORM TAC,-1(P)
PUSH P,['LOGOUT']
PUSH P,[' 1 2']
JRST ARPCOM ;RUN LOGOUT.DMP[1,2]
;LOGOUT TERMINATES VIA EXIT UUO WHICH JUMPS TO JOBKL.
COMMENT $
JOBKL KILL AT UUO LEVEL. CALLED FROM:
ESTOP3 - KILL PHANTOMS (SCHEDULE A MONITOR JOB)
ESTOP - KILL PHANTOMS - (ESTOP CALLED AT UUO LEVEL)
KILCM6 - UNPRIVILEGED KILL COMMAND
EXIT UUO - KILL UNLOGGED-IN JOBS
LOGOUT UUO
KILCM1 - KILL COMMAND
$
;AT KJOB2 FROM KJOB COMMAND FOR KILLING JOB ON A PTY OR UNLOGGED IN JOBS.
;IF JOB HAS CORE, SCHEDULE A MONITOR JOB TO RUN AT UUO LEVEL AND KILL IT.
KJOB2: SKIPN JBTPAG(J) ;SKIP IF JOB HAS CORE.
JRST JOBKL1 ;NO CORE.
PUSHJ P,APRMAP ;SETUP MAP FOR THIS JOB.
JSP TAC1,MONJOB ;SCHEDULE MONITOR JOB. EXIT TO COMRET.
JOBKL: MOVEI TAC1,ESTOP2 ;ESTOP AT END OF PDL
JSP TAC,MONSTR ;SET UP ACS AND PDL LIST
JOBKL1: PUSHJ P,DSFLUSH ;MAKE RESET TO KILL SPECIAL DETACHED SEGMENTS.
PUSHJ P,RESETSEG ;KILL DETACHED SEGMENTS
SKIPN JBTPAG(J) ;SKIP IF JOB IS IN CORE
JRST JOBKL2 ;JUMP IF THERE'S NO CORE ASSIGNED TO THIS JOB.
PUSHJ P,RESET ;FINISH IO BEFORE DEASSIGNING
PUSHJ P,DEASTY ;WHILE WE STILL HAVE CORE, DEASSIGN DEVICES XCPT TTY
PUSHJ P,JOB1 ;RESET, CORE 0, FLUSH JBTMAP.
JOBKL2: PUSHJ P,DEASTY ;DEASSIGN ALL BUT TTY
PUSHJ P,TTYERR ;GET TTY FOR OUTPUT
PUSHJ P,INLMES
ASCIZ /Kjob
/
PUSHJ P,PRPER
PUSHJ P,TTYSTR
PUSHJ P,TTYKIL ;RETURN TTY TO VIRGIN STATE
SKIPE AC1,JBTJL(J) ;AND JOB PRIORITY HISTORY
PUSHJ P,FSGIVE
SETZM JBTJL(J)
SKIPE AC1,JBTFS(J) ; ANY SPARE FREE STORAGE?
PUSHJ P,FSGIVE
SETZM JBTFS(J)
PUSHJ P,TMPKIL ;FLUSH ALL HIS TMPCOR FILES (IGNORING ALIAS)
HLRZ AC1,SAVSAI(J)
JUMPE AC1,.+2
PUSHJ P,FSGIVE ;RETURN SWAP UUO AC SAVE BLK
SETZM SAVSAI(J)
PUSHJ P,RELPDL ;RELEASE PDL. PDL MAY BE USED UNTIL WE LEAVE
;UUO LEVEL OR CH7
MOVSI TAC,JNA!JLOG!JACCT ;CLEAR BITS (FORMERLY CALLED KSTOP)
ANDCAM TAC,JBTSTS(J)
SETZM PRJPRG(J) ;KEEP TABLE ACCURATE
SETZM JOBNAM(J)
SETZM TTIME(J) ;CLEAR RUN TIME FOR *SPY*
SETZM JBTBTM(J) ;CLEAR LOGIN TIME FOR ACCOUNTING
SETZM JBTGSL(J) ;CLEAR GUARANTEED SERVICE WORDS
SETOM JBTWKM(J) ;WAKE ON ALL INTERRUPTS
MOVEI TAC,400000
IORM TAC,JBTLIN(J) ;MAKE AN INVALID TTY NUMBER
JRST ESTOP2
;KILCOM - KILL COMMAND.
KILCOM: PUSHJ P,DECIN ;GET ARGUMENT
JRST NOTENF ;NONE
JRST COMERA ;ILLEGAL
CAMN J,TAC1 ;NO SUICIDE!
JRST ILLKIL
CAIL TAC1,JOBN ;LEGAL?
JRST NOTLOG ;TOO BIG
JUMPLE TAC1,NOTLOG ;TOO SMALL
MOVE TAC,JBTSTS(TAC1)
TLNN TAC,JNA ;LEAVE US NOT FLUSH NON-EX JOBS
JRST NOTLOG
TLNE TAC,JSEG ;IS IT SEG2.
JRST KILCM5 ;JUST CHANGE NAME OF UPPER SEGMENT.
MOVSI AC1,KILPRV ;LOOK FOR KILL PRIVILEGE
TDNE AC1,JBTPRV(J) ;...
JRST KILOK ;HE HAS THE POWER
HRRZ AC1,PRJPRG(ITEM) ;GET PROGRAMMER NAME
HRRZ TAC,PRJPRG(TAC1) ;GET PRG OF GUY WE'RE KILLING
CAME TAC,AC1 ;SAME
JRST NOTYRS ;LOSE!
KILOK: MOVE TAC,JBTSTS(TAC1)
TLNE TAC,SHF
JRST DLYCM ;WAIT A WHILE
PUSH P,J ;KILLER'S JOB
MOVE J,TAC1 ;J←VICTIM
TLNE TAC,SWP ;SWAPPED OUT?
JRST KILCM3 ;YES, GET HIM IN
SKIPN JBTPAG(J) ;SKIP IF INCORE.
JRST KILCM7 ;VICTIM HAS NO CORE ASSIGNED.
MOVE TAC,-1(P)
MOVE TAC,JBTPRV(TAC) ;GET PRIVILEGES OF KILLER
TLNE TAC,KILPRV ;IF HE HAS THE PRIV
JRST KILCM6 ;HE CAN KILL DESPITE ACTIVE IO
PUSHJ P,ANYACT ;YES, ARE DEVICES ACTIVE?
JRST KILCM3 ;YES, DELAY
JRST KILCM6 ;WE HAVE CORE AND NO ACTIVE DEVICES
KILCM7: MOVEI TAC,JOBDA ;MAKE JOB DATA AREA FOR THE VICTIM
PUSHJ P,CORE0
JFCL
SKIPN JBTPAG(J)
JRST KILCM4 ;DELAY UNTIL VICTIM HAS CORE IN CORE.
KILCM6: MOVSI TAC1,CMWB ;CLEAR COMMAND WAIT BIT
ANDCAM TAC1,JBTSTS(J) ;SO VICTIM WILL RUN
MOVEI TAC1,KILCM1 ;ASSUME KILL WITH IO ACTIVE
MOVE TAC,-1(P) ;JOB NUMBER OF KILLER
MOVE TAC,JBTPRV(TAC) ;PRIVS OF KILLER.
TLNN TAC,KILPRV ;SKIP IF HE HAS IT
MOVEI TAC1,JOBKL ;NORMAL KILL - AFTER IO STOPS.
PUSHJ P,APRMAP ;SETUP MAP TO POINT TO VICTIM.
PUSHJ P,MONJOB ;SCHEDULE A MONITOR JOB.
POP P,J
POPJ P, ;COMRET WILL RESTORE MAP.
KILCM3: PUSHJ P,DLYCOM ;SET CMWB. GET VICTIM IN CORE IF NECESSARY.
KILCM4: POP P,J
JRST DLYCM ;DELAY KILLER.
KILCM5: MOVE TAC,PRJPRG(TAC1) ;HERE TO KILL A SEGMENT.
MOVEM TAC,JOBNAM(TAC1) ;JUST CLOBBER IT'S NAME
IFN FTSTAT,< PUSH P,J
MOVE J,TAC1
PUSHJ P,NAMSTT
POP P,J >;FTSTAT
POPJ P,
NOTYRS: JSP TAC,ERRMES
ASCIZ /Not one of your jobs
/
ILLKIL: JSP TAC,CONMES
ASCIZ /Use "KJOB" to log yourself out
/
;PRIVILEGED KILL ROUTINE, FLUSHES THINGS WITHOUT WAITING
;ENTER HERE AS A MONITOR JOB, I.E., RUNNING AT UUO LEVEL.
KILCM1: MOVEI TAC1,ESTOP
JSP TAC,MONSTR ;SETUP UUO LEVEL ACS.
PUSHJ P,RESETSEG ;FLUSH HIS SEGMENT
PUSHJ P,IOKILL ;KILL ALL IO WITHOUT WAITING
PUSHJ P,TTYFND ;FIND TTY
PUSHJ P,TSETBF ;CLEAR IO
MOVSI IOS,TOIP
ANDCAB IOS,DEVIOS(DDB) ;CLEAR TOIP SO ESTOP WON'T HANG
PUSHJ P,KILSPW ;KILL SPACEWAR
JRST JOBKL ;LET KJOB ROUTINE DO THE REST
;CORE COMMAND. JOB1
; "CORE #" - ASSIGNS #*1024 WORDS OF CORE TO JOB
;"CORE" WITH NO ARG. WILL PRINT NO OF FREE BLOCKS LEFT
CORE: PUSHJ P,DECIN ;GET NO. OF 1K BLOCKS (OR PAGES!)
JRST COR4 ;NO ARGUMENT - TYPE INFORMANTION
JRST COMERA ;ILLEGAL DECIMAL CHARACTER RETURN
MOVE TAC,JBTSTS(J) ;GET JOB STATUS WORD
TLNN TAC,JLOG ;IS JOB LOGGED IN?
JRST LOGPLS ;NO, TYPE OUT MESSAGE
PUSHJ P,CLRTPV ;CLEAR TEMPORARY PRIVILEGES
PUSH P,TAC1
LDB TAC1,PSEGN
SKIPE TAC1 ;SKIP IF NO SEGMENT
PUSHJ P,CORSGT ;GET NUMBER OF WORDS IN SEGEMENT
MOVN AC1,TAC1 ;-CORE SIZE OF UPPER, IF ANY
ADD AC1,SWAPLIMIT ;RESULT IS MAXIMUM PERMISSIBLE SIZE OF LOWER
LSH AC1,CSHIFT ;CONVERT TO PAGES OR K
POP P,TAC1 ;CORE SIZE HE IS REQUESTING (IN PAGES OR K)
CAMLE TAC1,AC1 ;TOO BIG?
JRST CORFX1 ;YES. TELL HIM SO.
TLNN TAC,SWP ;IS HE SWAPPED OUT?
JRST COR3 ;NO. CONTINUE
SKIPE JBTPAG(J) ;SKIP IF THERE'S NO CORE IN CORE.
JRST DLYCR1 ;JOB IS IN TRANSIT. WAIT FOR SWAPPING TO FINISH
SKIPN TAC,TAC1 ;IS HE REQUESTING 0 CORE?
TROA TAC,1 ;YES. SET CORE SIZE TO 1K - SHRINK BEFORE SWAPIN
SOSA (P) ;NOT 0. CORE0K ALWAYS SKIPS - RETURN TO COMRET
PUSH P,[DLYCOR-1] ;FOR CORE 0, WE DELAY COMMAND AFTER CORE0K
JRST CORE0K ;SET SWAPIN IMAGIN SIZE. RETURN, BEING DONE.
COR3: JUMPE TAC1,COR0 ;RELEASE DEVICES IF ASKING FOR 0 CORE
MOVE TAC,TAC1
LSH TAC,-CSHIFT ;CONVERT REQUEST TO WORDS
SUBI TAC,1 ;HIGHEST REL. LOC.
PUSH P,JBTPAG(J) ;SAVE OLD CORE ASSIGNMENT
LDB TAC1,PSEGN ;SEE IF HE HAS AN UPPER
SKIPE TAC1
PUSHJ P,CORSGT ;YES, GET ITS SIZE INTO TAC1
ADD TAC1,TAC ;ADD LOWER SIZE + UPPER SIZE
CAMLE TAC1,CORMAX ;WILL IT FIT?
JRST CORFX ;NO
;IF THE JOB HAS NO CORE AT ALL, CORE0 WILL ONLY ASSIGN CORE ON THE DISK. REG
PUSHJ P,CORE0 ;TRY TO ASSIGN CORE
JRST CORFX ;CAN'T DO IT
POP P,AC1 ;GET BACK OLD CORE ASSIGNMENT
JUMPN AC1,CPOPJ ;RETURN NOW IF THERE WAS CORE ASSIGNED PREVIOUSLY
JRST ESTOP2 ;PREVENT CONTINUE COMMAND.
;IMGOUT=0 SO SWAPPER (INJO2) WIPES JOBDAT ON SWAPIN
CORFX: POP P,(P) ;POP OFF OLD CORE ASSIGNMENT
CORFX1: MOVE DDB,-2(P) ;GET TTY DDB BACK
JSP TAC,ERRMES
ASCIZ /Not enough core
/
COR0: SKIPN JBTPAG(J) ;HERE FOR CORE 0 COMMAND. SKIP IF JOB HAS CORE.
POPJ P, ;RETURN QUICK IF USER HAS NO CORE ALREADY
MOVSI TAC,TTYRNU!NOPER!NOCRLF
IORM TAC,-1(P) ;TELL COMRET TO PUT TTY IN USER MODE
PUSHJ P,APRMAP
JSP TAC1,MONJOB ;SETUP MONITOR JOB. EXIT TO COMRET.
MOVEI TAC1,HOLD ;HERE AT UUO LEVEL. PUT ERROR STOP ON END OF PDL
JSP TAC,MONSTR ;SETUP ACS FOR MONITOR JOB.
JOB1: PUSHJ P,RESET ;RELEASE ALL IO DEVICES ASSIGNED TO THIS JOB
PUSHJ P,TTYFNU ;FIND TTY FOR THIS JOB (SETUP J WITH JOB NO.)
SETOM STIME(J) ;MARK CORE IMAGE ALTERED
LDB DAT,PSEGN
MOVE TEM,JBTSTS(DAT)
TLNN TEM,JWP
SETOM STIME(DAT)
MOVEI TAC,0 ;TAC←0 NEW CORE ASSIGNMENT
PUSHJ P,CORE1 ;RELEASE OLD CORE ASSIGNMENT.
JRST JOB1A ;CORE1 WILL SKIP. - IF IT DOESN'T WE'RE IN TROUBLE
PUSHJ P,NOCORQ ;JOB TO NULQ. CLEAR SWAP IMAGE. RELEASE JBTMAP
IFN FTDRD,< SKIPN JBTPAG(J) ;THE FOLLOWING IS MORE DRD CODE
POPJ P,
PUSHACS
PUSHJ P,DISMES
ASCIZ /JBTPAG NOT 0 AT JOB1 /
PUSHJ P,DISJOB
PUSHJ P,DISCRLF
POPACS >;IFN FTDRD
POPJ P,
JOB1A: PUSHACS
PUSHJ P,DISJOB
PUSHJ P,DISMES
ASCIZ / CORE1 FAILED TO RELEASE CORE AT JOB1.
/
PUSHJ P,DISFLU
PUSHJ P,WDDTCAL
POPACS
PUSHJ P,WSCHED ;ALLOW THE ERROR CONDITION TO GO AWAY.
JRST JOB1
;COR4 - CORE COMMAND WITHOUT ARGUMENT - PRINT STUFF
IFE FTPAGER,<↑↑CSHIFT←←-=10;>↑↑CSHIFT←-=9 ;SHIFT FROM WORD COUNT TO K OR PAGES
IFN FTPAGER,<DEFINE FOOMAC(A)<ASCIZ/ pages A
/>>
IFE FTPAGER,<DEFINE FOOMAC(A)<ASCIZ/ K A
/>>
COR4: MOVSI TAC,NOINCK ;DON'T INITIALIZE A JOB
IORM TAC,-1(P)
MOVE DDB,-2(P) ;RESTORE TTY DDB
MOVE TAC,JBTSTS(J) ;GET JOB STATUS WORD
TLNN TAC,JLOG ;IS JOB LOGGED IN?
JRST COR2.1 ;NOT LOGGED IN. HE HAS NO CORE.
MOVEI TAC1,(J) ;GET JOB NUMBER
PUSHJ P,CORSGT ;GET CORE SIZE IN WORDS
LSH TAC1,CSHIFT ;COMPUTE K (OR PAGES)
MOVEI TAC,(TAC1)
PUSHJ P,RADX10
LDB TAC1,PSEGN
JUMPE TAC1,COR4A
PUSHJ P,CORSGT ;CORE SIZE OF UPPER IN WORDS
LSH TAC1,CSHIFT ;COMPUTE K (OR PAGES)
PUSH P,TAC1
MOVEI TEM,"+"
XCT TYO
POP P,TAC
PUSHJ P,RADX10
COR4A: PUSHJ P,INLMES
FOOMAC ()
COR2.1: MOVE TAC,CORMAX ;AVAIL CORE.
CAMLE TAC,SWAPLIMIT ;BIGGER THAN SWAPLIMIT?
MOVE TAC,SWAPLIMIT ;YES, PRINT IT INSTEAD
LSH TAC,CSHIFT ;COMPUTE K (OR PAGES)
PUSHJ P,RADX10 ;WRITE
PUSHJ P,INLMES
FOOMAC (maximum)
MOVE TAC,CORMAX ;GET MAX AGAIN
CAMG TAC,SWAPLIMIT ;BIGGER THAN MAX?
POPJ P,
LSH TAC,CSHIFT ;COMPUTE K (OR PAGES)
PUSHJ P,RADX10 ;YES, PRINT IT ALSO
JSP TAC,CONMES ;PRINT MESSAGE AND POPJ
FOOMAC (<user core>)
PURGE FOOMAC
;START, STARTC, REENTE, START, CSTART, REENTER COMMANDS
; "START L" OR "START" - START AT LOC. L OR STARTING ADDRESS
; "CSTART L" OR "CSTART" - START AT LOC. L(TTY IN COMMAND MODE)
START: ;SAME AS STARTC
STARTC: PUSHJ P,SKIPSJ ;GET ARGUMENT, IF ANY
CAIE TEM,"+"
CAIN TEM,"-" ;REQUESTING INCREMENT?
JRST STARTA ;YES, SCAN
PUSHJ P,OCTIN ;CONVERT POSSIBLE OCTAL NO ARG.
XCTR XR,[SKIPA TAC1,JOBSA] ;NO ARGUMENT. GET JOBSA
JRST COMERA ;ILLEGAL CHARACTER.
XCTR XR,[CAME TAC1,JOBSA] ;STARTUP ADDRESS TYPED?
PUSHJ P,CLRTPV ;YES, CLEAR TEMP PRIVILEGES
HRRZ TAC,TAC1 ;GET STARTUP ADDR
TDZA TAC1,TAC1
STARTB: XCTR XR,[HRRZ TAC,JOBSA]
JUMPN TAC,STRTCK ;ADD INCREMENT AND START
JSP TAC,ERRMES
ASCIZ /No starting address
/
STARTA: CAIE TEM,"+" ;+?
JRST STARTE ;NO, MUST BE -
PUSHJ P,OCTINS ;YES, READ INC
SKIPA TAC1,[1] ;INVENT 1 FOR NO ARG
JRST COMERA
JRST STARTB
STARTE: PUSHJ P,OCTINS ;GET - INC
SKIPA TAC1,[1] ;INVENT 1 FOR NO ARG
JRST COMERA
MOVN TAC1,TAC1 ;NOW NEGATE
JRST STARTB
;"REENTER" - REENTER USER PROGRAM
REENTE: PUSHJ P,SKIPSJ
CAIN TEM,"-"
JRST REENTM ;GET - INC
PUSHJ P,OCTIN
TDZA TAC1,TAC1 ;0 FOR NO ARG
JRST COMERA ;ILL CHAR
REENTN: XCTR XR,[HRRZ TAC,JOBREN]
JUMPN TAC,STRTCK ;ADD INCREMENT AND START
JSP TAC,ERRMES
ASCIZ /No Reenter address
/
REENTM: PUSHJ P,OCTINS
SKIPA TAC1,[1]
JRST COMERA
MOVN TAC1,TAC1
JRST REENTN
STRTCK: JUMPE TAC1,.+2 ;ANY INCREMENT?
PUSHJ P,CLRTPV ;YES, CLEAR TEMP PRIVILEGES
ADD TAC1,TAC ;ADD INCREMENT
JRST USTART ;NOW START IT UP
;DDTGO - DDT COMMAND
DDTGO: XCTR XR,[HRRZ TAC1,JOBDDT] ;DDT STARTING ADR. IN JOB DATA AREA
JUMPN TAC1,DDTG1 ;JUMP IF DDT IS LOADED.
JSP TAC,ERRMES ;ZERO PRINT "NO DDT"
ASCIZ /No DDT
/
;KLUDGE TO MAKE SURE DDT MEMORY IS WRITEABLE
DDTG1: HLRZ TAC,JBTPAG(J)
LSH TAC,=9 ;TAC←NUMBER OF WORDS IN THE LOWER
CAIGE TAC1,(TAC) ;SKIP IF DDT STARTS IN UPPER.
JRST USTART ;SETUP JOBOPC, START DDT IN USER MODE.
XCTR XR,[MOVE TAC1,JOBPC] ;GET CURRENT PC. (SEE USTART)
TLNN TAC1,USRMOD
JRST DDTG2
MOVSI TAC,JOBDAC ;MOVE DUMP ACS TO USER'S SHADOW ACS
XCTR XBLTRW,[BLT TAC,17]
DDTG2: JSP TAC1,MONJOB ;GET TO UUO LEVEL. CALL MSTART
JSP TAC,MONSTR ;HERE AT UUO LEVEL. SETUP ACS.
PUSHJ P,UNPURE ;TRY TO UNPURIFY UPPER
JRST DDTPUR ;FAILED TO UNPURIFY UPPER.
DDTG3: XCTR XR,[HRRZ TAC,JOBDDT] ;DDT STARING ADDRESS.
XCTR XR,[HLL TAC,JOBOPC] ;WITH HIS OLD FLAGS
TLO TAC,USRMOD ;SET USER MODE.
NOKL10,<TLZ TAC,4037 ;CLEAR IOT-USER AND @() BITS>
IFKL10,<TLZ TAC,4037!PCPUBL ;CLEAR IOT-USER AND @() BITS. SET PRIVATE>
MOVEM TAC,UUOPC(J) ;STORE AS RETURN FROM UUOLEVEL
JRST USRXIT ;UUOCON "RETURNS" TO DDT'S START ADDRESS.
DDTPUR: MOVE J,JOB(PID) ;J WAS CLOBBERED BY UNPURE.
PUSHJ P,TTYERP
PUSHJ P,INLMES
ASCIZ /Couldn't unpurify upper. Continue to try anyway/
PUSHJ P,PRCRCC
PUSHJ P,TTYSTC ;NOW, FORCE TTY TO TYPE STUFF.
PUSHJ P,SETSTP ;MAKE US STOP SOON
JRST DDTG3 ;"RETURN" FROM UUOLEVEL TO DDT,
;BUT UUOCON WILL STOP US.
;STOP, "HALT" OR "<CONTROL>C", CONT, CONTC - CONTINUE AND CCONTINUE COMMAND
;SCANNER ROUTINES DUMMY UP 'HAL' (HALT) WHEN CONTROL C TYPED IN.
;STOP MUST BE DELAYED IF THIS JOB IS SYSTEM TAPE USER
;AND SYSTEM TAPE IS ACTIVE. OTHERWISE, THE JOB WILL NOT BE
;STOPPED WHEN DONE USING THE SYSTEM TAPE.
↑STOP: JUMPE J,STOPB
MOVSI TAC,JNA ;MAKE SURE THIS JOB IS FULLY INITIALIZED.
IORM TAC,JBTSTS(J) ;(SINCE HE MAY HAVE BEEN IN CMWQ BEFORE CALL)
CAMN J,STUSER ;IS THIS SYSTEM TAPE USER?
JRST STOPA ;YES
PUSHJ P,STOPCK ;CAN THE JOB STOP? (CHECK DSK DDBS)
JRST MAKCNC ;PUT BACK CONTROL C.
PUSHJ P,STOP1 ;STOP JOB
STOPB: MOVSI TAC,JACCT
ANDCAB TAC,JBTSTS(J) ;GOODBYE LOSER!
TLNN TAC,JLOG ;IS JOB LOGGED IN?
JUMPN J,STOPB1 ;NO. JUMP IF THERE'S A JOB NUMBER ASSIGNED
MOVE TAC1,LINSAV
MOVE TAC1,TTYTAB(TAC1);DDB
MOVEI TAC,25 ;ROOM TO PRINT ↑C CRLF AND DOT and fill, etc.
CAML TAC,TOFCTR(TAC1);SEE IF WE HAVE ENOUGH ROOM IN OUTPUT BUFFER
JRST MAKCN2 ;NOT ENOUGH ROOM IN BUFFER, TRY AGAIN LATER
MOVEI TAC,[BYTE(7)"↑","C",15,12] ;↑C CRLF
JRST CONMES ;PRINT ↑C CRLF. RETURN TO COMRET
;HERE TO KILL UNLOGGED-IN JOB THAT TYPES ↑C. INVENT A K COMMAND FOR THEM.
STOPB1: SUB P,[2,,2] ;FLUSH RETURN TO COMRET + MAJIC BITS/DISPATCH
JRST SCREWU ;ONCE MORE THRU THE COMMAND LOOP. WITH A 'K'.
STOPA: SUB P,[1,,1] ;ACTCHK MAY CALL DLYCM1 - CAN'T HAVE ANYTHING
; PUSHED - NOT EVEN THE CALL TO ACTCHK
PUSHJ P,ACTCHK ;RETURN IF THERE ARE ARE NO ACTIVE DEVICES
PUSHJ P,ESTOP ;STOP THE JOB AND LET GO OF SYSTEM TAPE
PUSH P,[COMRET] ;REPLACE RETURN ADDRESS ON STACK
JRST STOPB
MAKCNC: MOVE TAC1,LINSAV
MOVE TAC1,TTYTAB(TAC1)
MOVEI TAC,600
DPB TAC,TITAKR(TAC1)
JRST DLYCR1 ;DON'T REQUE, OR HE WON'T GET OUT OF THIS STATE!!!
MAKCN2: MOVEI TAC,600 ;PUT THE ↑C BACK
DPB TAC,TITAKR(TAC1)
JRST DLYCM2 ;Wait for output buffer to empty.
;CCONTINUE, CONTINUE,
; "CCONT" - CONTINUE EXECUTION(TTY REMAINS IN COMMAND MODE)
; "CONT" - CONTINUE EXECUTION FROM WHERE LEFT OFF
CONTC: ;SAME AS CONT
CONT: MOVSI TAC1,JERR
TDNE TAC1,JBTSTS(J) ;IS JOB ERROR BIT SET?
JRST NOCONT ;YES, LOSE
MOVNI TAC1,RUNQ ;NO, REQUE TO RUN QUEUE
MOVEM TAC1,JOBQUE(J)
JRST REQUE
NOCONT: JSP TAC,ERRMES ;YES, PRINT CANT CONTINUE
ASCIZ /Can't continue
/
;SETUWP CLRUWP COMMANDS, SETWPS, CLRWPS
SETWPS: PUSH P,[-1,,0] ;NO PRO BITS YET
CAIA
CLRWPS: PUSH P,[0] ;NO PRO BITS YET
PUSHJ P,OCTIN
JRST NOSPRO ;NO SET PRO
JRST [POP P,(P)
JRST COMERA]
CAILE TAC1,777 ;LEGAL?
JRST ILLPRO
TRO TAC1,400000 ;FLAG THAT ARGUMENT WAS TYPED.
HRRM TAC1,(P) ;STORE ARGUMENT.
NOSPRO: PUSH P,J ;MUST PUSH THIS - ARG TO ACCESS.
LDB J,PSEGN
JUMPE J,NXSEG
PUSHJ P,ACCESS
JRST WPSEG
JRST WPSEG
HRRZ TAC1,-1(P) ;GET PRO BITS
TRNN TAC1,400000 ;IS HE REQUESTING BIT SETTINGS?
JRST NOSPR1 ;NO
MOVE TAC1,(P) ;JOB NUMBER OF LOWER
MOVE TAC1,JBTPRV(TAC1)
TLNN TAC1,SEGPRV ;DOES HE HAVE PRIV?
TRNN TAC,400 ;NO, CHECK PROTECTION PROTECTION
CAIA ;OKAY TO DIDDLE
JRST WPSEG ;LOSE
HRRZ TAC1,-1(P) ;GET BITS AGAIN
ANDI TAC1,377 ;DON'T LET HIM SET UNPURIFIED BIT
DPB TAC1,[POINT 9,JOBCRD(J),8]
NOSPR1: MOVSI TAC,JWP
SKIPGE -1(P)
IORB TAC,JBTSTS(J) ;SETUWP
SKIPL -1(P)
ANDCAB TAC,JBTSTS(J) ;CLRUWP
POP P,-1(P) ;MOVE J BACK ONTO FLAG
HLRZ AC1,JBTPAG(J) ;GET NUMBER OF PAGES IN SEGMENT
LSH AC1,=9 ;CONVERT TO SEGMENT WORD COUNT
SUBI AC1,1 ;SEGMENT PROTECTION
TLNE TAC,JWP
TLO AC1,400000 ;SET WP BIT IF JWP SET
PUSHJ P,UAPPLY ;APPLY TO ALL LOWERS
PUSHJ P,SETRLC ;(ARGUMENT TO UAPPLY)
IFN FTPAGER,<
LDB DDB,[POINT 1,JBTSTS(J),JWPPOS]
PUSHJ P,WPMAPL ;SET WRITE PROTECT ACCORDING TO DDB
PUSHJ P,AUPMAP ;CHANGE ALL LOWERS OF OUR UPPER
>;FTPAGER
POP P,J
POPJ P,
SETRLC: SKIPN JBTPAG(J)
POPJ P, ;LOWER IS NOT INCORE.
PUSHJ P,APRMAP ;SETUP MAP TO POINT TO THE LOWER
XCTR XW,[MOVEM AC1,JOBRL2]
POPJ P,
WPSEG: SKIPA TAC,[[ASCIZ/Protection failure
/]]
NXSEG: MOVEI TAC,[ASCIZ/No upper segment
/]
SUB P,[2,,2]
JRST ERRMES
ILLPRO: POP P,(P)
JSP TAC,ERRMES
ASCIZ /Illegal protection code
/
;DISABL, ENABLE PRIVILEGES
DISABL: PUSHJ P,PRVSET ;GET BIT INTO TAC
JRST NXPRV ;NO SUCH PRIVILEGE
HRLOI TAC,-1-LUPPRV ;CR TYPED, CLEAR ALL BITS (EXCEPT LUPPRV)
JFCL ;NOT LEGAL PRIV FOR THIS USER (OK TO CLEAR)
ANDCAM TAC,JBTPRV(J)
POPJ P,
ENABLE: PUSHJ P,PRVSET
JRST NXPRV
SKIPA TAC,JB2PRV(J) ;CR, COPY PRIVILEGES FROM PASSIVE
JRST ILLPRV ;NOT LEGAL FOR THIS USER
IORM TAC,JBTPRV(J)
POPJ P,
NXPRV: JSP TAC,ERRMES
ASCIZ /No such privilege
/
ILLPRV: JSP TAC,ERRMES
ASCIZ /You can't have it
/
LOSYS ;PUT PRIVILEGE NAMES IN LOW CORE FOR PEEK TO SEE
DEFINE XLPRIV(NAM,VAL)< 'NAM',,VAL>
DEFINE XRPRIV(NAM,VAL)<>
↑LFTTAB:PRIVS
↑LFTLEN←←.-LFTTAB
DEFINE XLPRIV(NAM,VAL)<>
DEFINE XRPRIV(NAM,VAL)<'NAM',,VAL>
↑RHTTAB:PRIVS
↑RHTLEN←←.-RHTTAB
HISYS
PRVSET: PUSHJ P,CTEXT1
JUMPE TAC1,CPOPJ1 ;CR OR DELIM TYPED
IFG LFTLEN,< MOVSI TAC,-LFTLEN ;LENGTH OF LEFT TABLE
FNDLFT: HLLZ AC1,LFTTAB(TAC)
CAMN AC1,TAC1
JRST ISLFT
AOBJN TAC,FNDLFT >;LFTLEN
IFG RHTLEN,< MOVSI TAC,-RHTLEN
FNDRHT: HLLZ AC1,RHTTAB(TAC)
CAMN AC1,TAC1
JRST ISRHT
AOBJN TAC,FNDRHT >;RHTLEN
POPJ P, ;NO SUCH PRIVILEGE
ISLFT: HRLZ TAC,LFTTAB(TAC) ;LEFT HALF BIT
CAIA
ISRHT: HRRZ TAC,RHTTAB(TAC) ;RIGHT HALF BIT
AOS (P)
AOS (P) ;AT LEAST 2 SKIPS
TDNE TAC,[RSPRVS] ;IS HE REQUESTING A RESTRICTED PRIVILEGE?
POPJ P, ;YES, FLUSH
MOVE AC1,JB2PRV(J) ;GET PASSIVE PRIVILEGES
TLNN AC1,PRIPRV ;IF HE HAS PRIV PRIV, ALL IS OK
TDNE TAC,AC1 ;OR IF THE PRIV HE WANTS IS IN PASSIVE TABLE
AOS (P) ;SKIP IF PRIV OK
POPJ P,
;PRJOB, HELLO, ALOGIN, SETTPV, CLRTPV
PRJOB: PUSHJ P,INLMES
ASCIZ /Job /
MOVE TAC,J
PUSHJ P,RADX10
PUSHJ P,PRSPC
PRCNFG: MOVEI TAC,CONFIG
JRST CONMES
HELLO: PUSHJ P,PRCNFG ;TELL HIM WHAT FLAVOR SYSTEM WE ARE!
JRST CRLF ;TYPE CRLF
ALOGIN: MOVEM TAC,PRJPRG(J)
SETZM JBTUFD(J)
SETZM DSKPPN(J) ;INTIALIZE DISK ALIAS PPN
SETZM JBTKCJ(J)
SETZM JBTMSC(J)
MOVSI TAC,JLOG
ANDCAM TAC,JBTSTS(J)
ALOGN1: PUSHJ P,TTYATI ;MAKE SURE TTY IS ATTACHED IN CASE THIS
JFCL ;COMMAND MUST BE DELAYED BECAUSE NO CORE YET.
POPJ P,
SETTPV: ANDCM TAC,JBTPRV(J) ;DON'T NEED ANY TEMPORARY PRIVS HE REALLY HAS
IORM TAC,JBTPRV(J) ;GIVE HIM THE TEMP PRIVS
IORM TAC,JBTTPV(J) ;REMEMBER TEMP PRIVILEGES WE ARE GIVING HIM
POPJ P,
CLRTPV: EXCH TAC,JBTTPV(J) ;SAVE TAC, PICK UP TEMP PRIVILEGES
ANDCAM TAC,JBTPRV(J) ;TURN OFF TEMP PRIVS
MOVEI TAC,0
EXCH TAC,JBTTPV(J) ;RESTORE TAC, NO TEMP PRIVILEGES NOW
POPJ P,
;CLOGIN LOGIN COMMAND
LOGDET: JSP TAC,ERRMES
ASCIZ /Please Kjob or Detach
/
;HERE FOR ONE FREE LOGIN WHEN REFLAG IS SET
LOGREF: MOVEM TAC,PRJPRG(J) ;PPN FROM REFLAG
MOVSI TAC,JLOG
IORM TAC,JBTSTS(J) ;LOG HIM IN.
MOVSI TAC,LUPPRV!PRIPRV ;SET JOB PRIVILEGES
MOVEM TAC,JBTPRV(J)
MOVEM TAC,JB2PRV(J)
SETZM -1(P) ;CLEAR ALL FLAGS FOR COMRET.
SETZM REFLAG ;ONLY ONCE.
POPJ P,
CLOGIN: TLNE AC1,JLOG ;IS HE LOGGED IN?
JRST LOGDET ;YES. FORCE LOGOUT FIRST
SKIPE TAC,REFLAG ;DEC 3.16
JRST LOGREF ;DEC 3.16
JRST .+2 ;(TAC HAS A ZERO)
CXLOGI: MOVEI TAC,1
HRRM TAC,SAVSAI(J) ;SET STARTING OFFSET.
MOVE TAC,DUMPPN ;SET PRJPRG TO DMPPPN
PUSHJ P,ALOGIN ;AUTOMATIC LOGIN
MOVSI TAC,JACCT ;FLAG ACCOUNTING PROGRAM RUNNING
IORM TAC,JBTSTS(J)
PUSHJ P,SKPBRK
MOVE TAC,[SIXBIT /LOGIN/] ;LOGIN FILE NAME.
MOVEM TAC,JOBNAM(J) ;STORE FILE NAME
IFN FTSTAT,<PUSHJ P,NAMSTT>
MOVSI TAC1,'DSK' ;READ FROM DSK, DMPPPN AREA.
JRST RUNCO2
;COMMANDS THAT RUN PROGRAMS (RPG,COPY,DART,HELP,WHO,WHERE,FIND,TEST,LISP). HLPRUN
HELP1: MOVE TAC,HELPPP
TLNE AC1,JLOG
POPJ P, ;RETURN IF LOGGED IN ALREADY.
PUSHJ P,ALOGIN
AOS (P) ;SKIP RET TO ALLOW LUP FOR WHO
JRST SETLOG ;AND SET-UP LOGIN STUFF
HLPRUN: PUSH P,UUO ;ANY CMD WHICH RUNS SAME-NAME PGM
HELPX: PUSHJ P,HELP1
JFCL
JRST ARCOM
WHOCOM: PUSH P,['WHO ']
PUSHJ P,HELP1
JRST ARCOM
MOVSI TAC1,LUPPRV ;GIVE 100,100 THE LOCAL USER PRIV
IORM TAC1,JBTPRV(J) ;BECAUSE HE CAN'T HARM US
JRST ARCOM
ERPGCM: ;HERE FOR EDIT-STYLE RPG-COMMANDS
RPGCOM: PUSH P,['SNAIL ']
JRST AXXCOM
ETCOM: PUSH P,['E ']
JRST ARCOM
DSCCOM: PUSH P,['DART ']
JRST ARCOM
CPYCOM: PUSH P,['COPY ']
JRST HELPX
ORACOM: PUSH P,['ORACLE']
JRST HELPX
MAICOM: PUSH P,['MAIL ']
PUSHJ P,HELP1
JFCL
JRST AXXCOM
DRDCOM: PUSH P,['DIRED ']
JRST ARCOM
SPLCOM: PUSH P,['SPOOL ']
JRST HELPX
TNCOM: PUSH P,['T ']
JRST ARCOM
UDPCOM: PUSH P,['UDPUFD']
MOVE TAC,JBTPRV(J) ;GET USER'S REAL PRIVS
TLNN TAC,LUPPRV ;IS HE LOCAL?
JRST NSCOM2 ;NOPE, FLUSH HIM
MOVSI TAC,INFPRV!DAWPRV!WRTPRV!PROPRV!UDPPRV ;BOY IS THIS A HAIRY PROGRAM
NSCOM3: PUSHJ P,SETTPV ;SET TEMPORARY PRIVILEGES
PUSH P,[SIXBIT / 1 2/]
JRST ARPCOM
NSCOM2: POP P,TAC
JRST COMERR ;PRETEND IGNORANCE
IFN FTNEWS,<
NSCOM: PUSH P,['NS ']
NSCOM1: MOVE TAC,JBTPRV(J) ;GET USER'S REAL PRIVS
TLNN TAC,LUPPRV ;IS HE LOCAL?
JRST NSCOM2 ;NOPE, FLUSH HIM
MOVSI TAC,REAPRV
JRST NSCOM3
HOTCOM: PUSH P,['HOT ']
JRST NSCOM1
>;IFN FTNEWS
IFE FTNEWS,<
HOTCOM: NSCOM:
JSP TAC,ERRMES
ASCIZ /The News Service is unavailable due to lack of computing resources
/
>;NO NEWS
;R, RUN, SAVE, SSAVE, GET COMMANDS. ARCOM, CMDRUN, AXXCOM, AXCOM, ARPCOM
;ARCOM: CALL WITH JOBNAM STACKED. RUN IT FROM SYS:
;AXCOM: SAME AS ARCOM, EXCEPT JOB STARTS AT C(JOBSA)+1
;CMDRUN: RUNS PROGRAM OF SAME NAME AS COMMAND
CMDRUN: PUSH P,UUO
ARCOM: TDZA TAC,TAC ;AUTOMATIC RUN COMMAND
AXCOM: MOVEI TAC,1 ;START WITH OFFSET=1
PUSHJ P,SKPBRK
ARCOM1: HRRM TAC,SAVSAI(J) ;SET STARTUP OFFSET
POP P,JOBNAM(J) ;STORE FILE NAME
IFN FTSTAT,< PUSHJ P,NAMSTT>
MOVSI TAC1,'SYS' ;READ FROM SYSTEM DEVICE
JRST RUNCO2
;START UP WITH DOUBLE-SKIP C(JOBSA)+2, TTY POINTS TO THE REST OF LINE
AXXCOM: MOVSI TAC,NOSKPB ;DOUBLE-SKIP ENTRY
IORM TAC,-2(P) ;TELL COMRET NOT TO CALL SKPBRK (JOBNAME STILL ON STACK)
MOVEI TAC,2 ;SET FOR DOUBLE-SKIP ENTRY
JRST ARCOM1
;ARPCOM: CALL WITH JOBNAM STACKED, AND PPN STACKED TOO!
ARPCOM: HLLZS SAVSAI(J) ;ZERO STARTING OFFSET
POP P,JOBPPN(J) ;SETUP SGSET KLUDGE
PUSHJ P,SKPBRK ;SKIP TO END OF LINE
POP P,JOBNAM(J)
IFN FTSTAT,< PUSHJ P,NAMSTT>
MOVSI TAC1,'DSK' ;READ FROM DSK
JRST RUNCO4
;"R CUSPNAME CORE" - DOES "RUN SYS:CUSPNAME"
RCOM: PUSH P,[0] ;ZERO OUT PROGRAM NAME
MOVEI TAC,0
JRST ARCOM1
;"RUN DEVICE:FILE[PROJECT,PROGRAMMER] (CORE)"
;DOES A CORE,GET,START ALL IN ONE
;IF CORE ARG IS MISSING, SIZE IN DIRECTORY IS USED
RUNCOM: PUSHJ P,CTEXT1 ;GET DEVICE NAME FROM COMMAND STRING
SETZM JOBNAM(J) ;CLEAR OUT OLD JOB NAME
IFN FTSTAT,< PUSHJ P,NAMSTT>
HLLZS SAVSAI(J) ;CLEAR STARTUP INCREMENT
RUNCO2: SETZM JOBPPN(J) ;DISABLE JOBPPN KLUGE FOR SGSET
RUNCO4: MOVEI IOS,RUNJOB
RUNCM: PUSH P,IOS ;SAVE DISPATCH
SKIPE JBTPAG(J) ;SKIP IF THERE'S NO CORE FOR THIS JOB
JRST RUNCO1
PUSH P,TAC1 ;SAVE DEVICE NAME
MOVEI TAC,ASSPRG ;CLEAR TTY "ASSIGNED BY PROGRAM" BIT
ANDCAM TAC,DEVMOD(DDB)
MOVEI TAC,JOBDA ;REQUEST JUST ENOUGH CORE FOR A JOB DATA AREA
PUSHJ P,CORE0 ;IF OLD CORE (DEVICE ASSIGNMENTS RETAINED
JFCL ;CAN'T BECAUSE EITHER NO ROOM OR ACTIVE IO
POP P,TAC1 ;RESTORE DEVICE NAME
RUNCO1: POP P,IOS ;ADR. OF MONITOR JOB
SKIPN JBTPAG(J) ;SKIP IF WE HAVE CORE IN CORE
JRST DLYCOR ;DELAY IF CORE ASSIGNED IS ON THE DISK
PUSHJ P,APRMAP ;SETUP APR MAP SO XCTR WILL WORK.
XCTR XW,[MOVEM UUO,COMWRD] ;PUT COMMAND IN AC FOR PROGRAM TO SEE
XCTR XW,[MOVEM TEM,CHRWRD] ;ALSO DELIMITER CHAR
SKIPN AC2,JOBPPN(J) ;SPECIAL PPN HACK?
JRST SGSET ;NO
JRST SGSET0 ;YES. SPECIAL ENTRY
;"GET DEVICE:FILE-NAME[PROJ.,PROG.] CORE" - SETS UP JOB AREA FROM RETREIVABLE
;DEVICE AND ASSIGNS CORE.
GET: MOVEI IOS,GETJOB ;SETUP TO RUN GETJOB
PUSHJ P,CTEXT1 ;GET DEVICE NAME
SETZM JOBNAM(J) ;CLEAR JOB NAME
SETZM JOBPPN(J) ;DISABLE JOBPPN KLUGE FOR SGSET
IFN FTSTAT,< PUSHJ P,NAMSTT>
JRST RUNCM
;"SAVE FILE-NAME[PROJ.,PROG.] CORE" - SAVES JOB AREA ON RETRIEVABLE DEVICE
;ONLY A SAVE OR A GET IN PROGRESS FOR EACH JOB
;NO ATTEMPT IS MADE TO SAVE DEVICE ASSIGNMENTS, AC'S, OR PC
SSAVE: TROA IOS,SSAVJB ;SAVE UPPER ALSO (IOS CLEARED BEFORE DISPATCH)
SAVE: MOVEI IOS,SAVJOB ;SETUP TO RUN SAVJOB
PUSHJ P,CTEXT1 ;GET THE FIRST COMMAND ARGUMENT (DEV OR FILENAME)
SETZM JOBNAM(J) ;CLEAR JOB NAME.
IFN FTSTAT,< PUSHJ P,NAMSTT>
JRST SGSET ;SCAN THE REST OF THE ARGUMENTS
; "ASSIGN DEV:NAME" - ASSIGN DEVICE TO JOB AND GIVE IT LOGICAL NAME
ASSIGN: MOVEI AC1,0 ;START WITH NO ATTRIBUTES
ASSPP9: PUSHJ P,CTEXT1 ;GET FIRST ARGUMENT
JUMPE TAC1,NOTENF ;NO ARGUMENT TYPED IF 0
MOVEI AC2,0
MOVSI TAC,770000
ASSPP1: TDNN TAC,TAC1
JRST ASSPP2
IORM TAC,AC2 ;MAKE MASK FOR NUMBER OF CHARACTERS TYPED
LSH TAC,-6
JUMPN TAC,ASSPP1
ASSPP2: MOVSI TAC,-NASATT
ASSPP3: CAMN TAC1,ASATTT(TAC)
JRST ASSPP0 ;EXACT MATCH. GET BITS AND LOOP
MOVE AC3,ASATTT(TAC) ;GET NAME OF ATTRIBUTE
AND AC3,AC2 ;AND WITH MASK
CAMN TAC1,AC3
TLON AC1,400000(TAC)
AOBJN TAC,ASSPP3
JUMPL TAC,ASSPPX ;AOBJN DIDN'T FALL THROUGH (TOO MANY MATCHES)
JUMPGE AC1,ASSPPX ;IF SIGN BIT OFF THERE WERE NO MATCHES
LDB TAC,[POINT 17,AC1,17] ;GET INDEX OF MATCHING ENTRY
ASSPP0: TDNE AC1,ASATBB(TAC) ;CHECK FOR EXCLUDED BITS
JRST COMERR ;NAUGHTY NAUGHTY
IOR AC1,ASATTB(TAC) ;OK, TURN ON NEW BIT
MOVEI AC1,(AC1) ;FLUSH CRUFT IN LH
JRST ASSPP9
PUBBIT←←1
PRIBIT←←2
OLDBIT←←4
ASATTT: 'PUBLIC'
'PRIVAT'
'OLD '
NASATT←←.-ASATTT
ASATTB: PUBBIT
PRIBIT
OLDBIT
IFN .-ASATTB-NASATT,<PRINTS /SOMEONE CAN'T COUNT AT ASATTB
/>
ASATBB: PRIBIT!OLDBIT ;TABLE OF BITS NOT ALLOWED WITH NEW ONE
PUBBIT!OLDBIT
PUBBIT!PRIBIT
IFN .-ASATBB-NASATT,<PRINTS /ASATBB WRONG SIZE
/>
ASSPPX: MOVE AC2,TAC1 ;SAVE DEVICE NAME
PUSHJ P,CTEXT1 ;GET LOGICAL NAME, IF ANY
MOVEM TAC1,ASSLGN ;SAVE FOR LATER
MOVE TAC1,AC2 ;RESTORE TAC1 TO PHYS NAME
HRRZS (P) ;CLEAR PARTIAL MATCH FOUND FLAG
PUSH P,DDB ;SAVE TTY DDB ADDRESS
MOVE TAC,TAC1
PUSH P,AC1 ;SAVE ATTRIBUTE BITS
PUSHJ P,DEVPHY
JRST ASSG3
POP P,AC1
MOVEI TAC1,ASSCON
JRST ASSG4
ASSG3: POP P,AC1
MOVEI TAC1,ASSCON ;SETUP ASSIGNED BY CONSOLE BIT
HLRZ DDB,DEVLST
ASSG0: MOVE TAC,DEVNAM(DDB)
CAME AC2,DEVNAM(DDB) ;DOES PHYSICAL NAME MATCH?
JRST ASSG1 ;NO
ASSG4: CAMN AC2,[SIXBIT /DSK/] ;IS THIS A DISK?
JRST ASSG5 ;YES. BYPASS CHECK FOR SYSTEM TAPE
CAMN TAC,SYSTAP ;IS NEXT DEVICE IN LIST THE SYSTEM TAPE?
JRST ASSFIN ;YES, DO NOT ASSIGN. CLEAR DIRECTORY IN CORE BIT
ASSG5: PUSHJ P,ASSUDP ;TEST VARIOUS UDP CASES
JRST ASSR1A ;CAN'T GET UDPN SINCE PRIVATE AND NOT OURS
PUSHJ P,ASSCKS ;NOW CHECK FOR RECYCLABLE DDB
JRST ASLNOK ;I.E., SHARABLE DEVICE AND OUR ASSCON DDB
PUSHJ P,ASSASG ;TRY TO ASSIGN DEVICE
JRST ASSER1 ;ALREADY ASSIGNED TO ANOTHER JOB
JRST ASSFIN ;ASSIGNED
ASSUDP: HLRZ AC3,TAC
CAIE AC3,'UDP'
JRST CPOPJ1 ;NOT UDP.
LDB AC3,PUNIT
CAME AC2,[SIXBIT /UDP/]
JRST ASSUD1 ;ASKED FOR UDPN. SEE IF PUBLIC OR OURS
SKIPGE UDPOWN-1(AC3) ;NEED THIS IN CASE SWAPPING PACK--BH 5/25/75
SKIPE UDPCNT-1(AC3) ;ANY DDBS IN USE FOR THIS UDP?
POPJ P, ;YES.
ASSUD2: TRNE AC1,PUBBIT ;WANTS TO MAKE IT PUBLIC?
JRST AUDPPB ;YES.
TRNE AC1,OLDBIT ;WANTS TO MAKE IT OLD STYLE?
JRST AUDPOL ;YES.
TRNN AC1,PRIBIT ;MAKE IT PRIVATE?
JRST CPOPJ1 ;NO.
PUSHJ P,AUDPNU ;YES, FIRST MAKE IT NEW STYLE
PUSHJ P,AUDPPV ;THEN MAKE IT PRIVATE
JFCL ;IGNORE FAILURE RETURN
JRST CPOPJ1
AUDPPV: SKIPN UDPCNT-1(AC3)
JRST ASSUD3 ;OK TO PRIVATIFY UNUSED UDP
PUSH P,DDB
ASSUD4: HLRZ DDB,DEVSER(DDB)
JUMPE DDB,ASSUD5
CAME AC2,DEVNAM(DDB)
JRST ASSUD5 ;NO MORE DDBS FOR THIS UDP
LDB TAC,PJOBN
CAIN TAC,(J)
JRST ASSUD4 ;SAME JOB SAME UDP IS OK
MOVE DDB,-3(P) ;TTY DDB
PUSHJ P,INLMES
ASCIZ /Already in use - can't make private
/
POP P,DDB
MOVE TAC,DEVNAM(DDB)
POPJ P, ;FAILURE RETURN
ASSUD5: POP P,DDB
ASSUD3: MOVE TAC,DEVNAM(DDB)
MOVEM J,UDPOWN-1(AC3) ;MAKE UDP PRIVATE
JRST CPOPJ1 ;SUCCESS RETURN
ASSUD1: SKIPL UDPOWN-1(AC3) ;WANTS UDPN
CAMN J,UDPOWN-1(AC3)
JRST ASSUD2 ;OK SINCE PUBLIC OR OURS
POPJ P, ;CAN'T GET UDPN SINCE PRIVATE NOT OURS
AUDPPB: PUSHJ P,AUDPNU ;WANTS PUBLIC: FIRST MAKE NEW-STYLE
LDB AC3,PUNIT
MOVE TAC,DEVMOD(DDB) ;DDB POINTS TO MODEL DDB IT SAYS HERE
TLNE TAC,DVDSK ;IF WE MANAGED NEW-STYLE,
SETOM UDPOWN-1(AC3) ;PUBLICIFY IT
JRST CPOPJ1
AUDPNU: LDB AC3,PUNIT ;TRY TO MAKE IT NEW-STYLE UDP
MOVE TAC,DEVMOD(DDB)
TLON TAC,DVDSK ;OK IF ALREADY NEW-STYLE
SKIPN UDPCNT-1(AC3) ;OR IF NO DDBS YET
JRST AUDNOK
AUDFOO: EXCH DDB,-2(P) ;TTY DDB
PUSHJ P,INLMES
ASCIZ /Already in use - can't change format
/
EXCH DDB,-2(P)
MOVE TAC,DEVNAM(DDB)
POPJ P,
AUDNOK: MOVEM TAC,DEVMOD(DDB) ;SET FORMAT BIT
MOVEI TAC,DSKDSP
HRRM TAC,DEVSER(DDB) ;SIGH, SET THE NEW DISPATCH TABLE TOO
MOVE TAC,DEVNAM(DDB)
POPJ P,
AUDPOL: PUSHJ P,AUDPPV ;WANTS OLD-STYLE. FIRST PRIVATIFY
JRST CPOPJ1 ;FAILED TO PRIVATIFY, SO NO OLD-STYLE
AOS (P) ;WIN OR LOSE, WE'VE ESTABLISHED ACCESS
LDB AC3,PUNIT ;TRY TO MAKE IT OLD-STYLE UDP
MOVE TAC,DEVMOD(DDB)
TLZE TAC,DVDSK ;OK IF ALREADY OLD-STYLE
SKIPN UDPCNT-1(AC3) ;OR IF NO DDBS YET
JRST AUDOOK
JRST AUDFOO ;GIVE THE LOSE MESSAGE
AUDOOK: MOVEM TAC,DEVMOD(DDB) ;SET FORMAT BIT
MOVEI TAC,UDPDSP
HRRM TAC,DEVSER(DDB) ;SIGH, SET THE OLD DISPATCH TABLE TOO
MOVE TAC,DEVNAM(DDB)
POPJ P,
;ROUTINE TO TRY TO RECYCLE ASSCON-TYPE DDB FOR SHAREABLE DEVICE
ASSCKS: MOVE AC3,DEVCMR(DDB) ;FIRST OF ALL, GOTTA BE SHARABLE DEV
TLNN AC3,DEVSHR ;OR ASSASG WON'T COPY IT ANYWAY
JRST CPOPJ1
MOVE AC3,DDB ;NOW SEARCH ALL DDBS FOR THIS DEV
ASCKS1: LDB TAC,[POINT 6,DEVCHR(AC3),5] ;PJOBN
CAIE TAC,(J) ;MUST MATCH OUR JOB TO BE A CANDIDATE
JRST ASCKS9 ;ELSE CONTINUE THROUGH DDBS
MOVE TAC,DEVMOD(AC3) ;MUST HAVE ASSCON
TRNN TAC,ASSCON ;PERHAPS NEEDLESSLY CONSERVATIVE, BUT
JRST ASCKS9 ;PERHAPS SOMEONE NEEDS NOT CON+PRG SAME DDB
SKIPE TAC,DEVLOG(AC3) ;OK IF NO LOGICAL NAME IN THE DDB
CAMN TAC,ASSLGN ;OR IF IT'S THE SAME AS LOG NAME ARG NOW
JRST ASCKS2
SKIPE ASSLGN ;ALSO OK IF NO LOG NAME ARG IN COMMAND
JRST ASCKS9 ;BUT LOSE IF 2 DIFFERENT LOG NAMES
ASCKS2: MOVE DDB,AC3 ;GOT ONE! SAVE POINTER
POPJ P,
ASCKS9: HLRZ AC3,DEVSER(AC3) ;CONTINUE THROUGH DDB CHAIN
JUMPE AC3,CPOPJ1 ;CAN'T HAPPEN MAYBE
MOVE TAC,DEVNAM(AC3) ;MAKE SURE THIS IS SAME DEVICE
CAMN TAC,DEVNAM(DDB)
JRST ASCKS1 ;OK, CONTINUE TESTING
JRST CPOPJ1 ;NO, POP AC3, SKIP RET
;SYSTEM TAPE OR NOT MATCH OF ARG AND PHYSICAL NAME.
ASSG1: CAMN TAC,SYSTAP ;IS THIS SYSTEM TAPE?
JRST ASSG2 ;YES
LDB AC3,PJOBN ;SAVE OLD JOB NUMBER FOR THIS DEVICE
MOVEM AC3,ASSJBN
TRZ TAC,-1 ;COMPARE LEFT HALF ONLY
CAME TAC,AC2
JRST ASSG2
HRROS -1(P) ;FLAG PARTIAL NAME MATCH FOUND
PUSHJ P,ASSUDP ;DO UDP CHECKS
JRST ASSG2 ;THIS UDP NOT FREE TRY NEXT
PUSHJ P,ASSCKS ;NOW CHECK FOR RECYCLABLE DDB
JRST ASLNOK ;NONSKIP RETURN MEANS SUCCESS, GOT A DDB
PUSHJ P,ASSASG ;MATCH, TRY TO ASSIGN IT
JRST ASSG2 ;KEEP LOOKING
SKIPN ASSJBN
JRST ASSFIN ;IF OLD JOB NUMBER 0,
; DEVICE PREVIOUSLY UNASSIGNED
ASSG2: HLRZ DDB,DEVSER(DDB)
JUMPN DDB,ASSG0
POP P,DDB
SKIPL (P) ;DID WE HAVE ANY PARTIAL MATCHES?
JRST NOTDEV ;PRINT NO SUCH DEVICE
MOVE DDB,-2(P) ;RESTORE TTY DDB
PUSHJ P,INLMES
ASCIZ /No /
MOVE TAC1,AC2
PUSHJ P,PRNAME
JSP TAC,CONMES
ASCIZ /'s available
/
;ALREADY ASSIGNED TO ANOTHER JOB
ASSR1A: LDB TAC,PUNIT
SKIPA TAC,UDPOWN-1(TAC) ;GET JOB NUMBER OF PRIVATE OWNER OF UDPN
ASSER1: LDB TAC,PJOBN ;GET JOB NUMBER FOR DEVICE
POP P,DDB ;GET DDB FOR TTY
PUSH P,TAC ;SAVE JOB NUMBER
MOVEI TAC,ASSMS2 ;TYPE ERROR MESSAGE
PUSHJ P,ERRMES
POP P,TAC ;GET JOB NUMBER BACK
JRST DECLF
ASSMS2: ASCIZ /Already assigned to job /
;DEVICE ASSIGNED, GIVE IT A LOGICAL NAME
ASSFIN: SETZM DEVLOG(DDB) ;CLEAR LOGICAL NAME
ASLNOK: EXCH DDB,(P) ;GET TTY DDB, SAVE DEVICE DDB
MOVE TAC1,ASSLGN ;RETRIEVE SAVED LOGICAL NAME ARG
SKIPN TAC,TAC1 ;IS THERE A LOGICAL NAME SPECIFIED?
JRST DEFASS ;NO. CHECK FOR DEFAULTING ASSIGNMENT
PUSHJ P,DEVLG ;SEE IF IT IS ALREADY IN USE BY THIS USER
JRST ASSF1 ;NO
MOVEI TAC,LOGERR ;YES, PRINT ERROR
MOVE DDB,-3(P) ;RESTORE TTY DDB
PUSHJ P,ERRMES
DEFLOS: MOVEI TAC,0 ;CLEAR LOGICAL NAME FOR THIS DEVICE
ASSF1: POP P,DDB
SKIPN DEVLOG(DDB) ;WILL BE NONZERO ONLY FOR RECYCLED DDB
MOVEM TAC,DEVLOG(DDB) ;STORE IN DEVICE DATA BLOCK
MOVSI TAC1,DVDIRIN ;CLEAR DIRECTORY IN CORE BIT
ANDCAM TAC1,DEVMOD(DDB)
MOVE TAC1,DEVNAM(DDB) ;PHYSICAL NAME
MOVE AC2,DDB
MOVE DDB,-2(P) ;RESTORE TTY DDB
PUSHJ P,PRNAME ;PRINT IT
PUSHJ P,INLMES
ASCIZ / Assigned/
SKIPN DEVLOG(AC2)
JRST NOLOGP
PUSHJ P,INLMES
ASCIZ / as /
MOVE TAC1,DEVLOG(AC2)
PUSHJ P,PRNAME
NOLOGP: JSP TAC,CONMES
ASCIZ/
/
LOGERR: ASCIZ /Logical name already in use, /
DEFASS: MOVE DDB,(P)
CAME AC2,DEVNAM(DDB)
CAMN AC2,['TTY '] ;DON'T DO IT FOR TTY
JRST ASSF1
MOVE TAC,AC2
PUSHJ P,DEVLG ;INUSE?
JRST ASSF1
JRST DEFLOS
;"DEASSIGN DEV" - DEASSIGNS DEVICE FROM CONSOLE
DEASSI: JUMPE J,CPOPJ ;NO-OP IF NO JOB NUMBER
PUSHJ P,CTEXT1 ;GET DEVICE NAME
JUMPE TAC1,DEALL ;NO ARG. IF 0, DEASSIGN ALL BUT TTY
MOVE TAC,TAC1 ;DEVICE NAME
DEAER4: PUSHJ P,DEVLG ;SEARCH LOGICAL NAMES FIRST
JRST DEAER3
PUSHJ P,DEASG
CAIA
JRST DEADON
PUSH P,[DEAER4+1]
JRST DEV0
DEAER3: PUSHJ P,DEVPHY ;NOT FOUND, TRY PHYSICAL NAMES
JRST DEAER2 ;NOT FOUND AT ALL, LOSE!
PUSHJ P,DEASG ;FOUND, DEASSIGN IT
CAIA
JRST DEADON
MOVE AC1,DEVMOD(DDB)
TLNE AC1,DVTTY ;STOP IF FOUND A TTY
POPJ P, ;QUIT HERE ELSE LOOP INDEFINITELY. FLUSH UNUSED TTYS
PUSH P,[DEAER3+1]
JRST DEVLP2
DEADON: MOVE AC1,DEVMOD(DDB)
TLNE AC1,TTYATC ;NOT FOR CONSOLE OF LOSER
POPJ P,
TRNN AC1,ASSPRG ;STILL ASSIGNED BY PROGRAM?
JRST DEADN1 ;NO.
MOVE TAC1,DEVNAM(DDB)
MOVE DDB,-2(P)
PUSHJ P,PRNAME
JSP TAC,ERRMES
ASCIZ / deassigned, but still INITed
/
DEADN1: TLNN AC1,DVTTY ;IF TTY
POPJ P,
JRST TTYREL ;RELEASE IT SO DDB WILL BE LET GO
↑NOTDEV:
DEAER1: MOVE DDB,-2(P) ;RESTORE TTY DDB
JSP TAC,ERRMES ;PRINT 'NO SUCH DEVICE'
ASCIZ /No such device
/
DEAER2: MOVE TAC1,TAC ;PRINT PHYSICAL DEVICE NAME
MOVE DDB,-2(P) ;RESTORE TTY DDB FIRST
PUSHJ P,PRNAME
JSP TAC,ERRMES
ASCIZ / wasn't assigned
/
DEALL: PUSH P,DDB
MOVEI DDB,0
PUSHJ P,DEASTY
POP P,DDB
POPJ P,
;REASSI, REASS, REASSIGN UUO AND COMMAND.
;CALL MOVE AC,<NEW JOB NUMBER>
; MOVE AC+1,<SIXBIT /DEVICE/> OR <IO CHANNEL NUMBER>
; CALL AC,[SIXBIT /REASSIGN/]
;IF C(AC)=0, JOB HAS NOT BEEN INITIALIZED
;IF C(AC+1)=0, DEVICE NOT ASSIGNED TO THIS JOB OR DEVICE IS A TTY
;HERE FROM UUOCON.
REASSI: LDB UUO,PUUOAC
HRLI UUO,100000 ;UUO POSTIVE SIGNIFIES REASSIGN UUO
XCTR XR,[PUSH P,(UUO)] ;STACK JOB NUMBER ARGUMENT.
XCTR XR,[MOVE TAC1,1(UUO)] ;FETCH DEVICE NAME.
JRST REASS1 ;JUMP TO COMMON CODE.
;"REASSIGN DEV:JOB" - REASSIGN DEVICE "DEV" TO JOB "JOB"
REASS: PUSHJ P,CTEXT1 ;GET DEVICE NAME
JUMPE TAC1,NOTENF ;NULL NAME?
MOVE UUO,TAC1 ;SAVE DEVICE NAME.
PUSHJ P,DECIN1 ;GET NEW JOB NUMBER
JRST NOTENF ;NONE SPECIFIED. DOESN'T RETURN IF ERROR
JRST COMERA ;ILLEGAL CHARACTER
SKIPE JBTPAG(J) ;DOES THIS JOB HAVE ANY CORE?
PUSHJ P,APRMAP ;YES. SETUP THE MAP.
PUSH P,TAC1 ;PUT JOB NUMBER ON STACK
MOVE TAC1,UUO ;DEVICE NAME IN TAC1
MOVEI UUO,0 ;UUO←0 SIGNIFIES REASSIGN COMMAND
REASS1: EXCH J,(P) ;J←NEW JOB NUMBER. (STACK CURRENT J)
MOVE TAC,JBTSTS(J) ;NEW JOB STATUS
EXCH J,(P) ;RESTORE J AND STACK
TLNN TAC,JNA ;DOES NEW JOB EXIST?
JRST REASE1 ;NO.
MOVE TAC,TAC1 ;DEVICE NAME.
PUSHJ P,FNDDDB ;SEARCH FOR DEV (OR OPTIONAL CHANNEL # IF UUO)
JRST REASE2 ;NOT FOUND
LDB TAC,PJOBN ;GET JOB NUMBER OF THAT DEVICE
CAME TAC,J ;IS IT ASSIGNED TO THIS JOB?
JRST REASE3 ;NO
MOVE TAC,DEVMOD(DDB)
TLNE TAC,TTYATC ;IS IT HIS CONSOLE?
JRST REASE6 ;CAN'T REASSIGN CONSOLE.
TRNN TAC,ASSPRG ;IS DEVICE INITED?
JRST REASS3 ;NO.
JUMPN UUO,REASS4 ;DEVICE IS INITED. JUMP IF THIS IS AT UUO LEVEL
HRL DDB,(P) ;COMMAND LEVEL. RUN MONITOR JOB TO DO RELEASE
XCTR XW,[MOVEM DDB,JOBFDV] ;STORE ARGUMENT.
POP P,TAC1 ;JOB NUMBER OF DESTINATION.
MOVE DDB,-2(P) ;TTY DDB
MOVSI TAC1,TTYRNC ;SET TTYRNC SO JOB WILL RUN
IORM TAC1,-1(P)
JSP TAC1,MSTART ;SCHEDULE MONITOR JOB.
JSP TAC,MONSTR ;HERE WE ARE AT UUO LEVEL. SETUP ACS.
XCTR XR,[HLRZ TAC,JOBFDV] ;GET THE JOB NUMBER BACK
PUSH P,TAC ;STACK THE JOB NUMBER.
XCTR XR,[HRRZ DDB,JOBFDV] ;AND SETUP THE DDB ADDRESS.
MOVNI UUO,1 ;SET FLAG TO STOP JOB EXITING COMMAND.
REASS4: HRRZ DSER,DEVSER(DDB)
XCTR XW,[HRRZM DDB,JOBFDV] ;SAVE DDB ADDRESS.
SKIPGE UCHN,USRHCU(PID) ;HAS SAVGET BEEN HERE?
JRST REASS3 ;YES, WE CAN'T BE IN USRJDA LIST.
CAILE UCHN,17
MOVEI UCHN,17
REASS2: HRRZ DDB,USRJDA(UCHN)
PUSH P,UCHN
XCTR XR,[CAME DDB,JOBFDV]
JRST REASS8 ;FAILS TO MATCH.
HLL DDB,USRJDA(UCHN) ;PICK UP UUO FLAGS FIRST
PUSHJ P,RELEA5 ;GO RELEASE DEVICE.
REASS8: POP P,UCHN
SOJGE UCHN,REASS2 ;MAY BE INITED ON SEVERAL CHANNELS.
SKIPL UCHN,JBTIOP(J) ;LOOK IN THE IOPDL
JRST REAST1
REAST2: HRRZ DDB,(UCHN)
XCTR XR,[CAME DDB,JOBFDV]
JRST REAST3
MOVE DDB,USRJDA
EXCH DDB,(UCHN)
MOVEM DDB,USRJDA
PUSH P,UCHN
MOVEI UCHN,0
PUSHJ P,RELEA5 ;RELEASE DEVICE FROM IOPDL
POP P,UCHN
MOVE DDB,(UCHN)
EXCH DDB,USRJDA
MOVEM DDB,(UCHN)
REAST3: ADD UCHN,[2,,2]
JUMPL UCHN,REAST2
REAST1: XCTR XR,[MOVE DDB,JOBFDV]
REASS3: MOVEI TAC,ASSCON ;ASSIGN IT BY CONSOLE
IORM TAC,DEVMOD(DDB)
POP P,J
DPB J,PJOBN ;PUT IN NEW JOB NUMBER
SETZM DEVLOG(DDB) ;FLUSH LOGICAL DEVICE NAME
PUSHJ P,RELDVW ;REG 11/74. JOB MAY BE WAITING IN DWQ
MOVE J,JOB(PID) ;RESTORE CURRENT JOB NUMBER
JUMPL UUO,ESTOP ;IF REASSI COMMAND AT UUO LEVEL, WE STOP.
POPJ P, ;RETURN TO USER, OR COMRET
;ERRORS FROM REASSIGN
REASE1: POP P,TAC ;NO SUCH JOB. ADJUST STACK.
JUMPE UUO,NOTLOG ;JUMP IF REASSIGN COMMAND - PRINT MESSAGE
REASE4: XCTR XW,[SETZM (UUO)] ;CLEAR C(AC) - NO SUCH JOB RETURN
POPJ P,
REASE3: SKIPA TAC,[REASSX] ;WASN'T ASSIGNED
REASE2: MOVEI TAC,NOTDEV ;NO SUCH DEVICE
REASE5: POP P,TAC1
JUMPE UUO,(TAC) ;PRINT MESSAGE.
AOJA UUO,REASE4 ;ZERO C(AC+1) - CAN'T REASSIGN DEVICE
REASE6: MOVEI TAC,REASE7 ;USER'S TERMINAL CAN'T BE REASSIGNED.
JRST REASE5
REASE7: MOVE TAC1,DEVNAM(DDB)
MOVE DDB,-2(P) ;RESTORE TTY DDB
PUSHJ P,PRNAME
JSP TAC,ERRMES
ASCIZ / can't be reassigned
/
REASSX: MOVE TAC,DEVNAM(DDB)
JRST DEAER2 ;PRINT DEVICE XXX WAS NOT ASSIGNED.
;ATTACH COMMANDS
;"ATTACH DEVNAM" -ATTACHES A PREVIOUSLY DETACHED DEVICE. MUST HAVE DEVPRV
;"ATTACH N [PROJ.,PROG.]" - ATTACH CONSOLE TO JOB N
;CHANGES ADDRESS OF TTY DDB THAT WAS STORED IN -2(P) BY THE COMMAND DECODER
ATTACH: PUSHJ P,DECIN ;GET JOB NO.
JRST NOTENF ;NOT A NUMBER OR NONE SPECIFIEED
JRST DEVATT ;WANTS TO ATTACH A DEVICE
JUMPE TAC1,NOTLOG ;0 IS ILLEGAL
CAIL TAC1,JOBN ;IS JOB NUMBER TOO BIG?
JRST NOTLOG ;ILLEGAL JOB NUMBER. PRINT NO SUCH JOB
MOVSI AC2,JNA ;HAS THIS JOB NO BEEN ASSIGNED?
TDNN AC2,JBTSTS(TAC1)
JRST NOTLOG ;NO, PRINT NO SUCH JOB
PUSH P,TAC1 ;SAVE JOB NO.
PUSHJ P,PJPGNO ;GET PROJ.-PROG. NOS. ARG
MOVE AC2,PRJPRG(J) ;NO PP NO. USE CURRENT ONE
POP P,TAC1 ;RESTORE
CAME AC2,PRJPRG(TAC1);MATCHES THE DETACHED JOB'S PPN?
JRST ATT3 ;NO - ERROR
LDB TAC,PUNIT ;THIS TTY'S LINE NUMBER
HLL TAC,LINTAB(TAC) ;HIS LINE CHARACTERISTICS
TLNE TAC,DISLIN!DDDLIN!CTYLIN ;IF IT'S A LOCAL DISPLAY,
JRST ATTLCL ;OK TO ATTACH
JUMPE J,ATTFOO ;ELSE MUST BE LOGGED IN
MOVE TAC,JBTPRV(J) ;AND EITHER LOCAL OR SAME PPN
TLNN TAC,LUPPRV
CAMN AC2,PRJPRG(J)
JRST ATTLCL ;OK
ATTFOO: MOVEI J,0
JSP TAC,ERRMES ;NOPE, FLUSH HIM
ASCIZ /Can't Attach job
/
ATTLCL: MOVE TAC,JBTPRV(J)
MOVSI AC2,JLOG
TDNN AC2,JBTSTS(TAC1) ;SKIP IF JOB WE'RE ATTACHING IS LOGGED IN
TRNE TAC,ATTPRV ;NOT LOGGED IN. SKIP IF WE'RE UNPRIVILEGED
JRST .+2 ;JOB IS LOGGED IN OR WE'RE PRIVILEGED
JRST ATTFOO
LDB TAC,PUNIT ;GET LINE NUMBER OF TTY THAT'S TYPING.
JRST .+2
ATTILA: HRRE TAC,JBTLIN(J) ;GET LINE NUMBER OF CONTROLING JOB.
CAIGE TAC,PTYL0 ;IS THIS ON A PTY?
JRST THEHUN ;NO. ATTACH IS LEGAL.
MOVE J,PTYJOB-PTYL0(TAC) ;GET JOB NUMBER OF CONTROLING JOB.
CAIE J,(TAC1) ;CONTROLLER=JOB TO ATTACH TO?
JRST ATTILA ;NO. KEEP LOOPING
MOVEI J,0
JSP TAC,ERRMES
ASCIZ /Illegal attach loop
/
THEHUN: MOVSI TAC,JLOG ;MAKE SURE THE JOB THAT'S BEING
IORM TAC,JBTSTS(TAC1); ATTACHED IS LOGGED IN
MOVE J,TAC1 ;JOB NUMBER TO J
PUSHJ P,COMRT2 ;FIX COMCNT
PUSHJ P,TTYATT ;NO, ATTACH TTY
JRST ATT2 ;ERROR CAN'T ATTACH
MOVEM DDB,-2(P) ;CHANGE DEV DATA BLOCK ADDRESS
JRST TTYFND ;ATTACHED. GO SET UP OUTPUT BYTE PTR.
;ATTACH DEVICE DEVATT
DEVATT: ADDI TEM,20 ; MAKE FIRST CHAR OF DEVICE NAME INTO SIXBIT
PUSH P,TEM ; NOW SAVE IT
PUSHJ P,CTEXT ;GET DEVICE ARGUMENT
JFCL ;SHOULD NEVER RETURN
POP P,TEM ; GET CHARACTER BACK
MOVE AC1,JBTPRV(J) ;GET JOB PRIVILEGES.
TLNN AC1,DEVPRV ;HAS HE THIS PRIV?
JRST ATT5 ;NO - ERROR
MOVE TAC,TAC1 ;YES-SET UP DEVICE NAME
LSH TAC,-6
DPB TEM,[POINT 6,TAC,5]
PUSH P,DDB ;SAVE DDB FOR THIS TTY
PUSHJ P,DEVSRC ;SEARCH FOR DEVICE
JRST DADD01 ;NOT FOUND
LDB AC1,PJOBN ;GET JOB NUMBER
JUMPN AC1,ATT6 ;IS IT = 0?
MOVE TAC,DEVMOD(DDB) ;CHECK TO SEE IF THIS IS A TTY
TRNE TAC,ASSPRG ;IN USE BY JOB 0?
JRST ATT5A ;YES, CAN'T ATTACH IT
TLNE TAC,DVUDP
JRST ATTUDP ;UDP IS SPECIAL
DPB J,PJOBN ;SET JOB NUMBER
LDB TAC1,PUNIT ;
TLNE TAC,DVTTY ;IS IT A TTY?
HRRM DDB,TTYTAB(TAC1);DEC 3.16
DADD02: POP P,DDB ;
POPJ P, ;RETURN
ATTUDP: LDB TAC,PUNIT ;TRYING TO ATTACH UDP
SKIPN UDPCNT-1(TAC) ;MUST BE NO DDBS
SKIPE UDPOWN-1(TAC) ;AND OWNER 0
JRST ATT6 ;ELSE IN USE, PUBLIC, OR SWAPPING DEVICE!
SETOM UDPOWN-1(TAC) ;OK, MAKE IT PUBLIC
JRST DADD02 ;NOTE THAT YOU DON'T HAVE IT ASSIGNED NOW!
;NOTE: THIS ROUTINE IS ALSO CALLED FROM PJOB COMMAND
DADD00: MOVEI TAC1,0 ;SUBROUTINE TO CHECK "DEV" NAME FOR DD
ROTC TAC,14
CAIN TAC1,'DD' ;NOT A DEVICE, IS IT A DD CHANNEL?
PUSHJ P,SIX2LN ;YES, GOBBLE NUMBER
POPJ P, ;NOT DD OR NO NUMBER
CAIL TAC1,=32
POPJ P,
; MOVSI TAC,DDDETU!DDANYW ;DETACHED USE CODE
; HRRI TAC,(TAC1)
JRST CPOPJ1
DADD01: PUSHJ P,DADD00 ;NOT A REAL DEVICE, TRY DD CHAN
JRST TEMP1 ;NOPE
MOVEI TAC,DDBADB ;YES, GET BAD BIT MASK
TDNN TAC,DDTAB(TAC1)
JRST ATT6 ;WASN'T DET
ANDCAM TAC,DDTAB(TAC1) ;CLEAR THE BIT
JRST DADD02
ATT2: EXCH DDB,TAC1 ;PUT LINE NO. OF OUR TTY IN DDB
MOVE TAC1,DEVNAM(TAC1) ;PRINT PHYSICAL NAME
MOVE DDB,TTYTAB(DDB) ;PRINT MESSAGE ON RIGHT TTY !!
PUSHJ P,PRNAME
JSP TAC,ERRMES
ASCIZ / already attached
/
ATT3: JSP TAC,ERRMES
ASCIZ /PPN mismatch
/
ATT5A: POP P,DDB
ATT5: JSP TAC,ERRMES
ASCIZ /Can't attach device
/
ATT6: POP P,DDB
JSP TAC,ERRMES
ASCIZ /wasn't detached
/
;FLUSH THIS TTY'S BUFFERS IF NOT IN USE BY A JOB
FLUSH: PUSHJ P,CTEXT1
JUMPE TAC1,NOTENF ;NO ARG?
MOVE TAC,TAC1
PUSHJ P,LOG2LN ;CONVERT TO LINE NUMBER
JRST NOTTTY
SKIPN DDB,TTYTAB(TAC1)
JRST FLUSH1
MOVSI TAC,DEVPRV ;BH 1/24/75 ALLOW DEVPRV TO FLUSH ANYONE
TDNE TAC,JBTPRV(J)
JRST FLUSH0
LDB TAC,PJOBN
CAME TAC,J ;LET HIM DO IT TO HIMSELF
JUMPN TAC,INUSE ;JOB ON IT
FLUSH0: PUSHJ P,TSETBF ;CLEAR BUFFERS
MOVSI TAC,TPMON!IOFST
MOVEM TAC,DEVIOS(DDB) ;MAKE HIM A VIRGIN
FLUSH1: MOVE DDB,-2(P) ;GET BACK OUR DDB
MOVEI DAT,TTOBUF(DDB)
JSP TAC,CONMES
ASCIZ /Flushed/
NOTTTY: MOVE DDB,-2(P)
MOVEI DAT,TTOBUF(DDB)
JSP TAC,ERRMES
ASCIZ /Not a TTY
/
INUSE: MOVE DDB,-2(P)
MOVEI DAT,TTOBUF(DDB)
JSP TAC,ERRMES
ASCIZ /in use
/
;"FORK", "CFORK", "DETACH" AND "CDETACH" COMMANDS
;"DETACH" - DETACH CONSOLE FROM JOB
;"DETACH DEVNAM" - DETACHES DEVICE FROM THE SYSTEM SOFTWAREWISE
MFORK: PUSH P,J ;SAVE J
PUSHJ P,INIJOB ;INITIALIZE A JOB
JRST [POP P,J ;NO JOBS AVAILABLE.
POP P,(P) ;FLUSH CALL TO MFORK
MOVSI TAC,NOMESS ;LET ERROR MESSAGE THROUGH
ANDCAM TAC,-1(P)
JRST LOSEJB] ;
JRST [POP P,J
POP P,(P)
JRST DLYCM1] ;DELAY THIS COMMAND UNTIL FREE STORAGE AVAILABLE
MOVE TAC,J
POP P,J
POPJ P,
CFORK: MOVSI TAC,JERR
TDNE TAC,JBTSTS(J)
JRST NOCONT
MOVM TAC,JOBQUE(J)
CAIE TAC,STOPQ ;START HIM ONLY IF STOPPED.
JRST FORK ;ALREADY RUNNING(MIGHT NOT BE IN RUNQ)
PUSHJ P,MFORK ;GET A NEW JOB NUMBER IN TAC
PUSH P,TAC
MOVNI TAC,RUNQ
MOVEM TAC,JOBQUE(J)
PUSHJ P,REQUE
PUSHJ P,SETRUN
JRST FORK1 ;WE HAVE NEW JOB NUMBER ON STACK.
FORK: PUSHJ P,MFORK ;GET US A NEW JOB NUMBER IN TAC
PUSH P,TAC ;ALL SET.
FORK1: OFFSCN ;TURN OFF SCANNER CHANNEL
PUSH P,DEVIOS(DDB) ;SAVE OLD TOIP!IO
PUSH P,JBTLIN(J)
PUSHJ P,DETCH1
POP P,TAC1 ;GET BACK OLD LINE NUMBER
HRLM J,-2(P) ;SAVE THE OLD JOB NUMBER OVER PC FLAGS FOR FORKC
PUSHJ P,DDBSRC ;GET A NEW DDB
JRST [ ONSCN ;TURN SCANNER CHANNEL BACK ON
SUB P,[1,,1]
POP P,J ;LOSE.
PUSHJ P,RELJOB ;RELEASE THE JOB WE GOT
MOVEI J,0 ;SIGNAL ERROR TO COMRET
POPJ P,]
POP P,TAC ;OLD IOS
AND TAC,[TOIP!IO,,0];ONLY BITS TO BE PRESERVED
IORM TAC,DEVIOS(DDB) ;INTO THE NEW DDB
ONSCN ;TURN ON SCANNER CHANNEL
MOVSI TAC,NOMESS
ANDCAM TAC,-2(P) ;OK TO TALK NOW
MOVEM DDB,-3(P) ;AND WHERE TO SAY IT
MOVEI DAT,TTOBUF(DDB)
POP P,J ;GET THE JOB NUMBER OF NEW JOB.
PUSHJ P,FORKC ;COPY OLD JOB'S POOP
PUSHJ P,PRJOB
PUSHJ P,INLMES
ASCIZ /
Fork you very much/
JRST PRCRCC
↑FORKC: MOVSI TAC,JLOG!JNA
IORM TAC,JBTSTS(J) ;MAKE THIS JOB HIS
SETZM DEVLOG(DDB) ;ZERO LOGICAL NAME OF TTY
PUSHJ P,TTYATI
HLRZ TAC,-1(P) ;GET THE OLD JOB NUMBER BACK
MOVE TAC,PRJPRG(TAC)
MOVEM TAC,PRJPRG(J) ;GIVE HIM SAME PPN
HLRZ TAC,-1(P)
MOVE TAC,JBTPRV(TAC)
MOVEM TAC,JBTPRV(J) ;COPY PRIVILEGES
HLRZ TAC,-1(P)
MOVE TAC,JB2PRV(TAC)
MOVEM TAC,JB2PRV(J) ;ALSO PASSIVE ONES
PUSHJ P,SETLOG ;GET GOOD STUFF
HLRZ TAC,-1(P) ;GET THE OLD JOB NUMBER BACK
MOVE TAC,DSKPPN(TAC)
MOVEM TAC,DSKPPN(J) ;GIVE HIM THE SAME ALIAS
POPJ P,
LOSEJB: JSP TAC,ERRMES
ASCIZ /Job capacity exceeded
/
CDETACH:MOVSI TAC,JERR
TDNE TAC,JBTSTS(J)
JRST NOCONT
MOVM TAC,JOBQUE(J)
CAIE TAC,STOPQ
JRST DETCH1
MOVNI TAC,RUNQ
MOVEM TAC,JOBQUE(J)
PUSHJ P,REQUE
PUSHJ P,SETRUN
DETCH1: PUSHJ P,COMRT2 ;FIX COMMAND BIT, COMCNT BEFORE DETACHING.
JRST TTYDET ;GO DETACH TTY.
DETACH: PUSHJ P,CTEXT ;GET ARGUMENT
JUMPE TAC1,DETCH1 ;ONLY "DET" TYPED
MOVE AC1,JBTPRV(J) ;GET PRIV BITS
TLNN AC1,DEVPRV ;DEVICE DETACH-ATTACH PRIV?
JRST LOGER1 ;NO-PRINT ERROR MSG.
MOVE TAC,TAC1 ;YES-SET UP DEVICE NAME
PUSH P,DDB ;SAVE TTY DDB
PUSHJ P,DEVSRC ;SEARCH FOR DEVICE
JRST DDDD01 ;DEVICE NOT FOUND
MOVE TAC,DEVMOD(DDB) ;CHECK TO SEE IF THIS IS DSK
TLNE TAC,DVUDP ;IS IT A UDP?
JRST DDDUDP ;YES, BIG MESS
TLNE TAC,DVDSK ;IS IT THE DSK?
JRST TEMP1 ;YES-PRINT ERROR MSG.
MOVEI TAC1,ASSPRG ;IS DEVICE IN USE BY ANY PROGRAM?
TDNE TAC1,DEVMOD(DDB)
JRST ASSER1 ;DEVICE IS BUSY (DON'T DET IF IN USE BY THIS JOB).
MOVEI TAC1,ASSCON ;FOUND-SET UP ASSIGNED BY CONSOLE
PUSHJ P,ASSASG ;TRY TO ASSIGN
JRST ASSER1 ;CAN'T ASSIGN
TLNE DDB,SYSDEV ;IS THIS SYSTEM DEVICE?
JRST TEMP1 ;YES-PRINT ERROR MSG.
XOR AC1,AC1 ;NO-SET TO ZERO
DPB AC1,PJOBN ;SET JOB NO. TO NULL JOB
MOVE TAC,DEVMOD(DDB) ;CHECK TO SEE IF THIS IS A TTY
TLNN TAC,DVTTY ;IS IT A TTY?
JRST DDDD03 ;NO-GO AHEAD
LDB TAC,PUNIT ;YES-SET UP FOR SCNSER
MOVEI TAC1,-1 ;SET LEFT HALVE OF TTYTAB TO -1
HRRM TAC1,TTYTAB(TAC);SO THAT SCNSER CHECKS FOR THIS
DDDD03: POP P,DDB ;RESTORE OUR TTY DDB
MOVSI TAC,NOPER!NOCRLF!NOMESS ;ASK TO TYPE OUT A CRLF AND A PERIOD
ANDCAM TAC,-1(P) ; BY ZEROING THESE IN THE COMMAND FLAGS
POPJ P, ;SUCCESSFUL RETURN
DDDUDP: LDB TAC,PUNIT ;TRYING TO DETACH UDP, GET UNIT NUMBER
SKIPE UDPCNT-1(TAC) ;MUST HAVE NO OUTSTANDING DDBS
JRST TEMP1 ;ELSE LOSE
SETZM UDPOWN-1(TAC) ;OK, SET JOB 0 AS OWNER
JRST DDDD03 ;ANNOUNCE WIN
LOGER1: JSP TAC,ERRMES
ASCIZ /Can't detach device
/
DDDD01: PUSHJ P,DADD00 ;NOT A DEV, TRY DD CHAN
JRST TEMP1 ;N
MOVEI TAC,DDBADB ;GET BAD BIT
IORM TAC,DDTAB(TAC1) ;SET IN TABLE
JRST DDDD03 ;WIN
TEMP1: POP P,DDB ;RESTORE TTY DDB
JSP TAC,ERRMES
ASCIZ /in use
/
;"DAYTIME" COMMAND. DAYTIM, DAYT2, DAYCNT, DCTOSD
↑DAYTIM:
PUSHJ P,DECIN ;PICK UP JOB NUMBER ARGUMENT
JRST DAYT2 ;NO ARGUMENT. GIVE HIM DAY, DATE & TIME
JRST COMERA ;ILLEGAL DECIMAL ARGUMENT
JUMPN TAC1,.+2 ;ZERO ARGUMENT?
MOVE TAC1,J ;YES. "DAYTIME 0" GETS TIMES FOR OWN JOB
MOVE TAC,JBTSTS(TAC1)
TLNE TAC,JNA
TLNE TAC,JSEG
JRST NOTLOG ;NO JOB OR A SEGMENT. PRINT NO SUCH JOB.
PUSH P,[0] ;INITIALIZE A FLAG: DONT PRINT DATES
HLRZ TAC,JBTBTM(TAC1);GET LOGIN DATE
CAME TAC,THSDAT ;DID HE LOGIN TODAY?
SETOM (P) ;NO. FLAG TO PRINT DATES
MOVEI TAC,[ASCIZ /Login Run Now
/]
SKIPE (P) ;PRINTING DATES?
MOVEI TAC,[ASCIZ / Login Run Now
/] ;YES, LEAVE ROOM FOR DATES
PUSHJ P,CONMES ;PRINT TITLES
MOVE TAC,JBTBTM(TAC1);GET LOGIN DATE/TIME
PUSHJ P,PRDATM ; AND PRINT IT
MOVE TAC,FTIME(TAC1) ;GET DATE/TIME LAST RUN
PUSHJ P,PRDATM ; AND PRINT IT
MOVE TAC,TIMDAT ;GET CURRENT DATE/TIME
PUSHJ P,PRDATM ; AND PRINT IT
SUB P,[1,,1] ;POP FLAG
JRST CRLF ;PRINT CRLF, AND RETURN
PRDATM: SKIPN -1(P) ;ARE WE PRINTING DATES?
JRST PDTIM0 ;NO. JUST PRINT TIME
PUSH P,TAC1 ;YES.
PUSH P,TAC
HLRZ TAC,TAC ;GET DATE
IDIVI TAC,=31 ;CONVERT TO DAY OF MONTH
MOVEI TAC,1(TAC1) ; WHICH IS THE REMAINDER+1
MOVEI TEM," "
PUSHJ P,PRTIM3 ;PRINT DATE IN 2 COLS PADDING WITH LEADING BLANK
MOVEI TEM,"-"
XCT TYO
POP P,TAC
ANDI TAC,-1 ;CLEAR THE DATE HALF OF TAC
JRST PDTIM1 ;PRINT TIME
LOSYS ;CALLED FROM ONCE BEFORE MAP SETUP
↑DAYT2: PUSH P,DAT ; SAVE DAT OVER CALL ON DATIME
PUSH P,ITEM ;AND ITEM ;JS
MOVE TAC,THSDAT ;PICKUP DATE ;REG
PUSHJ P,DAYCNT ;CALCULATE
IDIVI TAC,7
LSH TAC1,1
MOVEI TAC,DAYTAB(TAC1) ;LOAD ADDRESS OF ASCIZ STRING
PUSHJ P,CONMES
PUSHJ P,PRSPC
POP P,ITEM ;RESTORE STACK
POP P,DAT
MOVE TAC,THSDAT ;END REG STUFF
IDIVI TAC,=31
EXCH TAC,TAC1 ;YEAR AND MONTH IN TAC1
AOS TAC ;DAY IN TAC
PUSHJ P,RADX10 ;PRINT DAY
MOVEI TAC,0
DIVI TAC,=12
EXCH TAC,TAC1
MOVE TAC,MONTAB(TAC) ;MONTH
DPB TAC,[POINT 21,DAMESS,27]
MOVEI TAC,DAMESS
PUSHJ P,CONMES ;PRINT DAY
MOVEI TAC,=64(TAC1)
PUSHJ P,RADX10 ;PRINT YEAR
PUSHJ P,PRSPC ;ADD SPACES
HRRZ TAC,TIMDAT ;PRINT TIME OF DAY
PUSHJ P,PDTIME
JRST CRLF
↑DAYTAB:
ASCIZ/Wednesday/
ASCIZ/Thursday/
ASCIZ/Friday/
ASCIZ/Saturday/
ASCIZ/Sunday/
ASCIZ/Monday/
ASCIZ/Tuesday/
MONTHB: 0 ;JAN
=31 ;FEB
=59 ;MAR
=90 ;APR
=120 ;MAY
=151 ;JUN
=181 ;JUL
=212 ;AUG
=243 ;SEP
=273 ;OCT
=304 ;NOV
=334 ;DEC
;CALL WITH TAC SET UP W/ SYSTEM FORMAT DATE.
;RETURN W/ TAC= NUMBER OF DAYS SINCE JAN 1, 1964
;TAC1 AND AC2 CLOBBERED
↑DAYCNT:
IDIVI TAC,=31 ;DAY OF THE MONTH IN TAC1
MOVEI DAT,1(TAC1) ;DAY INTO DAT
IDIVI TAC,=12 ;MONTHS IN TAC1, YEARS IN TAC
ADD DAT,MONTHB(TAC1) ;ADD NUMBER OF DAYS BEFORE THE 1st OF MONTH
TRNN TAC,3 ;SKIP UNLESS LEAP YEAR
CAIGE TAC1,2 ;LY. SKIP IF AFTER FEBRUARY
SUBI DAT,1 ;NOT LEAP YEAR. OR BEFORE MARCH
MOVEI TAC1,3(TAC)
LSH TAC1,-2 ;NUMBER OF LY SINCE '64 NOT INCLUDING THIS YEAR
IMULI TAC,=365 ;NUMBER OF YEARS TIMES 365
ADDI TAC,(TAC1) ;PLUS NUMBER OF PRIOR LEAP YEARS
ADDI TAC,(DAT) ;PLUS NUMBER OF DAYS SO FAR THIS YEAR.
POPJ P,
MONTHX: 0 ;JAN
=31 ;FEB
=60 ;MAR
=91 ;APR
=121 ;MAY
=152 ;JUN
=182 ;JUL
=213 ;AUG
=244 ;SEP
=274 ;OCT
=305 ;NOV
=335 ;DEC
;DAYCOUNT IN TAC TO SYSTEM DATE FORMAT IN TAC.
↑DCTOSD:MOVEI AC3,=1964 ;COUNT YEARS. START AT 1964
DCTOS1: TRNE AC3,3 ;IS THIS A LEAP YEAR?
JRST DCTOS3 ;NO.
MOVE AC1,AC3 ;IS THIS A CENTURY YEAR
IDIVI AC1,=100
JUMPN AC2,DCTOS2 ;JUMP IF NOT CENTURY YEAR. THIS IS A LEAP YEAR
TRNE AC1,3 ;CENTURY YEARS ARE LEAP YEARS IF MULTIPLES OF 400
JRST DCTOS3 ;CENTURY YEAR NOT A MULTIPLE OF 400 ISN'T LEAP
DCTOS2: CAIGE TAC,=366 ;A FULL YEAR'S WORTH OF DAYS LEFT?
JRST DCTOS5 ;NO. AC3 CONTAINS CORRECT YEAR.
SUBI TAC,=366
AOJA AC3,DCTOS1 ;COUNT A YEAR AND LOOP
DCTOS3: CAIGE TAC,=365
JRST DCTOS4 ;AC3 HAS CORRECT YEAR
SUBI TAC,=365
AOJA AC3,DCTOS1
DCTOS4: CAIL TAC,=31+=28 ;NOT A LEAP YEAR. IS THIS MARCH OR LATER?
ADDI TAC,1 ;YES. COMPENSATE FOR MONTHX
DCTOS5: SUBI AC3,=1964
IMULI AC3,=12*=31
MOVEI AC2,=11 ;COUNT DOWN MONTHS TO FIND FIRST ONE THAT'S SMALL
CAMGE TAC,MONTHX(AC2)
SOJA AC2,.-1
SUB TAC,MONTHX(AC2)
IMULI AC2,=31
ADD TAC,AC2
ADD TAC,AC3
POPJ P,
HISYS
;"TIME (JOB NO.)" - PRINT TOTAL AND INCREMENTAL RUNNING TIME FOR A JOB
;"TIME 0" IMPLIES RUNTIME FOR NULL JOB AND THE TOTAL TIME SPENT SHUFFLING USERS
; IF NO JOB NO. GIVEN-TIME WILL BE FOR CURRENTLY LOGGED IN JOB NO.
RUNTIM: PUSHJ P,DECIN ;GET JOB NO. ARG.
JRST CRUN1 ;NO ARG. GIVEN
JRST COMERA ;ILLEGAL DECIMAL CHARACTER RETURN
JUMPE TAC1,CRUN2 ;RUNTIME 0 GIVEN?
CAIL TAC1,JOBN ;JOB NO. TOO BIG?
JRST NOTLOG ;YES, ILLEGAL JOB NUMBER
CRUN3: MOVE TAC,JBTSTS(TAC1);IS THIS A REAL JOB WE HAVE HERE?
TLNE TAC,JNA ;SKIP IF NO NUMBER ASSIGNED.
TLNE TAC,JSEG ;THERE IS A JOB HERE. SKIP IF NOT A SEGMENT
JRST NOTLOG ;NO JOB OR A SEGMENT. PRINT NO SUCH JOB.
PUSHJ P,INLMES ;PRINT TITLES
ASCIZ / Total Increment Wait PS
/
MOVE TAC,TTIME(TAC1) ;CPU TIME SINCE LAST LOGIN
PUSHJ P,PRTIME ;PRINT COMPUTE TIME USED
MOVE TAC,TTIME(TAC1) ;CALCULATE INCREMENTAL RUN TIME
SUB TAC,RTIME(TAC1)
PUSHJ P,PRTIME ; AND PRINT IT
MOVE TAC,TTIME(TAC1)
CAMN J,TAC1 ;PRINTING TIME OUT FOR OWN JOB?
MOVEM TAC,RTIME(TAC1) ;YES. RESET INCREMENTAL TIME.
SKIPGE TAC,JBTWAT(TAC1);GET TIME WAITING FOR SYSTEM
ADD TAC,UPTIME ;MAKE THIS TIME REAL
PUSHJ P,PRTIME ; AND PRINT IT
MOVE TAC,JBTKCJ(TAC1);PAGE-JIFFIES USED
IDIVI TAC,=60 ;CONVERT TO PAGE-SECONDS
JRST DECLF ;PRINT WITH A CRLF. RETURN TO COMRET.
CRUN1: SKIPE TAC1,J ;LOGGED IN?
JRST CRUN3 ;YES. GIVE HIM HIS OWN TIME.
CRUN2: PUSHJ P,INLMES ;"TIME 0" OR UNLOGGED IN "TI"
ASCIZ /Up /
MOVE TAC,UPTIME
IDIVI TAC,=60*=60 ;CONVERT TO MINUTES
IDIVI TAC,=60 ;CALCULATE HOURS
PUSH P,TAC1 ;SAVE MINUTES
PUSHJ P,RADX10 ;PRINT HOURS
PUSHJ P,INLMES
ASCIZ / hr /
POP P,TAC ;RETRIEVE MINUTES
PUSHJ P,RADX10 ;PRINT MINUTES
PUSHJ P,INLMES
ASCIZ / min; Shfl /
MOVE TAC,SHFWRD ;NO. WORDS SHUFFLED
IDIVI TAC,=1000000/<=60*3> ;ABOUT THIS MANY WORDS PER TICK.
PUSHJ P,PERCNT ;PRINT AS A PERCENTAGE OF UPTIME
PUSHJ P,INLMES
ASCIZ /; Null /
MOVE TAC,TTIME ;GET NULL TIME
PUSHJ P,PERCNT ;AND PRINT AS A PERCENTAGE OF UPTIME
PUSHJ P,INLMES
ASCIZ /; Ilev /
MOVE TAC,INTIME
PUSHJ P,PERCNT
PUSHJ P,INLMES
ASCIZ /; RIT /
MOVE TAC,JLRIT
PUSHJ P,PERCN1
JRST CRLF
;ROUTINE TO PRINT A PERCENTAGE OF UPTIME IN FORM "DD.D%"
;CALL WITH TIME (IN TICKS) IN TAC: PUSHJ P,PERCNT
PERCNT: IMULI TAC,=1000
IDIV TAC,UPTIME
PERCN1: IDIVI TAC,=10 ;CALCULATE PERCENTAGE
PUSH P,TAC1 ;SAVE FRACTION
PUSHJ P,RADX10 ;PRINT INTEGRAL PART OF PERCENTAGE
PUSHJ P,PRPER ;PRINT A PERIOD
POP P,TEM
ADDI TEM,"0"
XCT TYO ;PRINT TENTHS OF A PERCENT
MOVEI TEM,"%"
XCT TYO ;PRINT PERCENT SIGN
POPJ P,
PR2SP: MOVEI TEM," "
XCT TYO
TYOPOP: XCT TYO ;PRINT TWO SPACES AFTER TIME
POPJ P,
PRCOLN: MOVEI TEM,":" ;PRINT COLON
JRST TYOPOP
;ROUTINE TO PRINT A TIME IN FORMAT "H:MM:SS'TT " (HOURS, MINS, SECS, TICKS)
;CALL WITH TIME IN TICKS IN TAC. PRESERVES TAC1!
PRTIME: PUSH P,TAC1
IDIVI TAC,=60*=60*=60 ;HOURS INTO TAC
JUMPE TAC,PRTIM1 ;PRINT 2 SPACES INSTEAD OF 0: FOR HOURS
PUSHJ P,RADX10
PUSHJ P,PRCOLN ;PRINT COLON
TRCA TEM,"0"≠":" ;MAKE SURE MINUTES GET PADDED WITH 0 IF NECESSARY
PRTIM1: PUSHJ P,PR2SP ;PRINT 2 SPACES
MOVE TAC,TAC1
IDIVI TAC,=60*=60 ;MINUTES INTO TAC
PUSHJ P,PRTIM3
PUSHJ P,PRCOLN
MOVE TAC,TAC1
IDIVI TAC,=60 ;SECONDS INTO TAC
PUSHJ P,PRTIM2 ;PRINT WITH LEADING 0 IF NECESSARY
MOVEI TEM,"'" ;USE RIGHT QUOTE TO PUNCTUATE TICKS
XCT TYO
MOVE TAC,TAC1 ;TICKS INTO TAC
PUSHJ P,PRTIM2
PUSHJ P,PR2SP
POP P,TAC1 ;RESTORE TAC1 FROM STACK
POPJ P, ;AND RETURN
PRTIM2: MOVEI TEM,"0" ;PAD WITH LEADING 0 IF NECESSARY
PRTIM3: CAIGE TAC,=10 ;ANY PADDING NEEDED?
XCT TYO ;YES. ONE CHARACTER OF PADDING PLEASE
JRST RADX10 ;NOW PRINT TAC AS DECIMAL NUMBER AND RETURN
;ROUTINE TO PRINT TIME OF DAY IN FORMAT "HH:MM "
;CALL WITH TIME IN SECONDS IN TAC. PRESERVES TAC1
PDTIM0: ANDI TAC,-1 ;CLEAR DATE IN LEFT HALF OF TAC
PDTIME: PUSH P,TAC1 ;SAVE TAC1
PDTIM1: IDIVI TAC,=60*=60 ;HOURS INTO TAC
PUSHJ P,PRTIM2 ;PRINT HOURS WITH LEADING 0 IF NECESSARY
PUSHJ P,PRCOLN
MOVE TAC,TAC1
IDIVI TAC,=60 ;MINUTES INTO TAC
PUSHJ P,PRTIM2 ;PRINT MINUTES WITH LEADING 0 IF NECESSARY
PUSHJ P,PR2SP ;PRINT 2 SPACES
POP P,TAC1 ;RESTORE TAC1
POPJ P,
;ROUTINE TO LET TTY TALK TO ANY OTHER RING OF TTYS
; "TALK TTYN"
; TTYN NEED NEVER HAVE BEEN TYPED ON BEFORE
TALK: PUSHJ P,CTEXT ;GET ARGUMENT
JUMPE TAC1,TALK2 ;NONE SPECIFIED
MOVE TAC,TAC1
PUSHJ P,DEVSRC ;SEARCH FOR DEVICE
JRST TALK1 ;NONE AVAIL
PUSHJ P,TTYTLK
JRST TALK1
POPJ P,
TALK2: MOVEM J,-1(P)
JRST NOTENF
TALK1: MOVE DDB,-2(P) ;RESTORE TTY DDB
MOVSI J,NOINCK ;SET FLAGS TO PRINT RESPONSE
MOVEM J,-1(P)
JSP TAC,ERRMES
ASCIZ /busy
/
;ECOM, DCOM, EXAMINE/DEPOSIT COMMANDS
;"E LOC" - EXAMINE AND PRINT IN OCTAL THE CONTENTL OF LOC. PRINT TAB, NOT CRLF.
; IF LOC IS OMITTED, NEXT LOC (FOLLWING ONE PREVIOUSLY EXAMINED) IS PRINTED.
;"DE LH RH LOC" - DEPOSITS LH,,RH IN LOC. IF LOC OMITTED, USES CURRENT LOC.
ECOM: PUSHJ P,OCTIN ;GET OCTAL LOCATION IN TAC1
JRST ECOM2 ;NO ARG - GET CURRENT LOC
JRST COMERA ;ILLEGAL CHARACTER
ECOM1: PUSHJ P,TESTIN ;GET SET UP. MAKE SURE UPPER, IF NEEDED, IS INCORE
JFCL ;OK IF WRITE-PROT
PUSHJ P,DEAT ;CHECK FOR AC REFERENCE. TAC1←USER RELATIVE ADDRESS
PUSH P,TAC1 ;SAVE USER-RELATIVE ADDRESS ON STACK.
XCTR XR,[HRRZ TAC,JOBEXM] ;PRINT LOC BEING EXAMINED
PUSHJ P,OCTPNT
PUSHJ P,INLMES ;PRINT SLASH TAB
ASCIZ %/ %
XCTR XR,[HLRZ TAC,@(P)] ;PRINT LEFT HALF
PUSHJ P,OCTPNT
PUSHJ P,INLMES ;PRINT SPACE
ASCIZ / /
XCTR XR,[HRRZ TAC,@(P)] ;PRINT RIGHT HALF
PUSHJ P,OCTPNT
PUSHJ P,INLMES ;PRINT FINAL TAB
ASCIZ / /
JRST TPOPJ
;GET THE PREVIOUS LOC+1. DON'T AOS JOBEXM SINCE WE MAY HAVE TO COME THROUGH
;HERE SEVERAL TIMES SINCE TESTIN MAY CALL DLYCOM
ECOM2: XCTR XR,[MOVE TAC1,JOBEXM]
AOJA TAC1,ECOM1
;HERE FOR DEPOSIT COMMAND.
DCOM: PUSHJ P,OCTIN ;GET LH
JRST NOTENF ;NOT ENOUGH ARGUMENTS
JRST COMERA ;ILLEGAL CHARACTER
MOVSI IOS,(TAC1) ;SAVE LH.
PUSHJ P,OCTIN ;GET RH
JRST NOTENF ;NOT ENOUGH ARGUMENTS
JRST COMERA ;ILLEGAL CHARACTER
HRRI IOS,(TAC1) ;SAVE RH
PUSHJ P,OCTIN ;GET LOC
XCTR XR,[SKIPA TAC1,JOBEXM] ;NOT SPECIFIED (DO DEPOSIT-THIS)
JRST COMERA ;ILLEGAL CHARACTER
PUSHJ P,TESTIN ;RETURN IF READY FOR DEPOSIT.
JRST ECOMP ;LOSE IF WRITE-PROT
CAIGE TAC1,20 ;IN USER ACS?
JRST .+3 ;YES.
CAIG TAC1,JOBPFI ;IN PROTECTED PART?
JRST ECOMA ;YES. DISALLOW.
PUSHJ P,DEAT ;CHECK FOR AC REFERENCE. TAC1←RELATIVE ADDRESS.
XCTR XW,[MOVEM IOS,(TAC1)]
JUMPE AC3,CPOPJ ;RETURN UNLESS DEPOSIT IN UPPER.
SETOM STIME(AC1) ;MARK UPPER AS ALTERED.
POPJ P,
;HERE ARE SOME SUBROUTINES FOR EXAMINE/DEPOSIT
DEAT: XCTR XW,[MOVEM TAC1,JOBEXM] ;STORE FOR NEXT TIME - MODIFIES CORE IMAGE.
SETOM STIME(J) ;AND NOTE THIS CORE IMAGE CHANGED
XCTR XR,[MOVE TAC,JOBPC] ;GET THE PC.
CAMN J,JOB(PID) ;IS THIS JOB RUNNING (MAYBE CCONTINUED)
MOVE TAC,USRPC(PID) ;YES, THIS IS THE PC WE NEED.
CAIL TAC1,20 ;IS IT AN AC?
POPJ P, ;NO
;(IF PC IS IN EXEC MODE, EXEC ACS ARE IN JOBDAC, AND USER LEVEL ACS ARE IN JOBAC)
TLNE TAC,USRMOD ;USER MODE?
ADDI TAC1,JOBDAC ;ACS ARE IN JOBDAC WHILE NOT RUNNING.
POPJ P, ;
;SETUP ROUTINE FOR EXAMINE/DEPOSIT COMMANDS
;ADDRESS CHECKS, AND WAITS FOR SWAP (VIA DLYCOM) IF NEEDED FOR UPPER
;EXECUTES INSTRUCTION FOLLOWING CALL IF WRITE-PROTECTED UPPER
;RETURNS AC3 NON-ZERO IF THIS REFERENCE IS TO AN UPPER. AC1←UPPER'S JOB NUMBER.
TESTIN: ANDI TAC1,-1 ;FLUSH EXTRANEOUS GARBAGE
MOVEI AC3,0 ;INITIALLY ASSUME LOWER
HLRZ TAC,JBTPAG(J) ;PAGE COUNT OF LOWER
LSH TAC,=9 ;SIZE OF LOWER IN WORDS
CAIGE TAC1,(TAC) ;SKIP IF ILLEGAL LOCATION
JRST CPOPJ1 ;LEGAL
MOVEI AC3,(TAC) ;COMPUTE POSSIBLE UPPER ORIGIN
LDB AC1,PSEGN ;# OF UPPER
JUMPE AC1,ECOMP ;NONE
MOVE AC2,JBTSTS(AC1)
TLNE AC2,JWP ;IF WRITE-PROTECTED,
XCT @(P) ;CHECK LEGALITY BEFORE TRYING TO SWAP
PUSH P,TAC1 ;SAVE USER-RELATIVE ADDRESS
MOVE TAC1,AC1 ;TAC1←JOB NUMBER OF UPPER.
PUSHJ P,CORSGT ;TAC1←CORE SIZE IN WORDS, OF UPPER
SOS TAC,TAC1 ;TAC←PROTECTION SIZE OF UPPER
POP P,TAC1 ;RESTORE USER'S ADDRESS.
CAIGE AC3,400000
MOVEI AC3,400000 ;AC3 IS NOW ORIGIN OF UPPER
ADDI TAC,(AC3) ;RELOCATE PROT TO UPPER
CAIL TAC1,(AC3)
CAILE TAC1,(TAC) ;LEGAL
JRST ECOMP ;NO
TLNN AC2,SWP ;IS UPPER IN CORE
JRST CPOPJ1
MOVSI TAC,JHLDIN
IORM TAC,JBTSTS(J) ;KEEP US IN
EXCH J,AC1
MOVSI TAC,COMSNB
PUSHJ P,SETSIN ;AND GET HIM IN
MOVE J,AC1
POP P,(P)
JRST DLYCM1 ;AND DELAY
ECOMP: POP P,TAC ;POP OFF RETURN (CALLED FROM INSIDE TESTIN)
ECOMA: JSP TAC,ERRMES ;ILLEGAL MEMORY REFERENCE
ASCIZ /Out of bounds
/
;CBLANK, NOCOM,
;BLANK OR NO ALPHA NUMERIC BEFORE BREAK CHAR.
;DISPATCHED TO LIKE ANY OTHER COMMAND IN COMMAND TABLE
;NOCOM IS LAST IN THE COMMAND DISPATCH TABLE
CBLANK: CAIE TEM,12 ;WAS BREAK A L.F.?
CAIN TEM,";" ;NO, IS IT SEMI COLON(MONITOR COMMENT)
POPJ P, ;YES, IGNORE FALL IN UNKNOWN COMMAND
NOCOM: JRST COMERR ;NO, APPEND ? TO WHAT HE TYPED IN
;FINIS - FINISH DEVICE - CLOSES,RELEASE AND DEASSIGNS DEVICE
FINIS: SKIPN JBTPAG(J) ;SKIP IF CORE IS ASSIGNED
POPJ P, ;NO CORE, NO DEVICES, NO FINISH.
PUSHJ P,CTEXT1 ;READ IN THE DEVICE NAME
XCTR XW,[MOVEM TAC1,JOBFDV] ;SAVE THE SIXBIT OF THE DEVICE NAME
MOVSI TAC,TTYRNU ;PUT TTY INTO USER MODE
IORM TAC,-1(P) ;TELL COMRET
JSP TAC1,MSTART ;MAKE US A MONITOR JOB
JSP TAC,MONSTR ;RETURN HERE AT UUO LEVEL. SETUP ACS
XCTR XR,[SKIPN TAC,JOBFDV] ;SET UP TO SEARCH FOR THIS DEVICE
JRST FINALL ;NONE GIVEN. FINISH ALL.
FIN3: PUSHJ P,DEVLG ;TRY LOGICAL NAMES FIRST
JRST FIN1 ;NOT FOUND, TRY PHYSICAL NAMES
PUSHJ P,FINRDV ;TRY TO FINISH IT
PUSH P,[FIN3+1] ;IF WE RETURN, THAT WASN'T THE RIGHT DEVICE
JRST DEV0 ;CONTINUE SCANNING THE DEVICES
FIN1: PUSHJ P,DEVPHY ;SEARCH PHYSICAL NAMES
JRST FIN2 ;NO NAMES, ERROR
PUSHJ P,FINRDV
PUSH P,[FIN1+1]
MOVE AC1,DEVMOD(DDB)
TLNN AC1,DVTTY ;FINISH TTY?
JRST DEVLP2 ;NO - SEARCH FOR ANOTHER DEVICE OF SAME NAME
FIN2: PUSHJ P,TTYFNU ;GET A TTY FOR US
PUSHJ P,INLMES ;GIVE AN ERROR MESSAGE
ASCIZ /
Finish what?/
JRST FINXIT ;STOP JOB, RESCHEDULE.
;FINISH A DEVICE BY RELEASING IT. DDB MUST BE IN USRJDA OR IN IOPDL
FINRDV: SKIPGE UCHN,USRHCU(PID) ;SKIP UNLESS SAVGET IO ACTIVE.
JRST FIN2 ;NO CHANNELS, NO DEVICES
CAILE UCHN,17
MOVEI UCHN,17 ;A LITTLE BULLETPROOFING.
FINRD1: HRRZ AC1,USRJDA(UCHN) ;GET DDB ADDRESS.
CAIE AC1,(DDB) ;IS THIS IT?
SOJGE UCHN,FINRD1 ;NO, LOOK AT ANOTHER
JUMPL UCHN,FINSTK ;IF NOT FOUND, GO CHECK IO PDL
PUSHJ P,FINREL ;RELEASE IT
FINRD2: PUSHJ P,TTYFNU ;GET A TTY
FINXIT: PUSHJ P,PRCRCC
PUSHJ P,TTYSTC ;KEEP THE TTY IN COMMAND MODE
JRST ESTOP ;STOP THE JOB NOW.
FINREL: PUSH P,UCHN
MOVSI UUO,(<RELEAS>) ;NOW SET UP TO RELEASE IT
DPB UCHN,PUUOAC
MOVE UCHN,DEVMOD(DDB)
TRNE UCHN,ASSCON ;WILL DDB BE THERE AFTER RELEASE?
JRST FINRL1 ;YES
XCT UUO ;RELEASE THE DEVICE
FINRL2: POP P,UCHN
POPJ P,
FINRL1: PUSH P,DDB
XCT UUO
POP P,DDB
MOVSI UCHN,DVDIRIN ;CLEAR DIRECTORY IN CORE BIT
ANDCAM UCHN,DEVMOD(DDB)
JRST FINRL2
FINSTK: MOVE J,JOB(PID)
SKIPL UCHN,JBTIOP(J)
POPJ P, ;NOTHING ON STACK
FINST1: HRRZ AC1,(UCHN)
CAIE AC1,(DDB)
JRST FINST2
MOVE DDB,USRJDA
EXCH DDB,(UCHN) ;SAVE CHANNEL 0
MOVEM DDB,USRJDA ;AND PUT THIS DDB IN CHANNEL 0
PUSH P,UCHN
MOVEI UCHN,0
PUSHJ P,FINREL ;RELEASE CHANNEL 0
POP P,UCHN
MOVE DDB,(UCHN) ;RESTORE CHANNEL 0
EXCH DDB,USRJDA
MOVEM DDB,(UCHN) ;STORE ZERO (FROM RELEASE) IN IOPDL
JRST FINRD2 ;
FINST2: ADD UCHN,[2,,2]
JUMPL UCHN,FINST1
POPJ P,
FINALL: SKIPGE UCHN,USRHCU(PID) ;SEE IF HE HAS CHANNELS OPEN
JRST FINAL3 ;NONE LEFT OPEN.
CAILE UCHN,17
MOVEI UCHN,17 ;MAKE SURE IT'S REASONABLE..
FINAL1: SKIPE DDB,USRJDA(UCHN) ;IS THERE ANYONE HERE?
PUSHJ P,FINREL
SOJGE UCHN,FINAL1
FINAL3: MOVE J,JOB(PID) ;DEPARTMENT OF REDUNDANCY DEPARTMENT
SKIPL UCHN,JBTIOP(J) ;ANY IO PDL?
JRST FINST3 ;NO. WE'RE DONE.
FINST4: SKIPN DDB,(UCHN)
JRST FINST5
SETZM (UCHN)
MOVEM DDB,USRJDA
PUSH P,UCHN
MOVEI UCHN,0
PUSHJ P,FINREL
POP P,UCHN
FINST5: ADD UCHN,[2,,2]
JUMPL UCHN,FINST4
HRRZ AC1,JBTIOP(J)
SETZM JBTIOP(J)
PUSHJ P,FSGIVE
FINST3: PUSHJ P,IOALLR ;RELEASE ANYTHING ELSE WE CAN FIND.
JRST FINRD2
;"RESOURCES" - PRINT OUT AVAILABLE DEVICES AND FREE BLOCKS ON THE DISK
FREDEV: MOVEI AC2,0 ;START WITH UNIT 0 (DSK)
JRST FRUDP2
FRUDP1: SKIPN UDPOWN-1(AC2) ;IS UDP IN USE FOR SWAPPING OR DET?
JRST FRUDP5 ;YES. PRINT NOTHING. (NOT A RESOURCE)
FRUDP2: MOVE TAC,DKDBML(AC2) ;ELSE GET ADDR OF MODEL DDB
MOVE TAC1,DEVNAM(TAC) ;GET NAME FROM MODEL
PUSHJ P,PRNAME ;PRINT THE NAME
MOVEI TAC,[ASCIZ/ /] ;ONE SPACE
PUSHJ P,CONMES
SKIPG SATADR(AC2)
JRST FRUDP3 ;NO SATADR, NO DSKRES.
MOVEI TAC1,(AC2)
PUSHJ P,DSKRES ;GET FREE BLOCK COUNT FROM DSKSER
PUSHJ P,RADX10 ;CONVERT TO DECIMAL
JUMPE AC2,FRUDP4 ;AVOID UDP STUFF FOR DSK
FRUDP3: SKIPG UDPCNT-1(AC2) ;SKIP IF NOT FREE
JRST FRUDP4 ;IS FREE. THAT'S ALL WE TYPE.
MOVEI TAC,[ASCIZ / Public /]
SKIPL UDPOWN-1(AC2) ;SKIP IF PUBLIC
MOVEI TAC,[ASCIZ / Private /]
PUSHJ P,CONMES
SKIPLE TAC,SATADR(AC2)
PUSHJ P,SATTAC ;TYPE SATID IF ANY
FRUDP4: PUSHJ P,CRLF
FRUDP5: CAIGE AC2,UPACKS ;DONE ENOUGH?
AOJA AC2,FRUDP1 ;INCREMENT COUNT AND DO IT AGAIN
PUSH P,[0]
HLRZ AC1,DEVLST ;GET DDB POINTER
LOP01: MOVE TAC,DEVMOD(AC1) ;GET DEVMOD
TRNN TAC,ASSCON+ASSPRG ;ASSIGNED BY CONSOLE OR PROGRAM?
TLNE TAC,DVTTY!DVDSK!DVUDP!DVIMP ;IMP,TTY,DSK,UDP?
JRST LP1RET ;ASSIGN, OR SPECIAL DEVICE
LOP04: MOVEI TEM,"," ;GET A COMMA
SKIPE (P) ;SKIP IF FIRST DEVICE
XCT TYO ;NOT FIRST. PRINT COMMA
MOVE TAC1,DEVNAM(AC1) ;GET DEVICE NAME
HRRZ AC2,DEVSER(AC1) ;SAME DEVICE-TYPE AS PREVIOUS ONE?
CAMN AC2,(P) ;
HRLZ TAC1,TAC1 ;YES. PRINT ONLY NUMBER (FLUSH LEFT SIDE)
MOVEM AC2,(P) ;AND SAVE FOR NEXT DEVICE
PUSHJ P,PRNAME ;GO AND PRINT IT OUT
LP1RET: HLRZ AC1,DEVSER(AC1) ;GET NEXT DDB
JUMPN AC1,LOP01 ;END OF CHAIN?
PUSHJ P,CRLF ;YES
JRST TPOPJ ;GET THAT EXTRA WORD OFF THE STACK
SATTAC: PUSH P,SATID(TAC) ;SAVE SATID ON STACK
MOVEI TEM,"(" ;(SATTAC CALLED BY PJOB FOR UDP)
XCT TYO
POP P,TAC1 ;GET VOLUME ID
PUSHJ P,PRNAME ;(IBM VOCABULARY TAKES OVER THE WORLD)
MOVEI TEM,")"
XCT TYO
POPJ P,
;RUNCHK, DLYCOR, DLYCR1
RUNCHK: CAMN J,STUSER ;SYSTEM TAPE USER?
JRST DLYCM1 ;YES. DELAY
ACTCHK: SKIPN JBTPAG(J) ;SKIP IF JOB HAS CORE INCORE
JRST ACTCH1 ;JOB HAS NO CORE INCORE.
TLNE AC1,SWP ;JOB HAS CORE. IS IT IN TRANSIT?
JRST ACTCH1 ;YES. - IN TRANSIT.
PUSHJ P,ANYACT ;NOT IN TRANSIT. ARE DEVICES ACTIVE?
JRST DLYCM1 ;DEVICES ARE ACTIVE - DELAY COMMAND.
ACTCH1: MOVE TAC1,-1(P) ;RESTORE COMMAND DISPATCH ADDRESS
MOVE DDB,-2(P) ;RESTORE TTY DDB ADDRESS
MOVE AC1,JBTSTS(J) ;RESTORE JOB STATUS
POPJ P,
;ROUTINE TO DELAY A COMMAND
;DELAYS COMMAND TO BE EXECUTED WHEN JOB IN CORE MEMORY AND POPS UP ONE LEVEL.
DLYCR2: MOVE TAC1,LINSAV ;GET THE LINE NUMBER
MOVSI TAC,COMBIT
; CONO PI,SCNOFF
OFFSCN ;TURN OFF SCANNER CHANNEL
TDNE TAC,TTYTAB(TAC1)
SOS COMCNT ;DECREMENT IF COMMAND BIT WAS SET
ANDCAM TAC,TTYTAB(TAC1)
IFN FTTTYBUG,<
PUSHJ P,COMBCK
PUSHJ P,CNTCOM
>
; CONO PI,SCNON
ONSCN ;TURN ON SCANNER CHANNEL
POPJ P,
DLYCR1: PUSHJ P,DLYCR2 ;CLEAR COMBIT
JRST DLYCM1 ;
DLYCOR: PUSHJ P,DLYCR2 ;CLEAR COMBIT
DLYCM: PUSHJ P,DLYCOM ;REQUEUE JOB TO CMWQ
↑DLYCM1:AOS NDLYCMS ;COUNT A DELAYED COMMAND
MOVSI DDB,DLYBIT ;TTYTAB BIT FOR TTYCM TO SET
DLYCM3: SUB P,[3,,3] ;FLUSH THE RETURN TO COMRET
; AND THE COMMAND BITS
; AND THE TTY DDB POINTER.
PUSHJ P,TTYCM ;DELAY PRESENT COMMAND AND GET A NEW COMMAND
POPJ P, ;THERE ARE NO NEW COMMANDS
JRST COM0 ;PROCESS A COMMAND.
;HERE TO DELAY A COMMAND UNTIL OUTPUT BUFFER EMPTY
DLYCM2: PUSHJ P,TTYSTR ;START TYPEOUT
PUSHJ P,DLYCR2 ;CLEAR COMBIT
MOVSI DDB,PAUSEB ;BIT FOR TTYCM TO SET
JRST DLYCM3
;STOPCK SEARCH DEVICE CHAIN FOR DSK WITH COUNTS ON
;CALL MOVE J,JOB NO
; PUSHJ P,STOPCK
; CAN'T STOP RETURN
; OK TO STOP RETURN
IFN FTDISK,<
↑STOPCK:PUSH P,DDB
PUSHJ P,STOPC1
SOS -1(P) ;MAKE NON-SKIP RETURN.
POP P,DDB
JRST CPOPJ1
STOPC1: MOVEI DDB,DSKDDB
↑STOPC2:MOVSI TAC1,DSKFGS ;CALLED FROM PARSER TO FLUSH GOBIT
STOPD: LDB TAC,PJOBN
CAIE J,(TAC) ;ASSIGNED TO THIS JOB?
JRST STOPC ;NO
TDNE TAC1,DEVIOS(DDB) ;DUMP MODE I/O IN PROGRESS ?
POPJ P, ;YES. DELAY. OFFENDING DDB IN DDB.
STOPC: HLRZ DDB,DEVSER(DDB)
MOVE TAC,DEVMOD(DDB) ;LOOP THRU DSK AND UDP DDBS
TLNE TAC,DVDSK
JRST STOPD ;ONLY LOOK AT DVDSK ONES
TLNE TAC,DVUDP
JRST STOPC ;BUT KEEP SEARCHING IF DVUDP
JRST CPOPJ1 ;OK TO STOP
>
;"FILES <filename or job number>" -- print status of open files.
FILCOM: SKIPE TAC,SAVDDB(DDB) ;SKIP UNLESS CONTINUING DELAYED COMMAND
PUSHJ P,FIL2 ;FIND PLACE TO CONTINUE FROM
MOVEI AC1,DSKDDB ;FIL2 SKIPS ON SUCCESS WITH SIGN BIT OF AC1 SET
PUSHJ P,CTEXT1 ;GET ARG OF COMMAND
JUMPE TAC1,FIL5C ;NO ARG
PUSH P,TAC1 ;SAVE ARG
CAIN TEM,"." ;DELIMITING PERIOD MEANS FILENAME EXT COMING
JRST FIL3 ;READ EXT
CAIN TEM,"[" ;DELIMITING LEFT BRACKET MEANS PPN COMING
JRST FIL4 ;READ PPN
PUSHJ P,FIL2JB ;SEE IF ARG WAS A JOB NUMBER RATHER THAN FILENAME
JRST FIL5 ;GOT JOB NUMBER
PUSH P,[0] ;MUST BE FILE NAME WITH ZERO EXTENSION.
FIL6D: SKIPN AC2,DSKPPN(J) ;GET APPROPRIATE PPN FOR FILE
MOVE AC2,PRJPRG(J)
FIL6: PUSH P,AC2 ;SAVE PPN
PUSHJ P,FIL99 ;SEE IF ANYTHING LEFT IN COMMAND LINE
JUMPL AC1,FIL6E ;DON'T ADVANCE TO NEXT DDB IF CONTINUING DELAYED CMD
FIL6A: PUSHJ P,NXTDSK ;GET NEXT DSK DDB
JRST FIL6B ;NONE, DONE
FIL6E: MOVE TAC,DEVFIL(AC1) ;GET NAME OF FILE OPEN
CAME TAC,-2(P) ;SAME AS FILE OF INTEREST?
JRST FIL6A ;NOPE
HLLZ TAC,DEVEXT(AC1) ;GET EXT OF FILE OPEN
CAME TAC,-1(P) ;SAME AS FILE OF INTEREST?
JRST FIL6A ;NOPE
MOVE TAC,FILPPN(AC1) ;AND PPN
CAMN TAC,(P) ;SAME?
PUSHJ P,PTFILE ;YES. PRINT STATUS OF THIS FILE
JRST FIL6A ;NOT SAME, OR STATUS PRINTED OK.
FIL6B: SUB P,[3,,3] ;RE-ADJUST STACK, FLUSHING FILE NAME, EXT, PPN
JRST FIL5F ;EXIT COMMAND
FIL4: SKIPA TAC1,[0] ;ZERO FILE EXTENSION
FIL3: PUSHJ P,CTEXT ;READ FILE EXTENSION
PUSH P,TAC1 ;SAVE EXT
PUSHJ P,PJPGNO ;READ PPN
JRST FIL6D ;NONE TYPED, GET DEFAULT PPN
JRST FIL6 ;GO SAVE PPN TYPED
FIL99: PUSHJ P,SKIPS1 ;SEE IF ANYTHING EXTRANEOUS AT END OF LINE
SUB P,[4,,4] ;YES. ERROR
JRST COMERA ;(SKIPS1 RETURNS UP A LEVEL IF FINDS END OF LINE)
FIL88: PUSHJ P,SKIPS1 ;COMEND MAKES THIS CHECK ALSO BUT ONLY REMOVES
SUB P,[2,,2] ; ONE ENTRY FROM STACK INSTEAD OF TWO
JRST COMERA
FIL5: SUB P,[1,,1] ;DISCARD SIXBIT JOB NUMBER ON STACK
JUMPN TAC,FIL5D ;ZERO JOB NUMBER MEANS OWN JOB,
FIL5C: SKIPN TAC,J ; IF ANY.
JRST LOGPLS ; IF NONE, CANT HELP YOU
FIL5D: MOVE TAC1,JBTSTS(TAC);SEE IF THIS JOB NUMBER IS ASSIGNED
TLNE TAC1,JNA
TLNE TAC1,JSEG ;NO SEGMENTS PLEASE
JRST NOTLOG ;NO SUCH JOB
PUSH P,TAC ;SAVE JOB NUMBER
PUSHJ P,FIL88 ;MAKE SURE NOTHING EXTRANEOUS AFTER JOB NUMBER
JUMPL AC1,FIL5G ;JUMP IF CONTINUING DELAYED COMMAND
FIL5A: PUSHJ P,NXTDSK ;GET NEXT DSK DDB
JRST FIL5B ;NONE, DONE
FIL5G: LDB TAC1,[POINT 6,DEVCHR(AC1),5] ;PICK UP JOB NUMBER FROM DDB
CAMN TAC1,(P) ;IS IT THE JOB OF INTEREST?
PUSHJ P,PTFILE ;YUP. PRINT FILE STATUS
JRST FIL5A ;NOT CORRECT JOB, OR FILE STATUS PRINTED OK
FIL5B: SUB P,[1,,1] ;REMOVE JOB NUMBER FROM STACK
FIL5F: HRRZM AC1,SAVDDB(DDB) ;REMEMBER WHETHER WE FINISHED PROCESSING DDB LIST
JUMPN AC1,DLYCM2 ;IF NOT END OF LIST, DELAY COMMAND
POPJ P,
FIL2JB: TDNE TAC1,[77,,-1] ;CONVERT SIXBIT TEXT TO JOB NUMBER
JRST CPOPJ1 ;MORE THAN TWO CHARS MEANS NOT JOB NUMBER
SETZ TAC,
LSHC TAC,6 ;GET FIRST SIXBIT CHAR
SUBI TAC,'0' ;CONVERT DIGIT TO BINARY
JUMPL TAC,CPOPJ1 ;NOT DIGIT MEANS NOT JOB NUMBER
CAILE TAC,=9
JRST CPOPJ1 ;NOT DIGIT
JUMPE TAC1,CPOPJ ;IF NO SECOND DIGIT, THEN DONE
ROT TAC1,6 ;GET SECOND DIGIT
SUBI TAC1,'0' ;CONVERT SIXBIT DIGIT TO BINARY
JUMPL TAC1,CPOPJ1 ;NO DIGEE, NO JOBEE
CAILE TAC1,=9
JRST CPOPJ1 ;LOSE
IMULI TAC,=10 ;SHIFT HIGH-ORDER DIGIT
ADD TAC,TAC1 ; AND ADD IN LOW-ORDER DIGIT
POPJ P, ;DIRECT RETURN WITH JOB NUMBER IN TAC
FIL2: MOVEI AC1,DSKDDB ;LOOK THROUGH DISK DDBS FOR PLACE WE QUIT LAST TIME
FIL2A: PUSHJ P,NXTDSK ;GET NEXT DSK DDB
POPJ P, ;NO MORE. CAN'T FIND RIGHT PLACE. START OVER.
CAME TAC,AC1 ;IS THIS THE DDB WHERE WE QUIT?
JRST FIL2A ;NO, TRY AGAIN.
TLO AC1,400000 ;FLAG NOT TO ADVANCE TO NEXT DDB
JRST CPOPJ1 ;SKIP WITH SUCCESS
PTFILE: TRNN AC2,ASSPRG ;AC2 HAS DEVMOD
POPJ P, ;DON'T TYPE ASSCON DDBS
MOVEI TAC,=39+4 ;PRINT A FILE'S STATUS, AT MOST =39 CHARS NEEDED.
CAML TAC,TOFCTR(DDB) ;SEE IF WE HAVE ENOUGH ROOM IN OUTPUT BUFFER
JRST CPOPJ1 ;NOT ENOUGH ROOM IN BUFFER
LDB TAC,[POINT 6,DEVCHR(AC1),5] ; GET NUMBER OF JOB WITH FILE OPEN
MOVEI TEM," "
CAIGE TAC,=10 ;IF JOB NUMBER LESS THAN =10,
XCT TYO ; THEN PAD NUMBER WITH A SPACE
PUSHJ P,RADX10 ;PRINT JOB NUMBER
MOVE TAC1,DEVFIL(AC1);GET FILE NAME
PUSHJ P,PR6SIX ; AND PRINT 6 CHARS AFTER SPACE
HLLZ TAC1,DEVEXT(AC1);GET FILE EXT
PUSHJ P,PR3SIX ; AND PRINT 3 CHARS AFTER SPACE
MOVE TAC1,FILPPN(AC1);GET FILE PPN
PUSHJ P,PR6SIX ; AND PRINT 6 CHARS AFTER SPACE
MOVE TAC,FILLNG(AC1) ;GET FILE LENGTH
PUSHJ P,DGETL1 ; AND CONVERT TO RECORDS (DGETL1 IS IN DSKSER)
SKIPE TAC1,TAC ;IF NON-ZERO, SUBTRACT ONE TO GET NUMBER
SUBI TAC1,1 ; OF LAST RECORD, NOT FIRST FREE RECORD
PUSHJ P,PRREC ; PRINT FILE LENGTH IN RECORDS
MOVE TAC1,USETP(AC1) ;GET CURRENT USET POINTER
PUSHJ P,PRREC ; AND PRINT IT
MOVEI TEM," "
XCT TYO ;PRINT A SPACE
MOVEI TEM,"U"
TLNE AC2,DVUDP ;IS THIS A UDP?
XCT TYO ;YES, PRINT "U"
MOVE TAC,DEVIOS(AC1) ;SEE WHAT IS HAPPENING TO THIS FILE
TLNN TAC,READB ;BEING READ?
JRST PTFIL2 ;NO
MOVEI TEM,"R" ;YES. PRINT "R"
XCT TYO
MOVEI TEM,"A"
TLNE TAC,ALTERB ;OPEN IN READ-ALTER MODE?
XCT TYO ;YUP, PRINT "A" AFTER THE "R"
MOVEI TEM,"E"
TLNE TAC,IOEND ;END OF FILE?
XCT TYO ;YES, PRINT "E"
JRST CRLF ;PRINT CRLF AND RETURN FROM PTFILE
PTFIL2: MOVEI TEM,"W"
TLNE TAC,WRITEB ;IS FILE BEING WRITTEN?
XCT TYO ;YES, PRINT "W"
JRST CRLF ;PRINT CRLF AND RETURN FROM PTFILE
PR3SIX: MOVEI UCHN,3 ;PRINT 3 SIXBIT CHARS
JRST .+2
PR6SIX: MOVEI UCHN,6 ;PRINT 6 SIXBIT CHARS
MOVEI TEM," "
XCT TYO
PRSIXA: SETZ TAC,
LSHC TAC,6 ;GET NEXT SIXBIT CHAR
MOVEI TEM,40(TAC) ;PRINT ASCII
XCT TYO
SOJG UCHN,PRSIXA ;PRINTED ENOUGH CHARS YET?
POPJ P, ;YUP
PRREC: MOVEI UCHN,5 ;PRINT OCTAL NUMBER IN 6 CHARS WITH LEADING BLANKS
MOVEI TEM," "
HRLZ TAC1,TAC1 ;PUT OCTAL NUMBER IN LEFT HALF OF TAC1
PRREC2: SETZ TAC,
LSHC TAC,3 ;GET NEXT OCTAL DIGIT
JUMPN TAC,PRREC1 ;IF NON ZERO, GO PRINT
XCT TYO ;OTHERWISE, PRINT SPACE
SOJG UCHN,PRREC2 ;PRINTED 5 LEADING SPACES YET?
PRREC3: SETZ TAC,
LSHC TAC,3 ;GET NEXT OCTAL DIGIT
PRREC1: MOVEI TEM,"0"(TAC) ;PRINT ASCII DIGIT
XCT TYO
SOJGE UCHN,PRREC3 ;PRINTED 6 CHARS YET?
POPJ P, ;YES. DONE AT LAST
NXTDSK: HLRZ AC1,DEVSER(AC1) ;GET LINK TO NEXT DDB
JUMPE AC1,CPOPJ ;DIRECT RETURN IF NONE
MOVE AC2,DEVMOD(AC1) ;GET DEVICE CHARACTERISTICS
TLNN AC2,DVDSK ;IS THIS A DSK DDB?
JRST NXTDSK ;NO. GET NEXT DDB
JRST CPOPJ1 ;YES. SKIP RETURN WITH DSK DDB